fix: deduplicate runtime dependency and resource copies to avoid parallel copy races

Author: FlyAndNotDown

CMake/Target.cmake

@@ -86,6 +86,37 @@ function(exp_gather_target_runtime_dependencies_recurse)
     set(${arg_OUT_DEP_TARGET} ${result_dep_target} PARENT_SCOPE)
 endfunction()
 
+function(exp_add_shared_copy_target)
+    set(options "")
+    set(singleValueArgs KEY SRC DST MAKE_DIR OUTPUT_TARGET)
+    set(multiValueArgs DEPENDS)
+    cmake_parse_arguments(arg "${options}" "${singleValueArgs}" "${multiValueArgs}" ${ARGN})
+
+    string(MAKE_C_IDENTIFIER "${arg_KEY}" key_id)
+    set(registry_property EXP_SHARED_COPY_TARGET_${SUB_PROJECT_NAME}_${key_id})
+
+    get_property(copy_target GLOBAL PROPERTY ${registry_property})
+    if (NOT copy_target)
+        set(copy_target ${SUB_PROJECT_NAME}.Copy.${key_id})
+        if (DEFINED arg_MAKE_DIR)
+            set(copy_commands COMMAND ${CMAKE_COMMAND} -E make_directory ${arg_MAKE_DIR})
+        else ()
+            set(copy_commands "")
+        endif ()
+        list(APPEND copy_commands COMMAND ${CMAKE_COMMAND} -E copy_if_different ${arg_SRC} ${arg_DST})
+
+        add_custom_target(${copy_target} ${copy_commands})
+        set_target_properties(${copy_target} PROPERTIES FOLDER ${AUX_TARGETS_FOLDER})
+        set_property(GLOBAL PROPERTY ${registry_property} ${copy_target})
+    endif ()
+
+    if (arg_DEPENDS)
+        add_dependencies(${copy_target} ${arg_DEPENDS})
+    endif ()
+
+    set(${arg_OUTPUT_TARGET} ${copy_target} PARENT_SCOPE)
+endfunction()
+
 function(exp_process_runtime_dependencies)
     set(options NOT_INSTALL)
     set(singleValueArgs NAME)
@@ -105,28 +136,37 @@ function(exp_process_runtime_dependencies)
             OUT_DEP_TARGET dep_dep_targets
         )
         list(APPEND runtime_deps ${dep_target_runtime_deps})
-        list(APPEND dep_targets ${dep_dep_targets})
     endforeach ()
 
-    set(copy_commands COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:${arg_NAME}>)
-    foreach(r ${runtime_deps})
-        list(APPEND copy_commands COMMAND ${CMAKE_COMMAND} -E copy_if_different ${r} $<TARGET_FILE_DIR:${arg_NAME}>)
-    endforeach()
-    if (NOT "${copy_commands}" STREQUAL "")
-        set(custom_target_name ${arg_NAME}.CopyRuntimeDeps)
-        add_custom_target(
-            ${custom_target_name}
-            ${copy_commands}
-        )
+    if (runtime_deps)
+        list(REMOVE_DUPLICATES runtime_deps)
+    endif ()
 
-        add_dependencies(${arg_NAME} ${custom_target_name})
-        foreach (t ${dep_targets})
-            add_dependencies(${custom_target_name} ${t})
-        endforeach ()
+    exp_get_runtime_output_dir(OUTPUT out_dir)
+    foreach (r ${runtime_deps})
+        set(copy_depends "")
+        if ("${r}" MATCHES "^\\$<TARGET_FILE:(.+)>$")
+            set(producer ${CMAKE_MATCH_1})
+            if (TARGET ${producer})
+                get_target_property(producer_imported ${producer} IMPORTED)
+                if (NOT producer_imported)
+                    set(copy_depends ${producer})
+                endif ()
+            endif ()
+        endif ()
 
-        set_target_properties(${custom_target_name} PROPERTIES FOLDER ${AUX_TARGETS_FOLDER})
-    endif ()
-    if (NOT arg_NOT_INSTALL AND NOT "${runtime_deps}" STREQUAL "")
+        exp_add_shared_copy_target(
+            KEY ${r}
+            SRC ${r}
+            DST ${out_dir}
+            MAKE_DIR ${out_dir}
+            DEPENDS ${copy_depends}
+            OUTPUT_TARGET copy_target
+        )
+        add_dependencies(${arg_NAME} ${copy_target})
+    endforeach ()
+
+    if (NOT arg_NOT_INSTALL AND runtime_deps)
         install(
             FILES ${runtime_deps} DESTINATION ${SUB_PROJECT_NAME}/Binaries
         )
@@ -153,29 +193,28 @@ function(exp_add_resources_copy_command)
     set(multiValueArgs RES)
     cmake_parse_arguments(arg "${options}" "${singleValueArgs}" "${multiValueArgs}" ${ARGN})
 
+    exp_get_runtime_output_dir(OUTPUT out_dir)
     foreach(r ${arg_RES})
         exp_expand_resource_path_expression(
             INPUT ${r}
             OUTPUT_SRC src
             OUTPUT_DST dst
         )
 
-        list(APPEND copy_commands COMMAND ${CMAKE_COMMAND} -E copy_if_different ${src} $<TARGET_FILE_DIR:${arg_NAME}>/${dst})
+        exp_add_shared_copy_target(
+            KEY ${dst}
+            SRC ${src}
+            DST ${out_dir}/${dst}
+            OUTPUT_TARGET copy_target
+        )
+        add_dependencies(${arg_NAME} ${copy_target})
 
         cmake_path(SET dst_path NORMALIZE "${SUB_PROJECT_NAME}/Binaries/${dst}")
         cmake_path(GET dst_path PARENT_PATH dst_dir)
         if (NOT arg_NOT_INSTALL)
             install(FILES ${src} DESTINATION ${dst_dir})
         endif ()
     endforeach()
-
-    set(copy_res_target_name ${arg_NAME}.CopyRes)
-    add_custom_target(
-        ${copy_res_target_name}
-        ${copy_commands}
-    )
-    set_target_properties(${copy_res_target_name} PROPERTIES FOLDER ${AUX_TARGETS_FOLDER})
-    add_dependencies(${arg_NAME} ${copy_res_target_name})
 endfunction()
 
 function(exp_gather_target_libs)