build.gradle

plugins {
    id 'java'
    id 'com.gradleup.shadow' version '9.0.0-beta5'
}

group = 'io.moidac'
version = '1.0.3'

repositories {
    mavenCentral()
    maven { url 'https://repo.papermc.io/repository/maven-public/' }
    maven { url 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }
    maven { url 'https://repo.codemc.io/repository/maven-public/' }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.21.11-R0.1-SNAPSHOT'
    compileOnly 'me.clip:placeholderapi:2.11.6'
    compileOnly 'com.github.retrooper:packetevents-spigot:2.13.0'

    implementation 'org.xerial:sqlite-jdbc:3.45.3.0'
    implementation 'com.google.code.gson:gson:2.10.1'
}

shadowJar {
    archiveClassifier.set('')
    archiveFileName.set("MoidAC-v${version}.jar")
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.release.set(21)
}

processResources {
    filteringCharset = 'UTF-8'
    filesMatching('plugin.yml') {
        expand version: version
    }
}

tasks.register('cleanServer') {
    doLast {
        delete fileTree('test_server').matching {
            exclude 'server.jar', 'plugins/'
        }
        delete fileTree('test_server/plugins').matching {
            exclude 'server.jar'
        }
    }
}

tasks.register('copyPlugin', Copy) {
    dependsOn 'shadowJar'
    from "build/libs/MoidAC-${version}.jar"
    into 'test_server/plugins'
}

tasks.register('runServer', Exec) {
    dependsOn 'copyPlugin'
    workingDir = file('test_server')
    standardInput = System.in
    def javaHome = "${System.getProperty('user.home')}/.local/share/PrismLauncher/java/java-runtime-epsilon"
    commandLine = ["${javaHome}/bin/java", '-Xmx1G', '-jar', 'server.jar', '--nogui']
}