devshell-tools/flake.nix at main · eikek/devshell-tools · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
{
  description = "Utilities for devshells";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = inputs @ {
    self,
    nixpkgs,
    flake-utils,
  }: let
    legacyPackages = pkgs: let
      startsWith = s: (
        name: v: nixpkgs.lib.strings.hasPrefix s name
      );
      filter = s: set: nixpkgs.lib.attrsets.filterAttrs (startsWith s) set;
      vm-scripts = filter "vm-" (import ./pkgs/vm-scripts.nix {
        inherit (pkgs) writeShellScriptBin;
      });
      cnt-scripts = filter "cnt-" (import ./pkgs/cnt-scripts.nix {
        inherit (pkgs) writeShellScriptBin jq;
      });
    in {
      inherit vm-scripts cnt-scripts;
    };

    devshellToolsPkgs = pkgs: let
      scripts = legacyPackages pkgs;
      sbts = pkgs.callPackage (import ./pkgs/sbt.nix) {};
      mill1 = pkgs.callPackage (import ./pkgs/mill1.nix) {};
      mills = pkgs.callPackage (import ./pkgs/mill.nix) {inherit mill1;};
      postgres-fg = pkgs.callPackage (import ./pkgs/postgres-fg.nix) {};
    in
      rec {
        solr = pkgs.callPackage (import ./pkgs/solr.nix) {};
        swagger-ui = pkgs.callPackage (import ./pkgs/swagger-ui.nix) {};
        openapi-docs = pkgs.callPackage (import ./pkgs/openapi-docs.nix) {
          inherit swagger-ui;
        };
        inherit (sbts) sbt11 sbt17 sbt21;
        inherit (mills) mill17 mill21 mill1_17 mill1_21;
        inherit mill1;
        inherit postgres-fg;
      }
      // scripts.vm-scripts
      // scripts.cnt-scripts;

    pkgsBySystem = system:
      import nixpkgs {
        inherit system;
        overlays = [self.overlays.default];
      };
  in
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};
    in {
      formatter = pkgs.alejandra;
      packages = devshellToolsPkgs pkgs;

      legacyPackages = legacyPackages pkgs;

      devShells.default = pkgs.mkShellNoCC {
        buildInputs = let
          internalScripts = pkgs.callPackage (import ./internal/scripts.nix) {};
        in [
          internalScripts.cnt-recreate
          internalScripts.cnt-login
          internalScripts.cnt-logs
          (devshellToolsPkgs pkgs).postgres-fg
        ];

        DEV_CONTAINER = "devshcnt";
      };

      checks =
        (devshellToolsPkgs pkgs)
        // (
          if pkgs.stdenv.isLinux
          then {
            services = with import (nixpkgs + "/nixos/lib/testing-python.nix")
            {
              inherit system;
            };
              makeTest {
                name = "devshell-tools";
                nodes = {
                  machine = {...}: {
                    imports =
                      (builtins.attrValues self.nixosModules)
                      ++ [
                        {nixpkgs.pkgs = pkgsBySystem system;}
                        ./checks
                      ];
                  };
                };

                testScript = builtins.readFile ./checks/testScript.py;
              };
          }
          else {}
        );
    })
    // rec {
      nixosModules = {
        dev-solr = import ./modules/solr.nix;
        dev-email = import ./modules/email.nix;
        dev-postgres = import ./modules/postgresql.nix;
        dev-mariadb = import ./modules/mariadb.nix;
        dev-redis = import ./modules/redis.nix;
        dev-minio = import ./modules/minio.nix;
        openapi-docs = import ./modules/openapi-docs.nix;
        dev-fuseki = import ./modules/fuseki.nix;
        dev-keycloak = import ./modules/keycloak.nix;
        dev-authentik = import ./modules/authentik.nix;
        dev-spicedb = import ./modules/spicedb.nix;
      };

      nixosConfigurations = {
        devshcnt = lib.mkContainer {
          system = "x86_64-linux";
          modules = [
            {
              services.dev-postgres = {
                enable = true;
                #                databases = ["mydb"];
              };
              networking.hostName = "devshcnt";
            }
          ];
        };
      };

      overlays = {
        default = final: prev: devshellToolsPkgs final;
      };

      lib = import ./lib {
        inherit inputs;
        inherit (self) nixosModules;
        inherit pkgsBySystem;
      };

      templates.default = {
        path = ./template;
        description = "An example template for devshell-tools";
      };
    };
}