Tracker.pck.st

'From Cuis7.9 [latest update: #8139] on 19 August 2026 at 1:26:38 pm'!
'Description A tracker implemented with Signals.'!
!provides: 'Tracker' 1 135!
!requires: 'Signals' 1 490 nil!
SystemOrganization addCategory: #'Tracker-Kernel'!
SystemOrganization addCategory: #'Tracker-Morphic'!
SystemOrganization addCategory: #'Tracker-Theme'!


!classDefinition: #DarkerTheme category: #'Tracker-Theme'!
Theme subclass: #DarkerTheme
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Theme'!
!classDefinition: 'DarkerTheme class' category: #'Tracker-Theme'!
DarkerTheme class
	instanceVariableNames: ''!

!classDefinition: #Tracker category: #'Tracker-Kernel'!
ActiveModel subclass: #Tracker
	instanceVariableNames: 'instruments tracks sequence label bpm swing level inputOctave cursorPattern cursorLine cursorTrack playheadPattern playheadLine followPlayhead playStartPattern playStartLine playEndPattern playEndLine playingMask loop anyTrackSoloed ticksToNextLine peakLeft peakRight buses random undoStack redoStack videoTrackA videoTrackB videoOperation bitblt'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Kernel'!
!classDefinition: 'Tracker class' category: #'Tracker-Kernel'!
Tracker class
	instanceVariableNames: ''!

!classDefinition: #PatternControlBar category: #'Tracker-Morphic'!
ControlPanel subclass: #PatternControlBar
	instanceVariableNames: 'tracker pattern'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'PatternControlBar class' category: #'Tracker-Morphic'!
PatternControlBar class
	instanceVariableNames: ''!

!classDefinition: #TrackControlBar category: #'Tracker-Morphic'!
ControlPanel subclass: #TrackControlBar
	instanceVariableNames: 'tracker track'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'TrackControlBar class' category: #'Tracker-Morphic'!
TrackControlBar class
	instanceVariableNames: ''!

!classDefinition: #TrackerWindow category: #'Tracker-Morphic'!
SystemWindow subclass: #TrackerWindow
	instanceVariableNames: 'instrumentEditor instrumentRack sampleEditor videoMonitor adjuster meter arranger patternEditor lowerPane'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'TrackerWindow class' category: #'Tracker-Morphic'!
TrackerWindow class
	instanceVariableNames: ''!

!classDefinition: #InstrumentRackMorph category: #'Tracker-Morphic'!
ScrollerMorph subclass: #InstrumentRackMorph
	instanceVariableNames: 'tracker'
	classVariableNames: 'ClipboardBuffer'
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'InstrumentRackMorph class' category: #'Tracker-Morphic'!
InstrumentRackMorph class
	instanceVariableNames: ''!

!classDefinition: #InstrumentEditorMorph category: #'Tracker-Morphic'!
ZoomerMorph subclass: #InstrumentEditorMorph
	instanceVariableNames: 'tracker'
	classVariableNames: 'ClipboardBuffer'
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'InstrumentEditorMorph class' category: #'Tracker-Morphic'!
InstrumentEditorMorph class
	instanceVariableNames: ''!

!classDefinition: #ArrangerMorph category: #'Tracker-Morphic'!
BoxMorph subclass: #ArrangerMorph
	instanceVariableNames: 'tracker font clipboard selectionStart showCursor pauseBlinking'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'ArrangerMorph class' category: #'Tracker-Morphic'!
ArrangerMorph class
	instanceVariableNames: ''!

!classDefinition: #MultitrackMeterMorph category: #'Tracker-Morphic'!
BoxMorph subclass: #MultitrackMeterMorph
	instanceVariableNames: 'tracker leftMargin meterWidth meterSpacing'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'MultitrackMeterMorph class' category: #'Tracker-Morphic'!
MultitrackMeterMorph class
	instanceVariableNames: ''!

!classDefinition: #PatternEditorMorph category: #'Tracker-Morphic'!
BoxMorph subclass: #PatternEditorMorph
	instanceVariableNames: 'tracker cursorPosition font labelFont labelMonoFont editStep showCursor pauseBlinking selectionLineStart selectionTrackStart'
	classVariableNames: 'ClipboardBuffer FXColors FXStrings TrackColors'
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'PatternEditorMorph class' category: #'Tracker-Morphic'!
PatternEditorMorph class
	instanceVariableNames: ''!

!classDefinition: #PlaybackStatusMorph category: #'Tracker-Morphic'!
BoxMorph subclass: #PlaybackStatusMorph
	instanceVariableNames: 'tracker font'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'PlaybackStatusMorph class' category: #'Tracker-Morphic'!
PlaybackStatusMorph class
	instanceVariableNames: ''!

!classDefinition: #SampleEditorMorph category: #'Tracker-Morphic'!
BoxMorph subclass: #SampleEditorMorph
	instanceVariableNames: 'tracker sample needsRecomputingImage needsUpdate waveformImage playheadPosition cursorPosition selectionPositionStart mode title flap showCursor pauseBlinking font playingSample'
	classVariableNames: 'ClipboardBuffer'
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'SampleEditorMorph class' category: #'Tracker-Morphic'!
SampleEditorMorph class
	instanceVariableNames: ''!

!classDefinition: #VideoMonitorMorph category: #'Tracker-Morphic'!
BoxMorph subclass: #VideoMonitorMorph
	instanceVariableNames: 'tracker'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Morphic'!
!classDefinition: 'VideoMonitorMorph class' category: #'Tracker-Morphic'!
VideoMonitorMorph class
	instanceVariableNames: ''!

!classDefinition: #Instrument category: #'Tracker-Kernel'!
Object subclass: #Instrument
	instanceVariableNames: 'patchMorph rackMorph patch track trigger'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Kernel'!
!classDefinition: 'Instrument class' category: #'Tracker-Kernel'!
Instrument class
	instanceVariableNames: ''!

!classDefinition: #Pattern category: #'Tracker-Kernel'!
Object subclass: #Pattern
	instanceVariableNames: 'blocks length lpb'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Kernel'!
!classDefinition: 'Pattern class' category: #'Tracker-Kernel'!
Pattern class
	instanceVariableNames: ''!

!classDefinition: #Track category: #'Tracker-Kernel'!
Object subclass: #Track
	instanceVariableNames: 'tracker muted soloed instrument ticksToTrigger trigger tuning numberOfFXColumns'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Kernel'!
!classDefinition: 'Track class' category: #'Tracker-Kernel'!
Track class
	instanceVariableNames: ''!

!classDefinition: #Trigger category: #'Tracker-Kernel'!
Object subclass: #Trigger
	instanceVariableNames: 'instrument note velocity effects'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Tracker-Kernel'!
!classDefinition: 'Trigger class' category: #'Tracker-Kernel'!
Trigger class
	instanceVariableNames: ''!

!classDefinition: #Tuning category: #'Tracker-Kernel'!
Object subclass: #Tuning
	instanceVariableNames: 'intervals label noteNames'
	classVariableNames: 'EDO12 Library'
	poolDictionaries: ''
	category: 'Tracker-Kernel'!
!classDefinition: 'Tuning class' category: #'Tracker-Kernel'!
Tuning class
	instanceVariableNames: ''!


!Tracker commentStamp: '<historical>' prior: 0!
This is the model of a tracker. It holds a whole song or project (instruments, tracks and sequence of patterns, and global settings like BPM, swing, etc), and it also keeps track of runtime state (cursor position, playhead position, etc).!

!Instrument commentStamp: '<historical>' prior: 0!
An instrument has a patch of signal-processing modules, and interprets tracker triggers by sending messages to the patch to play notes or change parameters like velocity, volume, panning, etc. The patch of an instrument can be a musical instrument like a synthesizer or it could also be a send effect (like a reverb) that processes the output of other instruments. Instruments are designed to be monophonic (they play one note at a time).!

!Pattern commentStamp: '<historical>' prior: 0!
A pattern is a grid of triggers (notes and effect commands). The blocks (columns) correspond to tracks or channels.!

!Track commentStamp: '<historical>' prior: 0!
A track can play one instrument at a time. It can be muted or soloed, and it can be set to an arbitrary tuning. If the tuning is other than the standard 12-EDO, it internally maps arbitrary notes to fractional 12-EDO notes (using floats instead of the standard MIDI 0 to 127 integers).!

!Trigger commentStamp: '<historical>' prior: 0!
A trigger is a cell in the grid of a pattern. It can contain any of the following (optional) parameters: an instrument number (1 to 255), a note to play (0 to 127 as MIDI, and -1 to represent note off), a velocity value (0 to 128), and effect commands.

Effect commands:
∙ <xy / >xy crescendo/diminuendo, fade in/out increasing/decreasing velocity by x over y lines (0 = 0%, F = 100%)
∙ !!xy cut to velocity x (0 = minimum, F = maximum) after y/16 of a line
∙ #xx finetune note up by xx/256 of a note (depending on the track's tuning system)
∙ Gxx glide to note over xx/16 lines (01 = 1/16 of a line, 10 = 1 line, FF = almost 16 lines)
∙ ^xy / _xy (printed ↑xy / ↓xy) slide pitch up/down by x notes over y lines (depending on the track's tuning system)
∙ *xy retrigger every y/16 of a line, and change velocity according to x (see below)
∙ @xx jump to sample offset (00 = start, FF = end)
∙ $xx jump to slice marker xx (00 = start)
∙ +xx / -xx jump forward / backwards xx/16th of a line at the current playback speed (10 = duration of 1 line)
∙ /xy / \xy slide playback speed to x over y lines and play forward / backwards (4 = ¹/₂×, 8 = 1×, C = 2×, F = 8×)
∙ ~xy scribble (oscillate playback direction) at peak speed x every y/16 of a line
∙ 0xx to 9xx set control value
∙ Fxx set tempo to xx BPM
∙ &xx delay trigger by xx/256 of a line (00 = no delay, 01 = 1/256 of a line, FF = 1/256 before next line)
∙ ?xx set the probability of playing the trigger (00 = never, FF = always)
∙ Axx / Bxx set video source A/B to track xx
∙ Xxy apply BitBlt rule x on video source A and y on video source B

Retrigger velocity change:
∙ 0 no velocity change
∙ 1, 2, 3, 4, 5 reduce velocity by subtracting 1/32, 1/16, 1/8, 1/4, 1/2
∙ 6, 7 scale down velocity multuplying by 2/3, 1/2
∙ 8 no velocity change
∙ 9, A, B, C, D increase velocity by adding 1/32, 1/16, 1/8, 1/4, 1/2
∙ E, F scale up velocity multiplying by 3/2, 2
!

!Tuning commentStamp: '<historical>' prior: 0!
A tuning system is defined by a list of intervals from the root note, in cents of a semitone. The last interval is assumed to be the octave (normally 1200.0 cents, but not always). This is the same definition of tuning system that Scala uses. We also include optional names for the notes, in order to support special notation for some tunings such as 31-EDO.!

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
acceptButton
	^ self successColor! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
background
	^ Color black! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
buttonColorFrom: paneColor
	^ paneColor adjustSaturation: -0.03 brightness: -0.1! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
buttonLabel
	^ Color black! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
cancelButton
	^ self errorColor! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
errorColor
	^ Color lightRed! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
failureColor
	^ Color yellow duller! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
focusIndicator
	^ self textHighlight lighter! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
listMultiHighlightFocused: aBoolean
	^ (self listHighlightFocused: aBoolean) 
		adjustSaturation: 0.0 brightness: 0.15! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
paneBackgroundFrom: aColor
"	^ aColor adjustSaturation: 0 brightness: -0.7"
	^ aColor alphaMixed: 0.14 with: Color black! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
scrollbarButtonColor
	^Color black! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
scrollbarColor
	^ Color black! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
scrollbarSliderShadowColor
	^Color black! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
shout
	"
	SHTextStylerST80 releaseClassCachedState
	"
	| green yellow pink blue lilac |
	"fav:"
	yellow := '#F6FA70'.
	blue := '#80DAFF'.
"	blue := '#62CDFF'."
	green := '#B4FF9F'.
	pink := '#FF8AAE'.
"	orange := '#FFCBA3'."
	lilac := '#ACBCFF'.
	"classic:"
"	yellow := '#FFFE82'.
	blue := '#9ED6FF'.
	green := '#ADFFD3'.
	purple := '#FF709C'."
	"fluo:"
"	green := '#A3F307'.
	yellow := '#e2f9e2'.
	purple := '#f50b86'.
	blue := '#05f9e2'."
	"neon:"
"	yellow := '#F6FA70'.
	blue := '#0079FF'.
	green := '#00DFA2'.
	purple := '#FF0060'."

	^ {
		#selector  				-> nil.
		#defaults 				-> #white.
		#undefined 				-> #white. "#(lightRed lighter lighter lighter lighter)."
		#comment 				-> #(lightGray lighter).
		#literals 				-> blue.
		#pseudoVariables 		-> pink. "and bold"
		#messages 				-> #(white).
		#incompleteMessages	-> #(white).
		#arguments 				-> yellow.
		#instVar 				-> lilac.
		#tempBar 				-> #(white darker).
"		#tempVars				-> '#F0FFC4'."
"		#tempVars				-> '#ADFFD3'."
		#tempVars				-> green.
"		#blockTemps				-> '#5CFFA7'."
		#blockTemps				-> green.
"		#block 					-> #(white)."
		#blockLevelZero		-> #(white).
		#blockLevelOne 		-> #(red muchLighter).
		#blockLevelTwo 		-> #(yellow muchLighter).
		#blockLevelThree 		-> #(green muchLighter).
		#blockLevelFour 		-> #(blue muchLighter).
		#blockLevelFive 		-> #(white darker).
		#blockLevelSix 		-> #(white darker).
		#blockLevelSeven 		-> #(white darker).
		#methodTags 			-> #(lightGray lighter). "#(hotPink)"
	}
	
"
		SHTextStylerST80 initialize
" 
! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
successColor
	^ Color lightGreen duller! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
text
	^ Color white! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 27/Jun/2026, 9:53:18 pm (UTC)'!
textAutoHighlight
"	^ (Color colorFrom: '#FF005C') alpha: 0.5"
"	^ (Color colorFrom: '#ff2f8e') alpha: 0.5"
	^ (Color colorFrom: '#FF4466') alpha: 0.5! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
textCursor
	^ Color white! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
textHighlight
	^ Color gray "Color r: 0.2 g: 0.35 b: 0.45"! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
unfocusedTextHighlightFrom: aColor
	^aColor adjustSaturation: 0.0 brightness: -0.08! !

!DarkerTheme methodsFor: 'colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
windowLabel
	^ `Color gray: 0.2`! !

!DarkerTheme methodsFor: 'icons' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
closeIcon
	^ self cancelIcon! !

!DarkerTheme methodsFor: 'initialization' stamp: 'len 19/Aug/2026, 5:59:09 am (UTC)'!
initialize
	super initialize.
"
	TTFontReader smalltalkAssignmentArrowGlyphCodePoint: 16r2B05.
	TTFontReader smalltalkReturnArrowGlyphCodePoint: 16r2B06.
	TrueTypeFontFamily readAllTrueTypeFontsIn: DirectoryEntry trueTypeFontsDirectory / 'DejaVu' / 'DejaVuSans'.
	
	TrueTypeFontFamily readAllTrueTypeFontsIn: DirectoryEntry trueTypeFontsDirectory / 'JetBrainsMono'.
	TrueTypeFontFamily readAllTrueTypeFontsIn: DirectoryEntry trueTypeFontsDirectory / 'Commodore 64'.

	PreferenceSet setDefaultFont: 'DejaVu Sans'.
	PreferenceSet defaultFontSize: 18.
"
	Preferences
		at: #focusFollowsMouse put: true;
		at: #showAssignmentAsLeftArrow put: true;
		at: #biggerCursors put: false;
		at: #dismissAllOnOptionClose put: true;
		at: #subPixelRenderColorFonts put: true;
		at: #italicsInShout put: true;
		at: #shoutInWorkspaces put: true;
		at: #optionalButtons put: false;
		at: #showAnnotations put: true.

	PreferenceSet defaultFontSize: 18.

	SHTextStylerST80 initialize.

	(self runningWorld taskbar color: Color transparent; submorphs) last hide! !

!DarkerTheme methodsFor: 'menu colors' stamp: 'len 17/Jun/2026, 10:50:11 am (UTC)'!
menu
	^ Color darkGray! !

!DarkerTheme methodsFor: 'menu colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
menuText
	^ Color white! !

!DarkerTheme methodsFor: 'menu colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
menuTitleBar
	^ self menu darker! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
buttonBorderWidth
	^ 1! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
buttonPaneHeight
	"Answer the user's preferred default height for button panes."

	^(Preferences at: #standardButtonFont) lineSpacing * 10 // 8! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
embossedButtonLabels
	^ false! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
embossedTitles
	^ false! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
fullScreenDeskMargin
	^ 0! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 18/Jun/2026, 2:04:07 pm (UTC)'!
layoutAdjusterThickness
	^ 4! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
roundButtons
	^ true! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
roundWindowCorners
	^ true! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
roundedButtonRadius
	^ 4! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
roundedWindowRadius
	^6! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
scrollbarShowButtons
	^ false! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
scrollbarThickness
	^ 16! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
useUniformColors
	^false! !

!DarkerTheme methodsFor: 'other options' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
windowBorderWidth
	^ 6! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
browser
	^ `(Color fromHexString: '#00FFAB') duller`
"	^ Color lightGreen duller"! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
changeList
	^ Color lightCyan duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
changeSorter
	^ Color lightCyan duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
debugger
	^ Color lightRed darker! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 20/Jun/2026, 11:19:46 am (UTC)'!
defaultButtonColor
	^ self defaultWindowColor lighter "lighter"! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
defaultWindowColor
	^ `Color hue: 212 chroma: 0.015 luminance: 0.35`! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
fileContentsBrowser
	^ Color tan! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
fileList
	^ Color lightMagenta duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
messageNames
	^ Color lightBlue duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
messageSet
	^ Color lightBlue duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
packageList
	^ Color tan! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
testRunner
	^ Color blue quiteWhiter duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
transcript
	^ Color lightOrange! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
versionsBrowser
	^ Color pink whiter duller! !

!DarkerTheme methodsFor: 'tool colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
workspace
	^ Color lightYellow duller! !

!DarkerTheme methodsFor: 'widget colors' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
textPane
	^ Color black! !

!DarkerTheme methodsFor: 'private - shout mappings' stamp: 'len 11/Apr/2026, 5:42:14 am (UTC)'!
generateShoutConfig

	| styles colors |
	styles := OrderedCollection new.
	colors := self shout as: Dictionary.

	{
		{self undefined. colors at: #undefined}.
		{self defaults . colors at: #defaults}.
		{self pseudoVariables . colors at: #pseudoVariables. #bold}.
		{self literals . colors at: #literals}.
		{self instVar . colors at: #instVar}.
		{self messages . colors at: #messages}.
		{self blockLevelZero . colors at: #blockLevelZero}.
		{self blockLevelOne . colors at: #blockLevelOne}.
		{self blockLevelTwo . colors at: #blockLevelTwo}.
		{self blockLevelThree . colors at: #blockLevelThree}.
		{self blockLevelFour . colors at: #blockLevelFour}.
		{self blockLevelFive . colors at: #blockLevelFive}.
		{self blockLevelSix . colors at: #blockLevelSix}.
		{self blockLevelSeven . colors at: #blockLevelSeven}.
		{self tempBar . colors at: #tempBar}.
		{self methodTags . colors at: #methodTags . #bold}.
		{self globals . colors at: #defaults . #bold}.
		{self incompleteMessages . colors at: #incompleteMessages . #underlined}.
		{self argumentTypes . colors at: #arguments . self italic}.
		{self symbols . colors at: #messages . #bold}.
		{self pattern . colors at: #selector . #bold}.
		{self ansiAssignment . nil . #bold}.
		{self assignment . nil . #bold}.
		{self return . nil . #bold}.
		{self tempVars . colors at: #tempVars . self italic}.
		{self blockTemps . colors at: #blockTemps . self italic}
	} do: [ :style |
		styles addAll:
			(style first
				collect: [ :category | | elements |
					elements _ style asOrderedCollection.
					elements at: 1 put: category.
					Array withAll: elements ])].

	"Miscellaneous remainder after factoring out commonality:"
	styles addAll: {
		{#unfinishedString . colors at: #undefined . #normal}.
		{#undefinedIdentifier . colors at: #undefined .#bold}.
		{#unfinishedComment . colors at: #undefined . self italic}.
		{#comment . colors at: #comment . self italic}.
		{#string . colors at: #literals . #normal}.
		{#literal . nil . self italic}.
		{#incompleteIdentifier . colors at: #incompleteMessages . {#italic. #underlined}}.
		{#classVar . colors at: #instVar . #bold}.
	}.

	^ styles! !

!DarkerTheme class methodsFor: 'as yet unclassified' stamp: 'len 11/Apr/2026, 5:49:05 am (UTC)'!
initialize
	super initialize.
	self beCurrent! !

!Tracker methodsFor: 'accessing' stamp: 'len 16/Dec/2025, 10:27:25 am (UTC)'!
bpm
	^ bpm! !

!Tracker methodsFor: 'accessing' stamp: 'len 29/Jun/2026, 7:08:05 pm (UTC)'!
bpm: aNumber
	bpm := aNumber.
	self triggerEvent: #bpmChanged: with: bpm! !

!Tracker methodsFor: 'accessing' stamp: 'len 5/Mar/2026, 8:36:52 am (UTC)'!
buses
	^ buses! !

!Tracker methodsFor: 'accessing' stamp: 'len 7/Jan/2026, 9:00:57 am (UTC)'!
followPlayhead
	^ followPlayhead! !

!Tracker methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 5:09:15 pm (UTC)'!
inputOctave
	^ inputOctave! !

!Tracker methodsFor: 'accessing' stamp: 'len 22/Jun/2026, 11:59:12 am (UTC)'!
inputOctave: anInteger
	inputOctave := anInteger.
	self triggerEvent: #inputOctaveChanged: with: inputOctave! !

!Tracker methodsFor: 'accessing' stamp: 'len 18/Feb/2026, 9:58:40 am (UTC)'!
instruments
	^ instruments! !

!Tracker methodsFor: 'accessing' stamp: 'len 10/Feb/2026, 8:05:40 am (UTC)'!
label
	^ label! !

!Tracker methodsFor: 'accessing' stamp: 'len 10/Feb/2026, 8:05:55 am (UTC)'!
label: aString
	label := aString.
	self triggerEvent: #labelChanged! !

!Tracker methodsFor: 'accessing' stamp: 'len 24/Jan/2026, 7:02:29 am (UTC)'!
level
	^ level! !

!Tracker methodsFor: 'accessing' stamp: 'len 24/Jan/2026, 7:20:55 am (UTC)'!
level: aNumber
	level := aNumber min: 1.0 max: 0.0.
	self triggerEvent: #levelChanged! !

!Tracker methodsFor: 'accessing' stamp: 'len 9/Jul/2026, 5:40:28 pm (UTC)'!
lps
	"Answer the number of lines per second."
	^ bpm * self playingPattern lpb / 60.0! !

!Tracker methodsFor: 'accessing' stamp: 'len 24/Jan/2026, 3:29:37 pm (UTC)'!
peakLeft
	^ peakLeft := peakLeft * 0.95! !

!Tracker methodsFor: 'accessing' stamp: 'len 24/Jan/2026, 3:29:52 pm (UTC)'!
peakRight
	^ peakRight := peakRight * 0.95! !

!Tracker methodsFor: 'accessing' stamp: 'len 21/Feb/2026, 9:39:00 am (UTC)'!
sequence
	^ sequence! !

!Tracker methodsFor: 'accessing' stamp: 'len 21/Feb/2026, 9:40:24 am (UTC)'!
sequencePatternNumbers
	| unique |
	unique := self sequenceUniquePatterns.
	^ sequence collect: [:each| unique indexOf: each key]! !

!Tracker methodsFor: 'accessing' stamp: 'len 21/Feb/2026, 9:40:36 am (UTC)'!
sequenceUniquePatterns
	| answer |
	answer := OrderedCollection new.
	sequence do: [:each| (answer identityIncludes: each key) ifFalse: [answer add: each key]].
	^ answer! !

!Tracker methodsFor: 'accessing' stamp: 'len 9/Feb/2026, 6:41:17 pm (UTC)'!
swing
	^ swing! !

!Tracker methodsFor: 'accessing' stamp: 'len 22/Jun/2026, 11:28:24 am (UTC)'!
swing: aNumber
	swing := aNumber min: 1.0 max: 0.0.
	self triggerEvent: #swingChanged: with: swing! !

!Tracker methodsFor: 'accessing' stamp: 'len 4/Jul/2026, 3:47:00 pm (UTC)'!
ticksToNextLine
	^ ticksToNextLine! !

!Tracker methodsFor: 'accessing' stamp: 'len 5/Aug/2026, 7:35:55 am (UTC)'!
tpb
	"Answer the number of ticks per beat."
	^ Module controlRate * 60.0 / bpm! !

!Tracker methodsFor: 'accessing' stamp: 'len 5/Aug/2026, 7:36:18 am (UTC)'!
tpl
	"Answer the number of ticks per line."
	^ self tpb / self playingPattern lpb! !

!Tracker methodsFor: 'accessing' stamp: 'len 16/Dec/2025, 2:18:23 pm (UTC)'!
tracks
	^ tracks! !

!Tracker methodsFor: 'cursor' stamp: 'len 1/Jan/2026, 10:06:02 am (UTC)'!
cursorLine
	^ cursorLine! !

!Tracker methodsFor: 'cursor' stamp: 'len 1/Jan/2026, 10:08:09 am (UTC)'!
cursorPattern
	^ cursorPattern! !

!Tracker methodsFor: 'cursor' stamp: 'len 1/Jan/2026, 9:37:16 am (UTC)'!
cursorTrack
	^ cursorTrack! !

!Tracker methodsFor: 'cursor' stamp: 'len 22/Jun/2026, 11:59:35 am (UTC)'!
inputOctaveDown
	inputOctave > 0 ifFalse: [^ self].
	self inputOctave: inputOctave - 1! !

!Tracker methodsFor: 'cursor' stamp: 'len 22/Jun/2026, 11:59:57 am (UTC)'!
inputOctaveUp
	inputOctave < 9 ifFalse: [^ self].
	self inputOctave: inputOctave + 1! !

!Tracker methodsFor: 'cursor' stamp: 'len 14/Mar/2026, 11:22:50 am (UTC)'!
moveCursorBeatDown
	self moveCursorLineDown: self selectedPattern lpb! !

!Tracker methodsFor: 'cursor' stamp: 'len 14/Mar/2026, 11:22:59 am (UTC)'!
moveCursorBeatUp
	self moveCursorLineUp: self selectedPattern lpb! !

!Tracker methodsFor: 'cursor' stamp: 'len 13/Jun/2026, 5:47:39 pm (UTC)'!
moveCursorLineBottom
	self isPlaying ifTrue: [self followPlayhead: false].
	cursorLine := self selectedPattern length.
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'cursor' stamp: 'len 10/Jan/2026, 3:27:29 pm (UTC)'!
moveCursorLineDown
	self moveCursorLineDown: 1! !

!Tracker methodsFor: 'cursor' stamp: 'len 23/Jul/2026, 2:33:14 pm (UTC)'!
moveCursorLineDown: anInteger
	| n |
	self isPlaying ifTrue: [self followPlayhead: false].
	cursorLine := cursorLine + anInteger.
	n := self selectedPattern length.
	cursorLine > n ifTrue:
		[cursorPattern < sequence size
			ifTrue:
				[cursorPattern := cursorPattern + 1.
				cursorLine := cursorLine - n min: self selectedPattern length]
			ifFalse: [cursorLine := n]].
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'cursor' stamp: 'len 13/Jun/2026, 5:47:34 pm (UTC)'!
moveCursorLineTop
	self isPlaying ifTrue: [self followPlayhead: false].
	cursorLine := 1.
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'cursor' stamp: 'len 10/Jan/2026, 3:27:36 pm (UTC)'!
moveCursorLineUp
	self moveCursorLineUp: 1! !

!Tracker methodsFor: 'cursor' stamp: 'len 23/Jul/2026, 2:33:06 pm (UTC)'!
moveCursorLineUp: anInteger
	self isPlaying ifTrue: [self followPlayhead: false].
	cursorLine := cursorLine - anInteger.
	cursorLine < 1 ifTrue:
		[cursorPattern > 1
			ifTrue:
				[cursorPattern := cursorPattern - 1.
				cursorLine := self selectedPattern length + cursorLine max: 1]
			ifFalse: [cursorLine := 1]].
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'cursor' stamp: 'len 13/Jun/2026, 5:46:59 pm (UTC)'!
moveCursorPatternDown
	self isPlaying ifTrue: [self followPlayhead: false].
	cursorPattern < sequence size ifFalse: [^ self].
	cursorPattern := cursorPattern + 1.
	cursorLine := cursorLine min: self selectedPattern length.
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'cursor' stamp: 'len 13/Jun/2026, 5:47:06 pm (UTC)'!
moveCursorPatternUp
	self isPlaying ifTrue: [self followPlayhead: false].
	cursorPattern > 1 ifFalse: [^ self].
	cursorPattern := cursorPattern - 1.
	cursorLine := cursorLine min: self selectedPattern length.
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'cursor' stamp: 'len 14/Feb/2026, 12:54:17 pm (UTC)'!
moveCursorTrackLeft
	self setCursorTrack: cursorTrack - 1! !

!Tracker methodsFor: 'cursor' stamp: 'len 14/Feb/2026, 12:54:07 pm (UTC)'!
moveCursorTrackRight
	self setCursorTrack: cursorTrack + 1! !

!Tracker methodsFor: 'cursor' stamp: 'len 22/Jun/2026, 9:27:57 am (UTC)'!
setCursorTrack: anInteger
	((anInteger between: 1 and: tracks size) and: [cursorTrack ~= anInteger]) ifFalse: [^ self].
	cursorTrack := anInteger.
	self triggerEvent: #cursorChanged.
	self triggerEvent: #selectedTrackTuningChanged: with: self selectedTrack tuning! !

!Tracker methodsFor: 'initialization' stamp: 'len 7/Jul/2026, 6:36:23 am (UTC)'!
initialize
	instruments := Dictionary new.
	tracks := #().
	sequence := #().
	bpm := 120.
	swing := 0.0.
	level := 1.0.
	inputOctave := 4.
	cursorPattern := 1.
	cursorLine := 1.
	cursorTrack := 1.
	playheadPattern := 1.
	playheadLine := 0.
	followPlayhead := true.
	loop := false.
	playStartPattern := 1.
	playStartLine := 1.
	anyTrackSoloed := false.
	buses := (Array new: 10) at: 1 put: Bus new; yourself. "the master bus at 0"
	peakLeft := 0.0.
	peakRight := 0.0.
	random := Random new.

	undoStack := OrderedCollection new.
	redoStack := OrderedCollection new.
	
	bitblt := BitBlt toForm: (Form extent: 227 @ 128 "16:9" depth: Display depth).
	videoTrackA := videoTrackB := 0.
	videoOperation := 16r11.
	
	self insertTrack: 1.
	self insertPattern: 1.
	self selectedPattern track: 1 at: 1 position: 2 put: 1 "set instrument to 1"! !

!Tracker methodsFor: 'patterns' stamp: 'len 21/Feb/2026, 9:20:33 am (UTC)'!
deletePattern
	sequence size > 1 ifFalse: [^ self]. "don't delete last pattern"
	self deletePattern: cursorPattern! !

!Tracker methodsFor: 'patterns' stamp: 'len 21/Feb/2026, 9:23:15 am (UTC)'!
deletePattern: anInteger
	sequence := (sequence copyFrom: 1 to: anInteger - 1), (sequence copyFrom: anInteger + 1 to: sequence size).
	cursorPattern := cursorPattern min: sequence size.
	cursorLine := cursorLine min: self selectedPattern length.
	self triggerEvent: #sequenceChanged! !

!Tracker methodsFor: 'patterns' stamp: 'len 1/Jan/2026, 10:00:10 am (UTC)'!
deleteTrigger
	self selectedPattern track: cursorTrack at: cursorLine put: nil! !

!Tracker methodsFor: 'patterns' stamp: 'len 10/Jan/2026, 3:55:11 pm (UTC)'!
insertPattern
	self insertPattern: (cursorPattern := cursorPattern + 1).
	cursorLine := cursorLine min: self selectedPattern length! !

!Tracker methodsFor: 'patterns' stamp: 'len 21/Feb/2026, 9:21:43 am (UTC)'!
insertPattern: anInteger
	| answer |
	answer := Pattern new: tracks size.
	sequence := (sequence copyFrom: 1 to: anInteger - 1), {answer -> (tracks collect: [:each| true])}, (sequence copyFrom: anInteger to: sequence size).
	self triggerEvent: #sequenceChanged.
	^ answer! !

!Tracker methodsFor: 'patterns' stamp: 'len 21/Feb/2026, 12:37:25 pm (UTC)'!
insertSequence: anArray
	"Insert a list of patterns and masks after the current pattern."
	sequence := (sequence copyFrom: 1 to: cursorPattern), (anArray collect: [:each| each key -> each value copy]), (sequence copyFrom: cursorPattern + 1 to: sequence size).
	self triggerEvent: #sequenceChanged! !

!Tracker methodsFor: 'patterns' stamp: 'len 18/Feb/2026, 9:58:40 am (UTC)'!
selectedInstrument
	^ instruments at: (self selectedInstrumentNumber ifNil: [^ nil]) ifAbsentPut: [Instrument new]! !

!Tracker methodsFor: 'patterns' stamp: 'len 18/Feb/2026, 9:41:16 am (UTC)'!
selectedInstrumentNumber
	^​ self selectedPattern track: cursorTrack instrumentAbove: cursorLine! !

!Tracker methodsFor: 'patterns' stamp: 'len 20/Feb/2026, 3:39:55 pm (UTC)'!
selectedInstrumentNumberAtTrack: trackIndex
	^​ self selectedPattern track: trackIndex instrumentAbove: cursorLine! !

!Tracker methodsFor: 'patterns' stamp: 'len 21/Feb/2026, 9:22:40 am (UTC)'!
selectedPattern
	^ (sequence at: cursorPattern) key! !

!Tracker methodsFor: 'patterns' stamp: 'len 1/Jan/2026, 9:55:05 am (UTC)'!
selectedTrigger
	^ self selectedPattern track: cursorTrack at: cursorLine! !

!Tracker methodsFor: 'patterns' stamp: 'len 20/Jan/2026, 9:40:37 am (UTC)'!
selectedTriggerAt: position put: value
	self selectedPattern track: cursorTrack at: cursorLine position: position put: value! !

!Tracker methodsFor: 'patterns' stamp: 'len 20/Jan/2026, 9:41:51 am (UTC)'!
selectedTriggerPut: aTrigger
	self selectedPattern track: cursorTrack at: cursorLine put: aTrigger! !

!Tracker methodsFor: 'patterns' stamp: 'len 31/Jul/2026, 12:06:52 pm (UTC)'!
setSelectedPatternLength: anInteger
	| pattern |
	(pattern := self selectedPattern) length = anInteger ifTrue: [^ self].
	pattern length: anInteger.
	cursorLine <= anInteger ifFalse: [cursorLine := anInteger. self triggerEvent: #cursorChanged].
	(playheadPattern = cursorPattern and: [playheadLine <= anInteger])
		ifFalse: [playheadLine := anInteger - 1. self triggerEvent: #playheadChanged].
	self triggerEvent: #sequenceChanged! !

!Tracker methodsFor: 'patterns' stamp: 'len 14/Jun/2026, 7:42:11 pm (UTC)'!
swapInstrument: anInteger with: anotherInteger
	| instrument1 instrument2 |
	anInteger = anotherInteger ifTrue: [^ self].
	instrument1 := instruments at: anInteger ifAbsent: [].
	instrument2 := instruments at: anotherInteger ifAbsent: [].
	self sequenceUniquePatterns do: [:each| each swapInstrument: anInteger with: anotherInteger].
	instrument1 ifNil: [instruments removeKey: anotherInteger ifAbsent: []] ifNotNil: [instruments at: anotherInteger put: instrument1].
	instrument2 ifNil: [instruments removeKey: anInteger ifAbsent: []] ifNotNil: [instruments at: anInteger put: instrument2].
	self triggerEvent: #sequenceChanged! !

!Tracker methodsFor: 'patterns' stamp: 'len 21/Feb/2026, 9:23:00 am (UTC)'!
swapPattern: anInteger with: anotherInteger
	anInteger = anotherInteger ifTrue: [^ self].
	sequence swap: anInteger with: anotherInteger.
	self triggerEvent: #sequenceChanged! !

!Tracker methodsFor: 'playing' stamp: 'len 22/Jun/2026, 10:49:25 am (UTC)'!
followPlayhead: aBoolean
	followPlayhead = aBoolean ifTrue: [^ self].
	followPlayhead := aBoolean.
	self triggerEvent: #followPlayheadChanged: with: aBoolean! !

!Tracker methodsFor: 'playing' stamp: 'len 2/Jan/2026, 8:12:17 am (UTC)'!
isPlaying
	^ AudioPlayer isPlaying: self! !

!Tracker methodsFor: 'playing' stamp: 'len 13/Jun/2026, 5:38:02 pm (UTC)'!
isPlayingFollowingPlayhead
	^ followPlayhead and: [self isPlaying]! !

!Tracker methodsFor: 'playing' stamp: 'len 9/Jul/2026, 11:23:03 am (UTC)'!
loop
	^ loop! !

!Tracker methodsFor: 'playing' stamp: 'len 9/Jul/2026, 11:23:25 am (UTC)'!
loop: aBoolean
	loop = aBoolean ifTrue: [^ self].
	loop := aBoolean.
	self triggerEvent: #loopChanged: with: loop! !

!Tracker methodsFor: 'playing' stamp: 'len 4/Jul/2026, 3:44:51 pm (UTC)'!
play
	self isPlaying ifTrue: [^ self].
	playStartPattern := 1.
	playStartLine := 1.
	playEndPattern := sequence size.
	playEndLine := sequence last key length.
	playingMask := nil.
	playheadPattern := cursorPattern.
	playheadLine := cursorLine - 1.
	ticksToNextLine := 0.
	buses from: 2 to: buses size put: nil. "remove all buses except the master bus"
	"if playing from the begining, reset all modules (for reproducibility):"
	(playheadPattern = 1 and: [playheadLine = 0]) ifTrue: [instruments do: [:each| each reset]].
	Smalltalk garbageCollect. "just in case, to make a GC less likely during playback"
	AudioPlayer startPlaying: self.
	self triggerEvent: #playheadChanged.
	self triggerEvent: #playingStatusChanged! !

!Tracker methodsFor: 'playing' stamp: 'len 4/Jul/2026, 3:44:51 pm (UTC)'!
playFrom: startPattern line: startLine to: endPattern line: endLine tracks: tracksToPlay
	self isPlaying ifTrue: [^ self].
	playStartPattern := startPattern.
	playStartLine := startLine.
	playEndPattern := endPattern.
	playEndLine := endLine.
	playingMask := tracksToPlay ifNotNil: [(1 to: tracks size) collect: [:i| tracksToPlay includes: i]].
	playheadPattern := playStartPattern.
	playheadLine := playStartLine - 1.
	ticksToNextLine := 0.
	buses from: 2 to: buses size put: nil. "remove all buses except the master bus"
	AudioPlayer startPlaying: self.
	self triggerEvent: #playheadChanged.
	self triggerEvent: #playingStatusChanged! !

!Tracker methodsFor: 'playing' stamp: 'len 14/Jul/2026, 11:08:50 am (UTC)'!
playLine
	| pattern mask ticksPerLine ticksSwing |
	"Advance playhead:"
	playheadLine := playheadLine + 1.
	(playheadPattern = playEndPattern and: [playheadLine > playEndLine]) ifTrue:
		[loop ifTrue: [playheadPattern := playStartPattern. playheadLine := playStartLine] ifFalse: [playheadLine := playheadLine - 1. ^ self]].
	playheadLine > (sequence at: playheadPattern) key length ifTrue:
		[playheadPattern < playEndPattern
			ifTrue: [playheadLine := 1. playheadPattern := playheadPattern + 1]
			ifFalse: [loop ifTrue: [playheadPattern := playStartPattern. playheadLine := playStartLine] ifFalse: [^ self]]].
	"Notify playhead change and update cursor if following playhead:"
	self triggerEvent: #playheadChanged.
	followPlayhead ifTrue:
		[cursorPattern := playheadPattern.
		cursorLine := playheadLine.
		self triggerEvent: #cursorChanged].
	"Play current line:"
	pattern := self playingPattern.
	mask := self playingMask.
	tracks withIndexDo: [:track :i|
		| p |
		(mask at: i) ifTrue: [(pattern track: i at: playheadLine) ifNotNil: [:aTrigger|
			((p := aTrigger probability) = 1.0 or: [random next <= p]) ifTrue: [track scheduleTrigger: aTrigger]]]].
	ticksPerLine := self tpl.
	ticksToNextLine := ticksToNextLine + ticksPerLine.
	swing = 0.0 ifFalse:
		[ticksSwing := ticksPerLine * 0.333 * swing squared.
		(playheadLine \\ pattern lpb) even ifTrue: [ticksSwing := ticksSwing negated].
		ticksToNextLine := ticksToNextLine + ticksSwing]! !

!Tracker methodsFor: 'playing' stamp: 'len 4/Jul/2026, 3:44:51 pm (UTC)'!
playSampleCount: n into: anAudioBuffer startingAt: startIndex
	| blockSize i masterGain mask masterBus |
	blockSize := Module blockSize.
	i := startIndex.
	self assert: n \\ blockSize = 0.
	masterGain := level * 0.25. "leave -12 dB of headroom"
	mask := self playingMask.
	masterBus := buses at: 1.
	n // blockSize timesRepeat:
		[ticksToNextLine > 0 ifTrue: [ticksToNextLine := ticksToNextLine - 1] ifFalse: [self playLine. mask := self playingMask].
		buses do: [:each| each ifNotNil: [each clear]].
		mask withIndexDo: [:enabled :trackIndex| enabled ifTrue: [(tracks at: trackIndex) tick]].
		masterBus leftBuffer *= masterGain.
		masterBus rightBuffer *= masterGain.
		peakLeft := peakLeft max: masterBus leftBuffer peak.
		peakRight := peakRight max: masterBus rightBuffer peak.
		masterBus mixInto: anAudioBuffer startingAt: i.
		i := i + blockSize].
	^ n! !

!Tracker methodsFor: 'playing' stamp: 'len 1/Jan/2026, 10:14:07 am (UTC)'!
playheadLine
	^ playheadLine! !

!Tracker methodsFor: 'playing' stamp: 'len 1/Jan/2026, 10:13:55 am (UTC)'!
playheadPattern
	^ playheadPattern! !

!Tracker methodsFor: 'playing' stamp: 'len 8/Mar/2026, 12:19:48 pm (UTC)'!
playingMask
	^ playingMask ifNil: [(sequence at: playheadPattern) value]! !

!Tracker methodsFor: 'playing' stamp: 'len 21/Feb/2026, 9:27:08 am (UTC)'!
playingPattern
	^ (sequence at: playheadPattern) key! !

!Tracker methodsFor: 'playing' stamp: 'len 9/Mar/2026, 10:22:44 am (UTC)'!
stop
	self isPlaying ifFalse: [^ self].
	AudioPlayer stopPlaying: self.
	self triggerEvent: #playheadChanged.
	self triggerEvent: #playingStatusChanged! !

!Tracker methodsFor: 'playing' stamp: 'len 13/Jun/2026, 5:45:20 pm (UTC)'!
toggleFollowPlayhead
	self followPlayhead: followPlayhead not! !

!Tracker methodsFor: 'serialization' stamp: 'len 25/Jul/2026, 7:44:46 am (UTC)'!
asJsonWithBuffers: bufferList
	| uniquePatterns |
	uniquePatterns := self sequenceUniquePatterns.
	^ OrderedDictionary new
		at: #bpm put: bpm;
		at: #swing put: swing;
		at: #level put: level;
		at: #tracks put: (tracks collect: [:each| each asJson]);
		at: #sequence put: (self sequence collect: [:each|
			OrderedDictionary new
				at: #pattern put: (uniquePatterns indexOf: each key);
				at: #mask put: each value;
				yourself]);
		at: #patterns put: (uniquePatterns collect: [:each| each asJson]);
		at: #instruments put: (instruments collect: [:each| each asJsonWithBuffers: bufferList]);
		yourself! !

!Tracker methodsFor: 'serialization' stamp: 'len 15/Jun/2026, 3:46:45 pm (UTC)'!
readFrom: aStream
	| numberOfBuffers bufferList json |
	aStream useBytes.
	numberOfBuffers := aStream nextInt32BigEndian: true.
	bufferList := (1 to: numberOfBuffers) collect: [:i| Float32Array newFromStream: aStream].
	aStream useByteCharacters.
	json := Json readFrom: aStream.
	^ self readFromJson: json buffers: bufferList! !

!Tracker methodsFor: 'serialization' stamp: 'len 19/Aug/2026, 6:14:02 am (UTC)'!
readFromJson: json buffers: bufferList
	| uniquePatterns tracksJson |
	bpm := json at: #bpm.
	swing := json at: #swing.
	level := json at: #level.
	cursorPattern := 1.
	cursorLine := 1.
	cursorTrack := 1.
	playheadPattern := 1.
	playheadLine := 0.
	sequence := #().
	tracks := #().
	(tracksJson := json at: #tracks) isInteger
		ifTrue: [tracksJson timesRepeat: [self addTrack]]
		ifFalse: [tracksJson size timesRepeat: [self addTrack].
			tracksJson with: tracks do: [:trackJson :track| track readFromJson: trackJson]].
	anyTrackSoloed := tracks anySatisfy: [:any| any soloed].
	uniquePatterns := (json at: #patterns) collect: [:each| Pattern new readFromJson: each].
	sequence := (json at: #sequence) collect: [:each| (uniquePatterns at: (each at: #pattern)) -> (each at: #mask)].
	instruments := Dictionary new.
	(json at: #instruments) keysAndValuesDo: [:key :value| instruments at: key asNumber put: (Instrument new readFromJson: value buffers: bufferList)]! !

!Tracker methodsFor: 'serialization' stamp: 'len 9/Feb/2026, 9:22:08 am (UTC)'!
writeOn: aStream
	| bufferList json |
	bufferList := OrderedCollection new.
	json := self asJsonWithBuffers: bufferList.
	aStream nextInt32Put: bufferList size bigEndian: true.
	bufferList do: [:each| each writeOn: aStream].
	json jsonWriteOn: aStream! !

!Tracker methodsFor: 'tracks' stamp: 'len 9/Jun/2026, 4:19:44 pm (UTC)'!
addTrack
	^ self insertTrack: tracks size + 1! !

!Tracker methodsFor: 'tracks' stamp: 'len 9/Jan/2026, 8:08:32 am (UTC)'!
anyTrackSoloed
	^ anyTrackSoloed! !

!Tracker methodsFor: 'tracks' stamp: 'len 14/Jan/2026, 5:49:04 am (UTC)'!
deleteTrack
	tracks size > 1 ifFalse: [^ self]. "don't delete last track"
	self deleteTrack: cursorTrack! !

!Tracker methodsFor: 'tracks' stamp: 'len 4/Jul/2026, 5:05:49 pm (UTC)'!
deleteTrack: anInteger
	self clearUndoRedo.
	tracks := (tracks copyFrom: 1 to: anInteger - 1), (tracks copyFrom: anInteger + 1 to: tracks size).
	self sequenceUniquePatterns do: [:each| each deleteTrack: anInteger].
	sequence := sequence collect: [:each| each key -> ((each value copyFrom: 1 to: anInteger - 1), (each value copyFrom: anInteger + 1 to: each value size))].
	self setCursorTrack: (cursorTrack min: tracks size).
	self triggerEvent: #tracksChanged! !

!Tracker methodsFor: 'tracks' stamp: 'len 4/Jul/2026, 5:05:58 pm (UTC)'!
insertTrack: anInteger
	| answer |
	self clearUndoRedo.
	answer := Track new setTracker: self.
	tracks := (tracks copyFrom: 1 to: anInteger - 1), {answer}, (tracks copyFrom: anInteger to: tracks size).
	self sequenceUniquePatterns do: [:each| each insertTrack: anInteger].
	sequence := sequence collect: [:each| each key -> ((each value copyFrom: 1 to: anInteger - 1), {true}, (each value copyFrom: anInteger to: each value size))].
	self triggerEvent: #tracksChanged.
	^ answer! !

!Tracker methodsFor: 'tracks' stamp: 'len 21/Feb/2026, 9:29:22 am (UTC)'!
selectedMask
	^ (sequence at: cursorPattern) value! !

!Tracker methodsFor: 'tracks' stamp: 'len 1/Jan/2026, 8:35:44 am (UTC)'!
selectedTrack
	^ tracks at: cursorTrack! !

!Tracker methodsFor: 'tracks' stamp: 'len 22/Jun/2026, 9:21:56 am (UTC)'!
setSelectedTrackTuning: aTuningOrNil
	self selectedTrack tuning: aTuningOrNil.
	self triggerEvent: #selectedTrackTuningChanged: with: self selectedTrack tuning! !

!Tracker methodsFor: 'tracks' stamp: 'len 4/Jul/2026, 5:06:05 pm (UTC)'!
swapTrack: anInteger with: anotherInteger
	anInteger = anotherInteger ifTrue: [^ self].
	self clearUndoRedo.
	tracks swap: anInteger with: anotherInteger.
	"swap pattern blocks:"
	self sequenceUniquePatterns do: [:each| each swapTrack: anInteger with: anotherInteger].
	"swap masks:"
	sequence do: [:each| each value swap: anInteger with: anotherInteger].
	self triggerEvent: #tracksChanged! !

!Tracker methodsFor: 'tracks' stamp: 'len 1/Jan/2026, 8:33:12 am (UTC)'!
toggleTrackMask
	self toggleTrackMask: cursorTrack at: cursorPattern! !

!Tracker methodsFor: 'tracks' stamp: 'len 21/Feb/2026, 9:30:16 am (UTC)'!
toggleTrackMask: trackIndex at: patternIndex
	| mask |
	mask := (sequence at: patternIndex) value.
	mask at: trackIndex put: (mask at: trackIndex) not.
	self triggerEvent: #tracksChanged! !

!Tracker methodsFor: 'tracks' stamp: 'len 1/Jan/2026, 9:42:36 am (UTC)'!
toggleTrackMute
	self toggleTrackMute: cursorTrack! !

!Tracker methodsFor: 'tracks' stamp: 'len 31/Dec/2025, 3:37:29 pm (UTC)'!
toggleTrackMute: trackIndex
	| track |
	track := tracks at: trackIndex.
	track muted: track muted not.
	self triggerEvent: #tracksChanged! !

!Tracker methodsFor: 'tracks' stamp: 'len 1/Jan/2026, 9:42:28 am (UTC)'!
toggleTrackSolo
	self toggleTrackSolo: cursorTrack! !

!Tracker methodsFor: 'tracks' stamp: 'len 9/Jan/2026, 8:08:18 am (UTC)'!
toggleTrackSolo: trackIndex
	| track |
	track := tracks at: trackIndex.
	track soloed: track soloed not.
	anyTrackSoloed := tracks anySatisfy: [:any| any soloed].
	self triggerEvent: #tracksChanged! !

!Tracker methodsFor: 'ui' stamp: 'len 9/Apr/2026, 11:50:20 am (UTC)'!
open
	^ TrackerWindow open: self label: label! !

!Tracker methodsFor: 'undo/redo' stamp: 'len 4/Jul/2026, 5:07:06 pm (UTC)'!
clearUndoRedo
	undoStack removeAll.
	redoStack removeAll! !

!Tracker methodsFor: 'undo/redo' stamp: 'len 4/Jul/2026, 5:53:44 pm (UTC)'!
redo
"	self isPlaying ifTrue: [^ self]."
	redoStack ifEmpty: [^ self].
	undoStack add: sequence.
	sequence := redoStack removeLast.
	cursorPattern := cursorPattern min: sequence size.
	cursorLine := cursorLine min: (sequence at: cursorPattern) key length.
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'undo/redo' stamp: 'len 4/Jul/2026, 5:43:01 pm (UTC)'!
snapshot
	| selectedPattern selectedPatternCopy |
	redoStack removeAll.
	selectedPattern := (sequence at: cursorPattern) key.
	selectedPatternCopy := selectedPattern copy.
	undoStack add:
		(sequence collect: [:each| each key == selectedPattern ifTrue: [selectedPatternCopy -> each value] ifFalse: [each]])! !

!Tracker methodsFor: 'undo/redo' stamp: 'len 4/Jul/2026, 5:25:16 pm (UTC)'!
undo
"	self isPlaying ifTrue: [^ self]."
	undoStack ifEmpty: [^ self].
	redoStack add: sequence.
	sequence := undoStack removeLast.
	cursorPattern := cursorPattern min: sequence size.
	cursorLine := cursorLine min: (sequence at: cursorPattern) key length.
	self triggerEvent: #cursorChanged! !

!Tracker methodsFor: 'video' stamp: 'len 6/Jul/2026, 5:35:45 pm (UTC)'!
currentVideoFrame
	| op |
	(op := videoOperation bitShift: -4) > 0 ifTrue:
		[self videoA ifNotNil: [:video| self drawVideo: video op: op]].
	(op := videoOperation bitAnd: 16rF) > 0 ifTrue:
		[self videoB ifNotNil: [:video| self drawVideo: video op: op]].
	^ bitblt destForm! !

!Tracker methodsFor: 'video' stamp: 'len 8/Jul/2026, 11:30:32 am (UTC)'!
drawVideo: video op: op
	| rule |
	rule := #(3 "src" 1 "and" 6 "xor" 7 "or" 8 "not(src) and dst" 9 "not(src) xor dst" 13 "not(src) or dst" 18 "int+" 19 "int-" 20 "rgb+" 21 "rgb-" 27 "rgb max" 28 "rgb min" 10 "not dst" 2 "not(src)") at: op ifAbsent: [0].
	bitblt sourceForm: video strip; sourceX: 0; sourceY: video line; width: video width; height: video height; destX: bitblt destForm width - video width // 2; combinationRule: rule.
	bitblt copyBits
	
	"Interesting BitBlt combination rules in hexa:
	00	fill with 0
	01	A and B; mix, high contrast, saturation, some weird colors)
	02	A and not B; works with B=0, just inverts the current state; trails, colors, flickers
	03	A only
	05	B only
	06	A xor B; works with B=0, xors A with the current state; trails, colors, digital, noise, flickers
	07	A or B; nice disolve, bright, burning; with B=0 creates trails, burns, bumps of color; effect proportional to motion
	09	not A xor B; mix with negative film colors; with B=0 negative colors, trails, flickers
	0B	A or not B; noncommutative, negative colors, transluscent; with B=0 flickers, shapes
	0D	not A or B; noncommutative, similar to 0B; but with B=0 works well, no flicker, shapes, trails
	0E	not A or not B; only useful with B=0, similar to 0B, flickers
	12	A word + B word; mix, weird colors; with B=0 fractal noise following shapes, color rotation
	13	A word - B word; mix, saturated cartoon colors, or black masks (clips negatives to 0); with B=0 flickers, cartoonish
	14	A RBG-add B (add color components); mix, natural; with B=0 slow film burn to white 
	15	A RGB-sub B (subtract color components)	; only with B=0, flickers, shows movement trails, dark
	17	A blend B (alpha blending); doesn't work
	1B	A RGB-max B (maximum of color components); nice mix, natural; with B=0 erases moving things
	1C	A RGB-min B (minimum of color components); nice mix, similar to 1B but darker"
! !

!Tracker methodsFor: 'video' stamp: 'len 6/Jul/2026, 4:27:45 pm (UTC)'!
setVideoOperation: anInteger
	videoOperation := anInteger! !

!Tracker methodsFor: 'video' stamp: 'len 3/Aug/2026, 7:27:15 pm (UTC)'!
setVideoSourceA: trackNumber
	videoTrackA := trackNumber.
"	followPlayhead ifTrue: [self setCursorTrack: trackNumber]."
	bitblt destForm fillBlack! !

!Tracker methodsFor: 'video' stamp: 'len 6/Jul/2026, 11:22:38 am (UTC)'!
setVideoSourceB: trackNumber
	videoTrackB := trackNumber.
	bitblt destForm fillBlack! !

!Tracker methodsFor: 'video' stamp: 'len 6/Jul/2026, 11:13:05 am (UTC)'!
videoA
	^ (tracks at: videoTrackA ifAbsent: [^ nil]) video! !

!Tracker methodsFor: 'video' stamp: 'len 6/Jul/2026, 11:13:23 am (UTC)'!
videoB
	^ (tracks at: videoTrackB ifAbsent: [^ nil]) video! !

!Tracker class methodsFor: 'as yet unclassified' stamp: 'len 5/Apr/2026, 10:24:41 am (UTC)'!
fileReaderServicesForFileEntry: filename suffix: suffix
	suffix = 'song' ifTrue: [^ {self serviceLoadSong}].
	^ #()! !

!Tracker class methodsFor: 'as yet unclassified' stamp: 'len 9/Apr/2026, 11:47:00 am (UTC)'!
fromFileEntry: aFileEntry
	| answer |
	answer := aFileEntry readStreamDo: [:s| self new readFrom: s binary].
	(aFileEntry name endsWith: '.song') ifTrue: [answer label: (aFileEntry name allButLast: 5)].
	^ answer! !

!Tracker class methodsFor: 'as yet unclassified' stamp: 'len 9/Apr/2026, 12:22:28 pm (UTC)'!
openFromFileEntry: aFileEntry
	^​ (self fromFileEntry: aFileEntry) open fitAllPatchesToInstrumentEditorBounds! !

!Tracker class methodsFor: 'as yet unclassified' stamp: 'len 9/Apr/2026, 11:48:19 am (UTC)'!
serviceLoadSong
	^ (SimpleServiceEntry
		provider: self
		label: 'open in tracker'
		selector: #openFromFileEntry:
		description:'open in tracker'
		buttonLabel: 'open in tracker') argumentGetter: [:fileList| fileList selectedFileEntry]! !

!PatternControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:20:28 pm (UTC)'!
initialize
	| control |
	super initialize.
	(control := Control min: 1 max: 256 value: 64)
		label: 'Pattern length';
		printer: [:x| x rounded printString, ' L'];
		fineStep: 1.0/256;
		coarseStep: 1.0/256;
		receive: #baseValue: from: self when: #lengthChanged:;
		when: #changed: send: #setLength: to: self.
	self addMorph: (TextualControlMorph new control: control).
	(control := Control min: 1 max: 16 value: 4)
		label: 'Lines per beat';
		printer: [:x| x rounded printString, ' LPB'];
		fineStep: 1.0/16;
		coarseStep: 1.0/16;
		receive: #baseValue: from: self when: #lpbChanged:;
		when: #changed: send: #setLPB: to: self.
	self addMorph: (TextualControlMorph new control: control)! !

!PatternControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 11:45:57 am (UTC)'!
setLPB: aNumber
	pattern lpb: aNumber rounded.
	self triggerEvent: #lpbChanged: with: pattern lpb.
	tracker triggerEvent: #sequenceChanged! !

!PatternControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 12:07:08 pm (UTC)'!
setLength: aNumber
	tracker isPlaying ifFalse:
		[| newLength |
		newLength := (aNumber rounded max: pattern lastLineWithTrigger).
		newLength = pattern length ifFalse: [tracker setSelectedPatternLength: newLength]].
	self triggerEvent: #lengthChanged: with: pattern length! !

!PatternControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:35:01 am (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	tracker when: #cursorChanged send: #update to: self.
	self update! !

!PatternControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:49:40 am (UTC)'!
update
	| newPattern |
	(newPattern := tracker selectedPattern) = pattern ifTrue: [^ self].
	pattern := newPattern.
	self triggerEvent: #lengthChanged: with: pattern length.
	self triggerEvent: #lpbChanged: with: pattern lpb.
	self redrawNeeded! !

!TrackControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:54:16 am (UTC)'!
initialize
	super initialize.
	self addMorph: (PulldownListMorph new
		options: Tuning library;
		when: #changed: send: #setTuning: to: self;
		receive: #state: from: self when: #tuningChanged:;
"		receive: #options: from: Tuning when: #tuningsLibraryChanged:;"
		setBalloonText: 'Tuning system')! !

!TrackControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:39:11 am (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	tracker when: #cursorChanged send: #update to: self.
	self update! !

!TrackControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:47:06 am (UTC)'!
setTuning: aTuningOrNil
	track tuning: aTuningOrNil.
	self triggerEvent: #tuningChanged: with: track tuning! !

!TrackControlBar methodsFor: 'as yet unclassified' stamp: 'len 31/Jul/2026, 8:47:52 am (UTC)'!
update
	| newTrack |
	(newTrack := tracker selectedTrack) = track ifTrue: [^ self].
	track := newTrack.
	self triggerEvent: #tuningChanged: with: track tuning.
	self redrawNeeded! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 27/Jun/2026, 9:31:01 pm (UTC)'!
fitAllPatchesToInstrumentEditorBounds
	| bounds |
	layoutMorph layoutSubmorphs.
	bounds := instrumentEditor localBounds insetBy: 8.
	model instruments do: [:each| each patchMorph fitTo: bounds]! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 3/Jun/2026, 12:00:30 pm (UTC)'!
openProject
	model isPlaying ifTrue: [model stop].
	self request: 'Project name' initialAnswer: '' do: [:name|
		(self class package packageDirectory / 'data' / 'projects' // (name, '.song')) readStreamDo: [:s| model readFrom: s binary].
		model label: name.
		self setLabel: name.
		self fitAllPatchesToInstrumentEditorBounds.
		model triggerEvent: #cursorChanged]! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 9/Apr/2026, 8:02:54 am (UTC)'!
saveProject
	self request: 'Project name' initialAnswer: (model label ifNil: '') do: [:newName|
		model label: newName.
		(self class package packageDirectory / 'data' / 'projects' // (newName, '.song')) writeStreamDo: [:s| model writeOn: s].
		self setLabel: newName]! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 31/Jul/2026, 3:55:52 pm (UTC)'!
setInstrumentEditorMode: editorMode
	editorMode ifTrue: [^ self setMode: #editor].
	instrumentEditor visible ifTrue: [self setMode: #rack]! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 29/Jul/2026, 7:45:30 am (UTC)'!
setMode: mode
	mode = (videoMonitor visible ifTrue: [#video] ifFalse: [instrumentEditor visible ifTrue: [#editor] ifFalse: [sampleEditor visible ifTrue: [#sample] ifFalse: [#rack]]]) ifTrue: [^ self].
	instrumentEditor visible: mode = #editor.
	instrumentRack visible: mode = #rack.
	sampleEditor visible: mode = #sample.
	videoMonitor visible: mode = #video.
	adjuster visible: mode ~= #rack.
	mode = #rack ifTrue: [instrumentRack update]. "in case the order of the modules changed"
	mode = #sample ifTrue: [sampleEditor update]. "in case the sample changed"
	"why need to do this? otherwise the lower pane doesn't expand properly when going to the smaller instrument rack:"
	lowerPane delete.
	layoutMorph addMorph: lowerPane proportionalHeight: (mode = #rack ifTrue: [1.0] ifFalse: [0.5]).
	self triggerEvent: #instrumentEditorModeChanged: with: mode = #editor.
	self triggerEvent: #videoModeChanged: with: mode = #video.
	self triggerEvent: #sampleEditorModeChanged: with: mode = #sample! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 31/Jul/2026, 3:55:20 pm (UTC)'!
setSampleEditorMode: sampleEditorMode
	sampleEditorMode ifTrue: [^ self setMode: #sample].
	sampleEditor visible ifTrue: [self setMode: #rack]! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 5/Jul/2026, 4:09:57 pm (UTC)'!
setVideoMode: videoMode
	videoMode ifTrue: [^ self setMode: #video].
	videoMonitor visible ifTrue: [self setMode: #rack]! !

!TrackerWindow methodsFor: 'actions' stamp: 'len 23/Jun/2026, 3:46:55 pm (UTC)'!
toggleInstrumentRackOrEditor
	self setInstrumentEditorMode: instrumentEditor visible not! !

!TrackerWindow methodsFor: 'events' stamp: 'len 27/Jul/2026, 12:04:44 pm (UTC)'!
handleCommandHotkey: anEvent
	anEvent keyCharacter = $o ifTrue: [self openProject. ^ true].
	anEvent keyCharacter = $s ifTrue: [self saveProject. ^ true].
	anEvent keyCharacter = $e ifTrue: "switch between instrument editor and rack"
		[| oldKeyboardFocus focusedModule |
		anEvent hand deleteBalloon. "because it doesn't disappear by itself, it's a bug in morphic"
		oldKeyboardFocus := anEvent hand keyboardFocus.
		focusedModule := (oldKeyboardFocus ownerChain detect: [:one| one isKindOf: RackableMorph] ifNone: []) ifNotNil: [:aRackableMorph| aRackableMorph module].
		self toggleInstrumentRackOrEditor.
		anEvent hand newKeyboardFocus: ((oldKeyboardFocus notNil and: [oldKeyboardFocus isInWorld]) ifTrue: [oldKeyboardFocus] ifFalse: [self]).
		layoutMorph layoutSubmorphs.
		focusedModule ifNotNil: [instrumentEditor focusOnModule: focusedModule].
		^ true].
	anEvent keyCharacter = $d ifTrue: [instrumentEditor duplicateInstrument. ^ true].
	anEvent keyCharacter = $r ifTrue: [instrumentEditor renameInstrument. ^ true].
"	anEvent keyCharacter = $e ifTrue: [instrumentEditor exportInstrument. ^ true].
	anEvent keyCharacter = $i ifTrue: [instrumentEditor importInstrument. ^ true]."
	anEvent keyCharacter = $] ifTrue: [model inputOctaveUp. ^ true].
	anEvent keyCharacter = $[ ifTrue: [model inputOctaveDown. ^ true].
	anEvent keyCharacter = $n ifTrue: [model insertPattern. ^ true].
	anEvent keyCharacter = $N ifTrue: [model deletePattern. ^ true].
	anEvent keyCharacter = $t ifTrue: [model addTrack. ^ true].
	anEvent keyCharacter = $T ifTrue: [model deleteTrack. ^ true].
	anEvent keyCharacter = $' ifTrue: [model selectedTrack increaseFXColumns. ^ true].
	anEvent keyCharacter = $; ifTrue: [model selectedTrack decreaseFXColumns. ^ true].
	anEvent keyCharacter = $m ifTrue: [model toggleTrackMask. ^ true].
	anEvent keyCharacter isDigit ifTrue:
		[model setCursorTrack: ('1234567890' indexOf: anEvent keyCharacter).
		^ true].
	^ false! !

!TrackerWindow methodsFor: 'events' stamp: 'len 2/Jul/2026, 4:31:36 pm (UTC)'!
keyStroke: anEvent
	anEvent isSpace ifTrue: [model isPlaying ifTrue: [model stop] ifFalse: [model loop: anEvent secondaryModifierPressed not; play]. anEvent wasHandled: true. ^ self].
	(anEvent primaryModifierPressed and: [self handleCommandHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	^ super keyStroke: anEvent! !

!TrackerWindow methodsFor: 'initialization' stamp: 'len 1/Aug/2026, 1:54:25 pm (UTC)'!
buildBar
	| bar playbackStatus bpmControl swingControl barFont transportBar modeBar |
	barFont := FontFamily defaultFamilyPointSize: 16.
	bar := ControlPanel newRow gap: 48; axisEdgeWeight: 0.0; color: Color darkGray.
	transportBar := ControlPanel newRow.
	playbackStatus := PlaybackStatusMorph new setTracker: model.
	transportBar addMorph: playbackStatus.
	transportBar addMorph: (ToggleButtonMorph new font: barFont; state: model loop; when: #changed: send: #loop: to: model; receive: #state: from: model when: #loopChanged:; icon: self class repeatIcon; setBalloonText: 'Loop').
	transportBar addMorph: (ToggleButtonMorph new font: barFont; state: model followPlayhead; when: #changed: send: #followPlayhead: to: model; receive: #state: from: model when: #followPlayheadChanged:; "label: '⇩';" icon: self class followPlayheadIcon; setBalloonText: 'Follow playhead').
	(bpmControl := Control min: 10.0 max: 999.0 curve: #log value: 120.0)
		label: 'Tempo';
		printer: [:x| (x printStringFractionDigits: 1), ' BPM'];
		fineStep: 0.1 / 255.0;
		baseValue: model bpm;
		receive: #baseValue: from: model when: #bpmChanged:;
		when: #changed: send: #bpm: to: model.
	transportBar addMorph: (TextualControlMorph new control: bpmControl).
	(swingControl := Control min: 0.0 max: 1.0 value: 0.0)
		label: 'Swing';
		printer: [:x| '⇄ ', (x * 100) rounded printString, '%'];
		baseValue: model swing;
		receive: #baseValue: from: model when: #swingChanged:;
		when: #changed: send: #swing: to: model.
	transportBar addMorph: (TextualControlMorph new control: swingControl).
	bar addMorph: transportBar.
	bar addMorph: (PatternControlBar new setTracker: model).
	bar addMorph: (TrackControlBar new setTracker: model).
	bar addMorph: (PulldownListMorph new
		options: (0 to: 9);
		state: model inputOctave;
		labels: ((0 to: 9) collect: [:each| 'C', each printString]);
		when: #changed: send: #inputOctave: to: model;
		receive: #state: from: model when: #inputOctaveChanged:;
		setBalloonText: 'Octave for keyboard input').
	modeBar := ControlPanel new axisEdgeWeight: 1.0.
	modeBar addMorph: (ToggleButtonMorph new font: barFont; state: false; when: #changed: send: #setInstrumentEditorMode: to: self; receive: #state: from: self when: #instrumentEditorModeChanged:; icon: self class instrumentEditorIcon; setBalloonText: 'Instrument editor').
	modeBar addMorph: (ToggleButtonMorph new font: barFont; state: false; when: #changed: send: #setSampleEditorMode: to: self; receive: #state: from: self when: #sampleEditorModeChanged:; icon: self class sampleEditorIcon; setBalloonText: 'Sample editor').
	modeBar addMorph: (ToggleButtonMorph new font: barFont; state: false; when: #changed: send: #setVideoMode: to: self; receive: #state: from: self when: #videoModeChanged:; icon: self class tvIcon3; setBalloonText: 'Video monitor').
	bar addMorph: modeBar.
	^ bar! !

!TrackerWindow methodsFor: 'initialization' stamp: 'len 29/Jul/2026, 7:26:35 am (UTC)'!
buildMorphicWindow
	| lowerLeftPane sequencerScroller patternEditorScroller bar |
	instrumentEditor := InstrumentEditorMorph new setTracker: model.
	instrumentRack := InstrumentRackMorph new setTracker: model.
	sampleEditor := SampleEditorMorph new setTracker: model.
	videoMonitor := VideoMonitorMorph new setTracker: model.
	meter := MultitrackMeterMorph new setTracker: model.
	arranger := ArrangerMorph new setTracker: model.
	patternEditor := PatternEditorMorph new setTracker: model.
	model when: #cursorChanged send: #ensureCursorVisible to: self.
	bar := self buildBar.
	lowerPane := LinearLayoutMorph newRow color: Color transparent.
	lowerLeftPane := LinearLayoutMorph newColumn color: Color transparent.
	sequencerScroller := ScrollerMorph new vertical: true; scrollable: arranger.
	patternEditorScroller := ScrollerMorph new horizontal: true; scrollable: patternEditor.
	lowerLeftPane
		addMorph: meter layoutSpec: LayoutSizeSpec new useMorphHeight;
		addMorph: sequencerScroller layoutSpec: LayoutSizeSpec new.
	lowerPane
		addMorph: lowerLeftPane layoutSpec: (LayoutSizeSpec new useMorphWidth);
		addMorph: patternEditorScroller layoutSpec: LayoutSizeSpec new.
	layoutMorph
		addMorph: bar fixedHeight: 36;
		addMorph: instrumentRack fixedHeight: 180;
		addMorph: instrumentEditor proportionalHeight: 0.5;
		addMorph: sampleEditor proportionalHeight: 0.5;
		addMorph: videoMonitor proportionalHeight: 0.5.
	adjuster := layoutMorph addAdjusterMorph submorphs first.
	layoutMorph addMorph: lowerPane "proportionalHeight: 1.0".
	instrumentEditor hide.
	sampleEditor hide.
	videoMonitor hide.
	adjuster hide! !

!TrackerWindow methodsFor: 'initialization' stamp: 'len 9/Apr/2026, 4:59:23 pm (UTC)'!
defaultColor
	^ Color black! !

!TrackerWindow methodsFor: 'initialization' stamp: 'len 26/Jun/2026, 10:38:44 am (UTC)'!
outOfWorld: aWorld
	model stop.
	super outOfWorld: aWorld! !

!TrackerWindow methodsFor: 'private' stamp: 'len 15/Jun/2026, 4:22:24 pm (UTC)'!
ensureCursorVisible
	patternEditor owner scrollToMakeVisible: (patternEditor externalizeBoundingRectOf: patternEditor activeBounds).
	arranger owner scrollToMakeVisible: (arranger externalizeBoundingRectOf: arranger activeBounds)! !

!TrackerWindow methodsFor: 'GUI building' stamp: 'len 18/Jun/2026, 2:37:08 pm (UTC)'!
windowColor
	^ Color gray! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:50:27 pm (UTC)'!
filmIcon
	^ IconMorph new pathData: 'M2 3.9934C2 3.44476 2.45531 3 2.9918 3H21.0082C21.556 3 22 3.44495 22 3.9934V20.0066C22 20.5552 21.5447 21 21.0082 21H2.9918C2.44405 21 2 20.5551 2 20.0066V3.9934ZM8 5V19H16V5H8ZM4 5V7H6V5H4ZM18 5V7H20V5H18ZM4 9V11H6V9H4ZM18 9V11H20V9H18ZM4 13V15H6V13H4ZM18 13V15H20V13H18ZM4 17V19H6V17H4ZM18 17V19H20V17H18Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 9/Jul/2026, 11:21:32 am (UTC)'!
followPlayheadIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M233.33-161.33 80-315.33l46.67-46L200-290v-470.67h66.67V-290l72.66-71.33 46.67 46-152.67 154Zm252.67-38V-266h394v66.67H486Zm0-247.34v-66.66h394v66.66H486ZM486-694v-66.67h394V-694H486Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 9:28:23 pm (UTC)'!
instrumentEditorIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M602.67-120v-123.33h-156V-650H358v126.67H80V-840h278v123.33h244.67V-840H880v316.67H602.67V-650h-89.34v340h89.34v-126.67H880V-120H602.67Zm-456-653.33V-590v-183.33ZM669.33-370v183.33V-370Zm0-403.33V-590v-183.33Zm0 183.33h144v-183.33h-144V-590Zm0 403.33h144V-370h-144v183.33ZM146.67-590h144.66v-183.33H146.67V-590Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:19:52 pm (UTC)'!
lineEndSquareIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M520-340h280v-280H520v280Zm-80 80v-180H80v-80h360v-180h440v440H440Zm220-220Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:19:43 pm (UTC)'!
lineStartSquareIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M160-340h280v-280H160v280Zm360 80H80v-440h440v180h360v80H520v180ZM300-480Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 9:31:02 pm (UTC)'!
mixerIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M200-160v-280h-80v-80h240v80h-80v280h-80Zm0-440v-200h80v200h-80Zm160 0v-80h80v-120h80v120h80v80H360Zm80 440v-360h80v360h-80Zm240 0v-120h-80v-80h240v80h-80v120h-80Zm0-280v-360h80v360h-80Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:47:51 pm (UTC)'!
movieIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'm160-800 80 160h120l-80-160h80l80 160h120l-80-160h80l80 160h120l-80-160h120q33 0 56.5 23.5T880-720v480q0 33-23.5 56.5T800-160H160q-33 0-56.5-23.5T80-240v-480q0-33 23.5-56.5T160-800Zm0 240v320h640v-320H160Zm0 0v320-320Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:36:37 pm (UTC)'!
repeatIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M280-80 120-240l160-160 56 58-62 62h406v-160h80v240H274l62 62-56 58Zm-80-440v-240h486l-62-62 56-58 160 160-160 160-56-58 62-62H280v160h-80Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 24/Jul/2026, 6:33:07 am (UTC)'!
sampleEditorIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M240-80 80-240l160-160 57 56-64 64h494l-63-64 56-56 160 160L720-80l-57-56 64-64H233l63 64-56 56Zm200-360v-480h80v480h-80Zm-160-80v-320h80v320h-80Zm320 0v-320h80v320h-80ZM120-620v-120h80v120h-80Zm640 0v-120h80v120h-80Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 9:29:56 pm (UTC)'!
soundIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M280-240v-480h80v480h-80ZM440-80v-800h80v800h-80ZM120-400v-160h80v160h-80Zm480 160v-480h80v480h-80Zm160-160v-160h80v160h-80Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:51:32 pm (UTC)'!
tapeIcon
	^ IconMorph new pathData: 'M10.8293 13H13.1707C13.0602 12.6872 13 12.3506 13 12C13 10.3431 14.3431 9 16 9C17.6569 9 19 10.3431 19 12C19 13.6569 17.6569 15 16 15H8C6.34315 15 5 13.6569 5 12C5 10.3431 6.34315 9 8 9C9.65685 9 11 10.3431 11 12C11 12.3506 10.9398 12.6872 10.8293 13ZM4 5V19H20V5H4ZM3 3H21C21.5523 3 22 3.44772 22 4V20C22 20.5523 21.5523 21 21 21H3C2.44772 21 2 20.5523 2 20V4C2 3.44772 2.44772 3 3 3ZM8 13C8.55228 13 9 12.5523 9 12C9 11.4477 8.55228 11 8 11C7.44772 11 7 11.4477 7 12C7 12.5523 7.44772 13 8 13ZM16 13C16.5523 13 17 12.5523 17 12C17 11.4477 16.5523 11 16 11C15.4477 11 15 11.4477 15 12C15 12.5523 15.4477 13 16 13Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:44:42 pm (UTC)'!
tvIcon
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M160-120v-80q-33 0-56.5-23.5T80-280v-440q0-33 23.5-56.5T160-800h640q33 0 56.5 23.5T880-720v440q0 33-23.5 56.5T800-200v80h-40l-26-80H227l-27 80h-40Zm0-160h640v-440H160v440Zm320-220Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:45:27 pm (UTC)'!
tvIcon2
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M320-120v-80H160q-33 0-56.5-23.5T80-280v-480q0-33 23.5-56.5T160-840h640q33 0 56.5 23.5T880-760v480q0 33-23.5 56.5T800-200H640v80H320ZM160-280h640v-480H160v480Zm0 0v-480 480Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 5/Jul/2026, 3:45:38 pm (UTC)'!
tvIcon3
	^ IconMorph new viewBox: (0 @ 0 extent: 24 @ 24); pathData: 'M15.4142 4.99998H21.0082C21.556 4.99998 22 5.44461 22 6.00085V19.9991C22 20.5519 21.5447 21 21.0082 21H2.9918C2.44405 21 2 20.5553 2 19.9991V6.00085C2 5.44808 2.45531 4.99998 2.9918 4.99998H8.58579L6.05025 2.46445L7.46447 1.05023L11.4142 4.99998H12.5858L16.5355 1.05023L17.9497 2.46445L15.4142 4.99998ZM4 6.99998V19H20V6.99998H4Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:23:43 pm (UTC)'!
waveIcon1
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M480-80 360-642l-88 402H80v-80h128l113-520h79l122 572 78-332h80l72 280h128v80H690l-48-188-82 348h-80Z'! !

!TrackerWindow class methodsFor: 'as yet unclassified' stamp: 'len 29/Jun/2026, 7:26:42 pm (UTC)'!
waveIcon2
	^ IconMorph new viewBox: (0 @ -960 extent: 960 @ 960); pathData: 'M326-171q-15-11-22-28l-92-241H40v-80h228l92 244 184-485q7-17 22-28t34-11q19 0 34 11t22 28l92 241h172v80H692l-92-244-184 485q-7 17-22 28t-34 11q-19 0-34-11Z'! !

!InstrumentRackMorph methodsFor: 'actions' stamp: 'len 20/Jun/2026, 8:31:27 pm (UTC)'!
duplicateInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Duplicate to instrument number' initialAnswer: '' verifying: [:s| (s allSatisfy: [:x| x isDigit]) and: [s asNumber between: 1 and: 255]] do: [:s| tracker instruments at: s asNumber put: instrument copy]! !

!InstrumentRackMorph methodsFor: 'actions' stamp: 'len 21/Jun/2026, 7:26:06 am (UTC)'!
exportInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Instrument name' initialAnswer: (instrument label ifNil: ['']) do: [:newName|
		instrument label: newName.
		(self class package packageDirectory / 'data' / 'projects' // (newName, '.patch')) writeStreamDo: [:s| instrument writeOn: s].
		tracker triggerEvent: #instrumentLabelChanged]! !

!InstrumentRackMorph methodsFor: 'actions' stamp: 'len 21/Jun/2026, 7:25:59 am (UTC)'!
importInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Instrument name' initialAnswer: (instrument label ifNil: ['']) do: [:newName|
		instrument label: nil.
		(self class package packageDirectory / 'data' / 'projects' // (newName, '.patch')) readStreamDo: [:s| instrument readFrom: s binary].
		instrument label: newName.
		self fitPatchToBounds.
		tracker triggerEvent: #instrumentLabelChanged]! !

!InstrumentRackMorph methodsFor: 'actions' stamp: 'len 20/Jun/2026, 8:31:27 pm (UTC)'!
moveInstrumentDown
	tracker selectedInstrumentNumber ifNotNil: [:anInteger| anInteger > 1 ifTrue: [tracker swapInstrument: anInteger with: anInteger - 1]]! !

!InstrumentRackMorph methodsFor: 'actions' stamp: 'len 20/Jun/2026, 8:31:27 pm (UTC)'!
moveInstrumentUp
	tracker selectedInstrumentNumber ifNotNil: [:anInteger| anInteger < 255 ifTrue: [tracker swapInstrument: anInteger with: anInteger + 1]]! !

!InstrumentRackMorph methodsFor: 'actions' stamp: 'len 21/Jun/2026, 7:25:45 am (UTC)'!
renameInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Instrument name' initialAnswer: (instrument label ifNil: ['']) do: [:newName| instrument label: newName. tracker triggerEvent: #instrumentLabelChanged]! !

!InstrumentRackMorph methodsFor: 'events' stamp: 'len 20/Jun/2026, 8:33:00 pm (UTC)'!
handleCommandHotkey: anEvent
	anEvent keyCharacter = $i ifTrue: [tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument inspect]. ^ true].
	^ false! !

!InstrumentRackMorph methodsFor: 'events' stamp: 'len 21/Jul/2026, 6:04:38 am (UTC)'!
handleOptionHotkey: anEvent
	anEvent shiftPressed ifTrue:
		[anEvent isArrowDown ifTrue: [self moveInstrumentDown. ^ true].
		anEvent isArrowUp ifTrue: [self moveInstrumentUp. ^ true]].
	^ false! !

!InstrumentRackMorph methodsFor: 'events' stamp: 'len 10/Jul/2026, 9:00:58 am (UTC)'!
keyStroke: anEvent
	| c i |
	(anEvent primaryModifierPressed and: [self handleCommandHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	(anEvent secondaryModifierPressed and: [self handleOptionHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	anEvent keyCharacter = $\ ifTrue:
		[anEvent wasHandled: true.
		tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument track ifNotNil: [:aTrack|
			anEvent primaryModifierPressed ifTrue: [tracker toggleTrackSolo: (tracker tracks indexOf: aTrack)] ifFalse: [tracker toggleTrackMute: (tracker tracks indexOf: aTrack)]]].
		^ self].
	anEvent anyModifierKeyPressed ifFalse:
		[c := anEvent keyCharacter.
		c = $a ifTrue: [anEvent wasHandled: true. tracker selectedInstrument ifNotNil: [:anInstument| anInstument noteOff]. ^ self].
		(i := 'zsxdcvgbhnjmq2w3er5t6y7ui9o0p' indexOf: c) > 0 ifTrue:
			[anEvent wasHandled: true. tracker selectedInstrument ifNotNil: [:anInstument| anInstument noteOn: tracker selectedTrack inputCenterKey + i - 1]. ^ self]].
	^ super keyStroke: anEvent! !

!InstrumentRackMorph methodsFor: 'initialization' stamp: 'len 30/Jun/2026, 8:10:19 pm (UTC)'!
initialize
	super initialize.
	self horizontal: true! !

!InstrumentRackMorph methodsFor: 'initialization' stamp: 'len 26/Jun/2026, 6:30:24 pm (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	aTracker
		when: #cursorChanged send: #update to: self;
		when: #tracksChanged send: #update to: self.
	self update! !

!InstrumentRackMorph methodsFor: 'private' stamp: 'len 30/Jun/2026, 8:24:16 pm (UTC)'!
update
	| selectedRack |
	selectedRack := tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument rackMorph].
	selectedRack = scrollable ifFalse:
		[selectedRack ifNotNil: [self scrollable: selectedRack] ifNil: [self removeMorph: scrollable. scrollable := nil]].
	self redrawNeeded! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 25/Jul/2026, 6:18:18 am (UTC)'!
clipboardCopy
	(self activeHand keyboardFocus ifNil: [^ self])
		withAllOwnersDo: [:each| (each isKindOf: PatchableMorph) ifTrue: [ClipboardBuffer := each module copy. ^ self]]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 25/Jul/2026, 6:18:22 am (UTC)'!
clipboardCut
	(self activeHand keyboardFocus ifNil: [^ self])
		withAllOwnersDo: [:each| (each isKindOf: PatchableMorph) ifTrue: [ClipboardBuffer := each module copy. each delete. ^ self]]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 28/Jun/2026, 10:50:15 am (UTC)'!
clipboardPaste
	ClipboardBuffer ifNil: [^ self].
	self patchMorph ifNotNil: [:aPatchMorph|
		aPatchMorph addMorph: ClipboardBuffer copy patchable position: ((aPatchMorph internalizeFromWorld: self activeHand morphPosition))]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 19/Apr/2026, 3:52:50 pm (UTC)'!
duplicateInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Duplicate to instrument number' initialAnswer: '' verifying: [:s| (s allSatisfy: [:x| x isDigit]) and: [s asNumber between: 1 and: 255]] do: [:s| tracker instruments at: s asNumber put: instrument copy]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 21/Jun/2026, 7:26:14 am (UTC)'!
exportInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Instrument name' initialAnswer: (instrument label ifNil: ['']) do: [:newName|
		instrument label: newName.
		(self class package packageDirectory / 'data' / 'projects' // (newName, '.patch')) writeStreamDo: [:s| instrument writeOn: s].
		tracker triggerEvent: #instrumentLabelChanged]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 28/Jun/2026, 10:50:22 am (UTC)'!
fitPatchToBounds
	self patchMorph ifNotNil: [:aPatchMorph| aPatchMorph fitTo: (self localBounds insetBy: 8)]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 25/Jul/2026, 6:19:20 am (UTC)'!
focusOnModule: aModule
	| patchMorph patchable boundsInPatch boundsInZoomer zoomerCenter |
	patchMorph := self patchMorph ifNil: [^ self].
	patchable := (patchMorph patchableFor: aModule) ifNil: [^ self].
	patchable comeToFront.
	boundsInPatch := patchable fullBoundsInOwner.
	boundsInZoomer := patchMorph externalizeBoundingRectOf: boundsInPatch.
	zoomerCenter := extent / 2.0.
	patchMorph translateBy: zoomerCenter - boundsInZoomer center.
	"patchMorph scaleBy: ((extent x / boundsInZoomer width asFloat min: extent y / boundsInZoomer height asFloat) * 0.3) around: zoomerCenter"! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 21/Jun/2026, 7:26:20 am (UTC)'!
importInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Instrument name' initialAnswer: (instrument label ifNil: ['']) do: [:newName|
		instrument label: nil.
		(self class package packageDirectory / 'data' / 'projects' // (newName, '.patch')) readStreamDo: [:s| instrument readFrom: s binary].
		instrument label: newName.
		self fitPatchToBounds.
		tracker triggerEvent: #instrumentLabelChanged]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 4:20:07 pm (UTC)'!
moveInstrumentDown
	tracker selectedInstrumentNumber ifNotNil: [:anInteger| anInteger > 1 ifTrue: [tracker swapInstrument: anInteger with: anInteger - 1]]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 4:20:46 pm (UTC)'!
moveInstrumentUp
	tracker selectedInstrumentNumber ifNotNil: [:anInteger| anInteger < 255 ifTrue: [tracker swapInstrument: anInteger with: anInteger + 1]]! !

!InstrumentEditorMorph methodsFor: 'actions' stamp: 'len 21/Jun/2026, 7:26:25 am (UTC)'!
renameInstrument
	| instrument |
	instrument := tracker selectedInstrument ifNil: [^ self].
	self request: 'Instrument name' initialAnswer: (instrument label ifNil: ['']) do: [:newName| instrument label: newName. tracker triggerEvent: #instrumentLabelChanged]! !

!InstrumentEditorMorph methodsFor: 'drawing' stamp: 'len 6/Apr/2026, 12:01:18 pm (UTC)'!
drawOn: aCanvas
"	self patch ifNotNil: [aCanvas frameRectangle: self patch fullBoundsInOwner borderWidth: 2 color: Color white]. "! !

!InstrumentEditorMorph methodsFor: 'events' stamp: 'len 18/Jun/2026, 8:40:20 am (UTC)'!
handleCommandHotkey: anEvent
	anEvent keyCharacter = $c ifTrue: [self clipboardCopy. ^ true].
	anEvent keyCharacter = $x ifTrue: [self clipboardCut. ^ true].
	anEvent keyCharacter = $v ifTrue: [self clipboardPaste. ^ true].
	anEvent keyCharacter = $i ifTrue: [tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument inspect]. ^ true].
	^ false! !

!InstrumentEditorMorph methodsFor: 'events' stamp: 'len 21/Jul/2026, 6:04:30 am (UTC)'!
handleOptionHotkey: anEvent
	anEvent shiftPressed ifTrue:
		[anEvent isArrowDown ifTrue: [self moveInstrumentDown. ^ true].
		anEvent isArrowUp ifTrue: [self moveInstrumentUp. ^ true]].
	^ false! !

!InstrumentEditorMorph methodsFor: 'events' stamp: 'len 14/Jun/2026, 7:43:19 pm (UTC)'!
keyStroke: anEvent
	| c i |
	(anEvent primaryModifierPressed and: [self handleCommandHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	(anEvent secondaryModifierPressed and: [self handleOptionHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	anEvent keyCharacter = $` ifTrue: [anEvent wasHandled: true. self fitPatchToBounds. ^ self].
	anEvent keyCharacter = $\ ifTrue:
		[anEvent wasHandled: true.
		tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument track ifNotNil: [:aTrack|
			anEvent primaryModifierPressed ifTrue: [tracker toggleTrackSolo: (tracker tracks indexOf: aTrack)] ifFalse: [tracker toggleTrackMute: (tracker tracks indexOf: aTrack)]]].
		^ self].
	anEvent anyModifierKeyPressed ifFalse:
		[c := anEvent keyCharacter.
		c = $a ifTrue: [anEvent wasHandled: true. tracker selectedInstrument ifNotNil: [:anInstument| anInstument noteOff]. ^ self].
		(i := 'zsxdcvgbhnjmq2w3er5t6y7ui9o0p' indexOf: c) > 0 ifTrue:
			[anEvent wasHandled: true. tracker selectedInstrument ifNotNil: [:anInstument| anInstument noteOn: tracker selectedTrack inputCenterKey + i - 1]. ^ self]].
	^ super keyStroke: anEvent! !

!InstrumentEditorMorph methodsFor: 'initialization' stamp: 'len 26/Jun/2026, 6:30:33 pm (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	aTracker
		when: #cursorChanged send: #update to: self;
		when: #tracksChanged send: #update to: self.
	self update! !

!InstrumentEditorMorph methodsFor: 'private' stamp: 'len 28/Jun/2026, 10:49:21 am (UTC)'!
patchMorph
	^ submorphs detect: [:one| one isKindOf: PatchMorph] ifNone: []! !

!InstrumentEditorMorph methodsFor: 'private' stamp: 'len 28/Jun/2026, 10:50:44 am (UTC)'!
update
	| selectedPatch |
	selectedPatch := tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument patchMorph].
	selectedPatch = self patchMorph ifFalse:
		[self removeAllMorphs.
		selectedPatch ifNotNil: [self addMorph: selectedPatch]].
	self redrawNeeded! !

!ArrangerMorph methodsFor: 'actions' stamp: 'len 23/Feb/2026, 9:11:15 am (UTC)'!
clipboardCopy
	clipboard := selectionStart isNil
		ifTrue: [{tracker sequence at: tracker cursorPattern}]
		ifFalse: [((selectionStart min: tracker cursorPattern) to: (selectionStart max: tracker cursorPattern)) collect: [:i| tracker sequence at: i]]! !

!ArrangerMorph methodsFor: 'actions' stamp: 'len 21/Jul/2026, 4:05:07 pm (UTC)'!
clipboardCut
	| cursor |
	selectionStart isNil ifTrue: "cut the pattern at cursor"
		[clipboard := {tracker sequence at: tracker cursorPattern}.
		tracker deletePattern.
		^ self].
	cursor := tracker cursorPattern.
	clipboard := ((selectionStart min: cursor) to: (selectionStart max: cursor)) collect: [:i| tracker sequence at: i].
	(selectionStart max: cursor) to: (selectionStart min: cursor) by: -1 do: [:i| tracker deletePattern: i].
	selectionStart := nil.
	self redrawNeeded! !

!ArrangerMorph methodsFor: 'actions' stamp: 'len 23/Jul/2026, 2:36:51 pm (UTC)'!
clipboardPaste
	selectionStart := nil.
	self redrawNeeded.
	clipboard ifNotNil: [tracker insertSequence: (clipboard collect: [:each| each key -> each value])]! !

!ArrangerMorph methodsFor: 'actions' stamp: 'len 23/Jul/2026, 2:37:04 pm (UTC)'!
clipboardPasteNew
	selectionStart := nil.
	self redrawNeeded.
	clipboard ifNotNil: [tracker insertSequence: (clipboard collect: [:each| each key copy -> each value])]! !

!ArrangerMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 4:15:15 pm (UTC)'!
moveSelectedPatternsDown
	| start end |
	selectionStart
		ifNotNil: [start := selectionStart min: tracker cursorPattern.
			end := selectionStart max: tracker cursorPattern]
		ifNil: [start := end := tracker cursorPattern].
	end < tracker sequence size ifFalse: [^ self].
	end to: start by: -1 do: [:i| tracker swapPattern: i with: i + 1].
	tracker moveCursorPatternDown.
	selectionStart ifNotNil: [selectionStart := selectionStart + 1]! !

!ArrangerMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 4:14:04 pm (UTC)'!
moveSelectedPatternsUp
	| start end |
	selectionStart
		ifNotNil: [start := selectionStart min: tracker cursorPattern.
			end := selectionStart max: tracker cursorPattern]
		ifNil: [start := end := tracker cursorPattern].
	start > 1 ifFalse: [^ self].
	start to: end do: [:i| tracker swapPattern: i with: i - 1].
	tracker moveCursorPatternUp.
	selectionStart ifNotNil: [selectionStart := selectionStart - 1]! !

!ArrangerMorph methodsFor: 'drawing' stamp: 'len 19/Apr/2026, 9:56:56 am (UTC)'!
activeBounds
	"Answer a subrectangle of the bounds of the receiver that should preferably be kept visible inside a scroller."
	| blockHeight charWidth |
	charWidth := font widthOf: $X.
	blockHeight := charWidth * 3.
	^ 0 @ ((tracker cursorPattern - 1) * blockHeight) extent: self morphWidth @ blockHeight! !

!ArrangerMorph methodsFor: 'drawing' stamp: 'len 21/Jun/2026, 5:24:59 pm (UTC)'!
drawOn: aCanvas
	| x y s charWidth blockHeight blockWidth space cursorTrack cursorPattern patternNumbers oldPatternNumbers |
	charWidth := font widthOf: $X.
	blockHeight := charWidth * 3.
	blockWidth := charWidth / 2.0.
	space := charWidth/4.0.
	x := blockHeight + space.
	cursorTrack := tracker cursorTrack.
	"draw tracks background:"
	tracker tracks withIndexDo: [:track :i|
		aCanvas fillRectangle: (x @ 0 extent: blockWidth @ extent y) color: ((PatternEditorMorph trackColor: i) lightnessAndChromaBy: (i = cursorTrack ifTrue: [0.6] ifFalse: [0.4])).
		x := x + blockWidth + space].
	y := 0.
	"draw selection:"
	selectionStart ifNotNil:
		[aCanvas fillRectangle: (0 @ (((selectionStart min: tracker cursorPattern) - 1) * blockHeight) corner: self morphWidth @ (((selectionStart max: tracker cursorPattern)) * blockHeight)) color: PatternEditorMorph selectionColor].
	"draw sequence and cursor:"
	cursorPattern := tracker cursorPattern.
	patternNumbers := tracker sequencePatternNumbers.
	oldPatternNumbers := OrderedCollection new.
	1 to: tracker sequence size do: [:i| | p c |
		i = cursorPattern ifTrue:
			[self hasKeyboardFocus
				ifTrue: [aCanvas fillRectangle: (0@y extent: blockHeight @ blockHeight) color: (showCursor ifTrue: [PatternEditorMorph cursorColor] ifFalse: [PatternEditorMorph cursorColor alpha: 0.7])]
				ifFalse: [aCanvas fillRectangle: (0@y extent: blockHeight @ blockHeight) color: (PatternEditorMorph cursorColor alpha: 0.7)]].
		p := patternNumbers at: i.
		(oldPatternNumbers includes: p) ifFalse: [aCanvas frameRectangle: (4@(y+4) extent: blockHeight -8 @ (blockHeight - 8)) borderWidth: 1 color: Color white cornerRadius: 8].
		s := p printStringBase: 16 nDigits: 2.
		c := Color white.
		(oldPatternNumbers includes: p) ifTrue: [i = cursorPattern ifFalse: [c := Color veryLightGray]] ifFalse: [oldPatternNumbers add: p].
		aCanvas drawString: s at: blockHeight - (charWidth*2.5) @ (y+(charWidth/2.0)) font: font color: c.
		y := y + blockHeight].
	y := 0.
	"draw pattern blocks:"
	tracker sequence do: [:each|
		x := blockHeight + space.
		tracker tracks withIndexDo: [:track :i|
			(each key isEmptyTrack: i) ifFalse: [aCanvas fillRectangle: (x @ y extent: blockWidth @ blockHeight) color: ((each value at: i) ifTrue: [(PatternEditorMorph trackColor: i)] ifFalse: [Color black])].
			x := x + blockWidth + space].
		y := y + blockHeight].
	y := tracker cursorPattern - 1 * blockHeight + (tracker cursorLine * blockHeight / tracker selectedPattern length asFloat).
	"draw pattern line cursor and playhead:"
	aCanvas line: blockHeight + 1 @ y to: extent x - 4 @ y width: 3 color: Color veryVeryLightGray.
	tracker isPlaying ifTrue:
		[y := tracker playheadPattern - 1 * blockHeight + (tracker playheadLine * blockHeight / tracker playingPattern length asFloat).
		aCanvas line: blockHeight + 1 @ y to: extent x - 4 @ y width: 3 color: Color white]! !

!ArrangerMorph methodsFor: 'drawing' stamp: 'len 19/Feb/2026, 2:44:53 pm (UTC)'!
requiresVectorCanvas
	^ true! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 16/Jul/2026, 8:34:22 am (UTC)'!
handleCommandHotkey: anEvent
	anEvent keyCharacter = $c ifTrue: [self clipboardCopy. ^ true].
	anEvent keyCharacter = $x ifTrue: [self clipboardCut. ^ true].
	anEvent keyCharacter = $v ifTrue: [self clipboardPaste. ^ true].
	anEvent keyCharacter = $V ifTrue: [self clipboardPasteNew. ^ true].
	anEvent keyCharacter = $i ifTrue: [tracker selectedPattern ifNotNil: [:aPattern| aPattern inspect]. ^ true].
	^ false! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 19/Aug/2026, 6:16:38 am (UTC)'!
handleNavigationKey: anEvent
	selectionStart := nil.
	self redrawNeeded.
	anEvent isArrowUp ifTrue: [tracker moveCursorPatternUp].
	anEvent isArrowDown ifTrue: [tracker moveCursorPatternDown].
	anEvent isArrowLeft ifTrue: [tracker moveCursorTrackLeft].
	anEvent isArrowRight ifTrue: [tracker moveCursorTrackRight]! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 15/Jun/2026, 4:10:21 pm (UTC)'!
handleOptionHotkey: anEvent
	anEvent shiftPressed ifTrue:
		[anEvent isArrowUp ifTrue: [self moveSelectedPatternsUp. ^ true].
		anEvent isArrowDown ifTrue: [self moveSelectedPatternsDown. ^ true]].
	^ false! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 29/Jul/2026, 12:38:03 pm (UTC)'!
handleSelectionKey: anEvent
	selectionStart ifNil: [selectionStart := tracker cursorPattern. self redrawNeeded].
	anEvent isArrowUp ifTrue: [tracker moveCursorPatternUp].
	anEvent isArrowDown ifTrue: [tracker moveCursorPatternDown]! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 19/Aug/2026, 6:20:08 am (UTC)'!
handlesKeyboardFocus
	^ true! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 23/Jun/2026, 9:32:14 pm (UTC)'!
handlesMouseDown: anEvent
	^ anEvent mouseButton2Pressed or: [anEvent mouseButton1Pressed]! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 21/Jul/2026, 3:59:13 pm (UTC)'!
keyStroke: anEvent
	(anEvent secondaryModifierPressed and: [self handleOptionHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	(anEvent primaryModifierPressed and: [self handleCommandHotkey: anEvent]) ifTrue:
		[anEvent wasHandled: true.
		^ self].
	anEvent isArrow ifTrue:
		[anEvent wasHandled: true.
		anEvent shiftPressed ifTrue: [self handleSelectionKey: anEvent] ifFalse: [self handleNavigationKey: anEvent].
		^ self].
	^ super keyStroke: anEvent! !

!ArrangerMorph methodsFor: 'events' stamp: 'len 24/Feb/2026, 8:43:39 am (UTC)'!
keyboardFocusChange: aBoolean
	aBoolean ifTrue: [self startBlinking] ifFalse: [self stopBlinking].
	self redrawNeeded! !

!ArrangerMorph methodsFor: 'geometry' stamp: 'len 21/Feb/2026, 9:41:06 am (UTC)'!
minimumExtent
	| blockHeight blockWidth charWidth space |
	charWidth := font widthOf: $X.
	blockHeight := charWidth * 3.
	blockWidth := charWidth / 2.0.
	space := charWidth / 4.0.
	^ (blockWidth + space) * tracker tracks size + blockWidth + blockHeight @ (blockHeight * tracker sequence size)! !

!ArrangerMorph methodsFor: 'initialization' stamp: 'len 10/Mar/2026, 12:03:12 pm (UTC)'!
initialize
	super initialize.
	font := FontFamily familyName: 'JetBrains Mono NL' pointSize: 15.
	showCursor := true.
	pauseBlinking := false! !

!ArrangerMorph methodsFor: 'initialization' stamp: 'len 2/Jan/2026, 12:33:30 pm (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	aTracker when: #sequenceChanged send: #redrawNeeded to: self.
	aTracker when: #tracksChanged send: #update to: self.
	aTracker when: #cursorChanged send: #redrawNeeded to: self.
	aTracker when: #playheadChanged send: #redrawNeeded to: self.
	self update! !

!ArrangerMorph methodsFor: 'private' stamp: 'len 24/Feb/2026, 8:38:55 am (UTC)'!
onBlinkCursor
	"Blink the cursor"
	showCursor := showCursor not | pauseBlinking.
	pauseBlinking := false.
	"cursorRect ifNotNil: [ :r | self invalidateLocalRect: r]"
	self redrawNeeded! !

!ArrangerMorph methodsFor: 'private' stamp: 'len 24/Feb/2026, 8:38:48 am (UTC)'!
pauseBlinking
	"Show a solid cursor (non blinking) for a short while."
	pauseBlinking := true.
	"Show cursor right now if needed:"
	showCursor ifFalse:
		[showCursor := true.
		self redrawNeeded]! !

!ArrangerMorph methodsFor: 'private' stamp: 'len 24/Feb/2026, 8:38:27 am (UTC)'!
startBlinking
	"And show the cursor"
	pauseBlinking := true.
	"Start blinking in a short while"
	showCursor := true.
	self startStepping: #onBlinkCursor stepTime: 500! !

!ArrangerMorph methodsFor: 'private' stamp: 'len 24/Feb/2026, 8:38:38 am (UTC)'!
stopBlinking
	"And do not show cursor anymore."
	self stopStepping: #onBlinkCursor.
	"Hide cursor right now if needed:"
	showCursor ifFalse:
		[showCursor := false.
		self redrawNeeded]! !

!ArrangerMorph methodsFor: 'private' stamp: 'len 31/Dec/2025, 3:21:20 pm (UTC)'!
update
	self ensureMinimumExtent.
	self redrawNeeded! !

!MultitrackMeterMorph methodsFor: 'drawing' stamp: 'len 12/Feb/2026, 9:36:41 am (UTC)'!
colorForMeterValue: aNumber
	"White up to -12 dB, yellow from -12 dB to -3 dB, red over -3 dB."
	^ aNumber > 0.7 ifTrue: [Color redCathode] ifFalse: [aNumber > 0.25 ifTrue: [Color lemonPhosphor] ifFalse: [Color white]]! !

!MultitrackMeterMorph methodsFor: 'drawing' stamp: 'len 16/Jun/2026, 7:37:49 am (UTC)'!
drawOn: aCanvas
	| v x y leftMaster rightMaster peak |
	leftMaster := rightMaster := 0.0.
	tracker tracks withIndexDo: [:track :i|
		(v := track meterValue) > 0.001 ifTrue:
			[x := meterSpacing * (i-1) + leftMargin.
			y := self yForMeterValue: v.
			aCanvas fillRectangle: (x @ y corner: x + meterWidth @ extent y) color: (PatternEditorMorph trackColor: i).
			leftMaster := leftMaster + track meterLeftValue.
			rightMaster := rightMaster + track meterRightValue]].
	leftMaster := leftMaster * tracker level * 0.25. "internally we leave -12 dB of headroom"
	rightMaster := rightMaster * tracker level * 0.25.
	x := meterSpacing * (-2) + leftMargin.
	y := self yForMeterValue: rightMaster.
	aCanvas fillRectangle: (x @ y corner: x + meterWidth @ (extent y - 2)) color: (self colorForMeterValue: rightMaster).
	peak := tracker peakRight.
	y := self yForMeterValue: peak.
	aCanvas line: x @ y to: x + meterWidth @ y width: 2 color: (self colorForMeterValue: peak).
	x := meterSpacing * (-3) + leftMargin.
	y := self yForMeterValue: leftMaster.
	aCanvas fillRectangle: (x @ y corner: x + meterWidth @ (extent y - 2)) color: (self colorForMeterValue: leftMaster).
	peak := tracker peakLeft.
	y := self yForMeterValue: peak.
	aCanvas line: x @ y to: x + meterWidth @ y width: 2 color: (self colorForMeterValue: peak).
	y := extent y - 4 - (extent y - 8 * tracker level) max: 0.
	aCanvas strokeWidth: 1.0 color: Color white do: [aCanvas moveTo: x - 8 @ (y - 4); lineTo: x - 8 @ (y + 4); lineTo: x - 2 @ y; closePath]! !

!MultitrackMeterMorph methodsFor: 'drawing' stamp: 'len 24/Jan/2026, 7:11:16 am (UTC)'!
requiresVectorCanvas
	^ true ! !

!MultitrackMeterMorph methodsFor: 'drawing' stamp: 'len 25/Jan/2026, 12:46:18 pm (UTC)'!
yForMeterValue: aNumber
	"Answer the y coordinate for the given linear meter value (RMS or peak).
	We map it logarithmically to the height of the morph. We ignore values below -60 dB or over 0 dB."
	^ extent y - (extent y * (aNumber linearToDecibels + 60.0 max: 0.0) / 60.0) max: 0.0! !

!MultitrackMeterMorph methodsFor: 'events' stamp: 'len 24/Feb/2026, 10:31:47 am (UTC)'!
handlesKeyboardFocus
	^ false! !

!MultitrackMeterMorph methodsFor: 'events' stamp: 'len 24/Jan/2026, 7:14:37 am (UTC)'!
handlesMouseScroll: anEvent
	^ anEvent anyModifierKeyPressed not! !

!MultitrackMeterMorph methodsFor: 'events' stamp: 'len 6/Feb/2026, 10:57:18 am (UTC)'!
mouseScroll: anEvent localPosition: localEventPosition
	| step |
	step := 0.01.
	anEvent shiftPressed ifTrue: [step := step * 0.1].
	anEvent direction = #up ifTrue: [step := step negated] ifFalse: [anEvent direction = #down ifFalse: [^ self]].
	tracker level: tracker level + step.
	self showBalloon: tracker level linearToDecibelsPrintString! !

!MultitrackMeterMorph methodsFor: 'geometry' stamp: 'len 31/Dec/2025, 4:16:09 pm (UTC)'!
minimumExtent
	^ meterSpacing * (tracker tracks size + 1) @ 64! !

!MultitrackMeterMorph methodsFor: 'initialization' stamp: 'len 10/Mar/2026, 12:03:03 pm (UTC)'!
initialize
	| font charWidth |
	super initialize.
	font := FontFamily familyName: 'JetBrains Mono NL' pointSize: 15.
	charWidth := font widthOf: $X.
	leftMargin := charWidth * 3 + (charWidth/4.0).
	meterWidth := charWidth / 2.0.
	meterSpacing := meterWidth + (charWidth/4.0)! !

!MultitrackMeterMorph methodsFor: 'initialization' stamp: 'len 24/Jan/2026, 7:21:32 am (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	aTracker when: #tracksChanged send: #update to: self.
	aTracker when: #levelChanged send: #redrawNeeded to: self! !

!MultitrackMeterMorph methodsFor: 'stepping' stamp: 'len 18/Jan/2026, 7:01:38 pm (UTC)'!
step
	(tracker isPlaying or: [tracker tracks anySatisfy: [:any| any meterValue > 0.01]]) ifTrue: [self redrawNeeded]! !

!MultitrackMeterMorph methodsFor: 'stepping' stamp: 'len 18/Jan/2026, 6:59:32 pm (UTC)'!
stepTime
	^ 100! !

!MultitrackMeterMorph methodsFor: 'stepping' stamp: 'len 28/Dec/2025, 9:24:02 am (UTC)'!
wantsSteps
	^ true! !

!MultitrackMeterMorph methodsFor: 'private' stamp: 'len 31/Dec/2025, 3:43:38 pm (UTC)'!
update
	self ensureMinimumExtent.
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 11/Mar/2026, 7:45:09 am (UTC)'!
adjustFontSizeBy: anInteger
	| pointSizes |
	pointSizes := font family pointSizes select: [:each| each between: 6 and: 36]. "not too small, not too big"
	font := font family atPointSize: (pointSizes atPin: (pointSizes indexOf: font pointSize) + anInteger).
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 26/Jun/2026, 9:38:40 pm (UTC)'!
clipboardCopy
	| pattern |
	selectionLineStart ifNil: [ClipboardBuffer := {{(tracker selectedTrigger ifNil: [^ self]) copy}}. ^ self].
	pattern := tracker selectedPattern.
	ClipboardBuffer := self selectedLines collect: [:i| self selectedTracks collect: [:k| pattern track: k at: i]]! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 25/Jun/2026, 8:00:00 pm (UTC)'!
clipboardCut
	self clipboardCopy; deleteSelection! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 6/Aug/2026, 5:06:14 pm (UTC)'!
clipboardPaste
	| i0 k0 pattern |
	self unselectAll.
	pattern := tracker selectedPattern.
	k0 := tracker cursorTrack - 1.
	i0 := tracker cursorLine - 1.
	ClipboardBuffer ifNil: [^ self].
	tracker snapshot.
	ClipboardBuffer withIndexDo: [:line :i|
		line withIndexDo: [:trigger :k|
			(k0 + k <= tracker tracks size and: [i0 + i <= pattern length])
				ifTrue: [pattern track: k0 + k at: i0 + i put: trigger copy]]].
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 4/Jul/2026, 5:04:12 pm (UTC)'!
deleteSelection
	| pattern |
	tracker snapshot.
	pattern := tracker selectedPattern.
	selectionLineStart ifNil:
		[pattern track: tracker cursorTrack at: tracker cursorLine put: nil.
		self redrawNeeded.
		^ self].
	self selectedLines do: [:i|
		self selectedTracks do: [:k|
			pattern track: k at: i put: nil]].
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 27/Jul/2026, 4:22:42 pm (UTC)'!
moveCursorColumnLeft
	cursorPosition <= 2
		ifTrue:
			[tracker cursorTrack = 1 ifTrue: [^ self].
			tracker moveCursorTrackLeft.
			cursorPosition := self lastColumnPosition]
		ifFalse:
			[cursorPosition > 8
				ifTrue: [cursorPosition := cursorPosition - 6 // 3 - 1 * 3 + 6]
				ifFalse: [cursorPosition := #(1 1 1 3 3 4 4 4) at: cursorPosition]].
	self showFXBalloon.
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 27/Jul/2026, 4:20:18 pm (UTC)'!
moveCursorColumnRight
	cursorPosition >= self lastColumnPosition
		ifTrue:
			[tracker cursorTrack = tracker tracks size ifTrue: [^ self].
			cursorPosition := 1.
			tracker moveCursorTrackRight]
		ifFalse:
			[cursorPosition > 5
				ifTrue: [cursorPosition := cursorPosition - 6 // 3 + 1 * 3 + 6]
				ifFalse: [cursorPosition := #(3 3 4 6 6) at: cursorPosition]].
	self showFXBalloon.
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 27/Jul/2026, 12:19:12 pm (UTC)'!
moveCursorLeft
	cursorPosition = 1
		ifTrue:
			[tracker cursorTrack = 1 ifTrue: [^ self].
			tracker moveCursorTrackLeft.
			cursorPosition := self lastPosition]
		ifFalse:
			[cursorPosition := cursorPosition - 1].
	self showFXBalloon.
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 11:29:48 am (UTC)'!
moveCursorRight
	cursorPosition = self lastPosition
		ifTrue:
			[tracker cursorTrack = tracker tracks size ifTrue: [^ self].
			cursorPosition := 1.
			tracker moveCursorTrackRight]
		ifFalse:
			[cursorPosition := cursorPosition + 1].
	self showFXBalloon.
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 4:02:52 pm (UTC)'!
moveSelectedTracksLeft
	| trackStart trackEnd |
	selectionTrackStart
		ifNotNil: [trackStart := selectionTrackStart min: tracker cursorTrack.
			trackEnd := selectionTrackStart max: tracker cursorTrack]
		ifNil: [trackStart := trackEnd := tracker cursorTrack].
	trackStart > 1 ifFalse: [^ self].
	trackStart to: trackEnd do: [:i| tracker swapTrack: i with: i - 1].
	tracker moveCursorTrackLeft.
	selectionTrackStart ifNotNil: [selectionTrackStart := selectionTrackStart - 1]! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 15/Jun/2026, 4:03:57 pm (UTC)'!
moveSelectedTracksRight
	| trackStart trackEnd |
	selectionTrackStart
		ifNotNil: [trackStart := selectionTrackStart min: tracker cursorTrack.
			trackEnd := selectionTrackStart max: tracker cursorTrack]
		ifNil: [trackStart := trackEnd := tracker cursorTrack].
	trackEnd < tracker tracks size ifFalse: [^ self].
	trackEnd to: trackStart by: -1 do: [:i| tracker swapTrack: i with: i + 1].
	tracker moveCursorTrackRight.
	selectionTrackStart ifNotNil: [selectionTrackStart := selectionTrackStart + 1]! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 4/Jul/2026, 5:07:43 pm (UTC)'!
moveSelectedTriggersDown
	| pattern lineStart lineEnd trackStart trackEnd |
	pattern := tracker selectedPattern.
	selectionLineStart
		ifNotNil: [lineStart := selectionLineStart min: tracker cursorLine.
			lineEnd := selectionLineStart max: tracker cursorLine.
			trackStart := selectionTrackStart min: tracker cursorTrack.
			trackEnd := selectionTrackStart max: tracker cursorTrack]
		ifNil: [lineStart := lineEnd := tracker cursorLine.
			trackStart := trackEnd := tracker cursorTrack].
	lineEnd < pattern length ifFalse: [^ self].
	tracker snapshot.
	lineEnd to: lineStart by: -1 do: [:i|
		trackStart to: trackEnd do: [:k|
			pattern track: k swap: i with: i + 1]].
	tracker moveCursorLineDown.
	selectionLineStart ifNotNil: [selectionLineStart := selectionLineStart + 1]! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 4/Jul/2026, 5:07:53 pm (UTC)'!
moveSelectedTriggersUp
	| pattern lineStart lineEnd trackStart trackEnd |
	pattern := tracker selectedPattern.
	selectionLineStart
		ifNotNil: [lineStart := selectionLineStart min: tracker cursorLine.
			lineEnd := selectionLineStart max: tracker cursorLine.
			trackStart := selectionTrackStart min: tracker cursorTrack.
			trackEnd := selectionTrackStart max: tracker cursorTrack]
		ifNil: [lineStart := lineEnd := tracker cursorLine.
			trackStart := trackEnd := tracker cursorTrack].
	lineStart > 1 ifFalse: [^ self].
	tracker snapshot.
	lineStart to: lineEnd do: [:i|
		trackStart to: trackEnd do: [:k|
			pattern track: k swap: i with: i - 1]].
	tracker moveCursorLineUp.
	selectionLineStart ifNotNil: [selectionLineStart := selectionLineStart - 1]! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 9/Mar/2026, 12:44:57 pm (UTC)'!
playSelection
	| cursorPattern cursorLine cursorTrack |
	cursorPattern := tracker cursorPattern.
	cursorLine := tracker cursorLine.
	cursorTrack := tracker cursorTrack.
	selectionLineStart ifNil: [tracker playFrom: cursorPattern line: cursorLine to: cursorPattern line: cursorLine tracks: {cursorTrack}. ^ self].
	tracker playFrom: cursorPattern line: (selectionLineStart min: cursorLine) to: cursorPattern line: (selectionLineStart max: cursorLine) tracks: ((selectionTrackStart min: cursorTrack) to: (selectionTrackStart max: cursorTrack))! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 29/Jun/2026, 9:00:16 pm (UTC)'!
selectAll
	self selectedLines size = tracker selectedPattern length ifFalse: "extend selection to all lines of the pattern"
		[selectionTrackStart ifNil: [selectionTrackStart := tracker cursorTrack].
		selectionLineStart := 1.
		tracker moveCursorLineBottom.
		^ self redrawNeeded].
	self selectedTracks size = tracker tracks size ifFalse: "extend selection to all tracks"
		[selectionLineStart ifNil: [selectionLineStart := tracker cursorLine].
		selectionTrackStart := 1.
		tracker setCursorTrack: tracker tracks size.
		^ self redrawNeeded].
! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 26/Jun/2026, 9:42:28 pm (UTC)'!
selectedTriggersDo: aBlock
	| pattern |
	pattern := tracker selectedPattern.
	self selectedLines do: [:i|
		self selectedTracks do: [:k|
			(pattern track: k at: i) ifNotNil: aBlock]]! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 4/Jul/2026, 5:20:54 pm (UTC)'!
transposeSelectedTriggersBy: aNumber
	tracker snapshot.
	self selectedTriggersDo: [:each| each transposeBy: aNumber].
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'actions' stamp: 'len 28/Jul/2026, 8:04:21 am (UTC)'!
unselectAll
	"Unselect all."
	selectionLineStart ifNil: [^ self]. "no selection to unselect"
	selectionLineStart := selectionTrackStart := nil.
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'drawing' stamp: 'len 26/Jul/2026, 2:38:33 pm (UTC)'!
activeBounds
	"Answer a subrectangle of the bounds of the receiver that should preferably be kept visible inside a scroller.
	We use the bounds of the currently selected trigger, so when we move the cursor the current trigger is kept visible."
	| lineSpacing charWidth x y |
	lineSpacing := font lineSpacing.
	charWidth := font widthOf: $X.
	y := self morphHeight / 2.0.
	x := 2.5.
	1 to: tracker cursorTrack - 1 do: [:i| x := (tracker tracks at: i) widthInCharacters + 0.5 + x].
	^​ x * charWidth @ y extent: tracker selectedTrack widthInCharacters * charWidth @ lineSpacing! !

!PatternEditorMorph methodsFor: 'drawing' stamp: 'len 27/Jul/2026, 4:13:48 pm (UTC)'!
cursorRect
	| lineSpacing charWidth cursorWidth x y |
	lineSpacing := font lineSpacing.
	charWidth := font widthOf: $X.
	y := self morphHeight / 2.0.
	cursorWidth := cursorPosition = 3 ifTrue: [3] ifFalse: [1].
	x := 2.5 + cursorPosition - 1.
	1 to: tracker cursorTrack - 1 do: [:i| x := (tracker tracks at: i) widthInCharacters + 0.5 + x].
	cursorPosition > 2 ifTrue: [x := x + 0.5].
	cursorPosition > 3 ifTrue: [x := x + 2.5].
	cursorPosition > 5 ifTrue: [x := x + (cursorPosition - 6 // 3 + 1 * 0.5)].
	^​ x * charWidth @ y extent: cursorWidth * charWidth @ lineSpacing! !

!PatternEditorMorph methodsFor: 'drawing' stamp: 'len 15/Jun/2026, 11:59:45 am (UTC)'!
drawCursorOn: aCanvas
	| cursorRect |
	cursorRect := self cursorRect.
	aCanvas fillRectangle: (0 @ cursorRect top extent: self morphWidth @ cursorRect height) color: `Color white alpha: 0.1`.
	self hasKeyboardFocus ifFalse: [aCanvas frameRectangle: cursorRect borderWidth: 1 color: self class cursorColor. ^ self].
	aCanvas fillRectangle: cursorRect color: (showCursor ifTrue: [self class cursorColor] ifFalse: [self class cursorColor alpha: 0.7])! !

!PatternEditorMorph methodsFor: 'drawing' stamp: 'len 22/Feb/2026, 12:01:27 pm (UTC)'!
drawOn: aCanvas
	self drawTracksOn: aCanvas.
	self drawCursorOn: aCanvas.
	self drawPatternOn: aCanvas! !

!PatternEditorMorph methodsFor: 'drawing' stamp: 'len 5/Aug/2026, 7:25:32 am (UTC)'!
drawPatternOn: aCanvas
	| lineSpacing charWidth y unsetColor noteColor velocityColor pattern endLine middle startLine darkColor lightColor xLeft xRight beatColor |
	pattern := tracker selectedPattern.
	lineSpacing := font lineSpacing.
	charWidth := font widthOf: $X.
	unsetColor := self class unsetColor.
	noteColor := Color white.
	velocityColor := self class velocityColor.
	middle := self morphHeight / 2.0.
	startLine := tracker cursorLine - ((middle - self headerHeight) / lineSpacing) truncated max: 1.
	y := middle - (lineSpacing * (tracker cursorLine - startLine)).
	endLine := startLine + (self morphHeight - y / lineSpacing) truncated - 1 min: pattern length.
	xLeft := 1.
	xRight := self morphWidth - 1 - ((font widthOf: $X)*2) - xLeft.
	lightColor := Color veryLightGray.
	darkColor := Color lightGray.
	beatColor := pattern lpb > 1 ifTrue: [Color white alpha: 0.06] ifFalse: [Color transparent].
	"Draw playhead line:"
	(tracker isPlaying and: [tracker playheadPattern = tracker cursorPattern and: [tracker playheadLine between: startLine and: endLine]])
		ifTrue: [aCanvas fillRectangle: (0@(tracker playheadLine - startLine * lineSpacing + y) extent: extent x @ lineSpacing) color: self class playheadColor].
	"Draw selection:"
	selectionLineStart ifNotNil:
		[| sl0 sl1 st0 st1 x0 w |
		sl0 := selectionLineStart min: tracker cursorLine.
		sl1 := selectionLineStart max: tracker cursorLine.
		st0 := selectionTrackStart min: tracker cursorTrack.
		st1 := selectionTrackStart max: tracker cursorTrack.
		(sl0 <= endLine and: [sl1 >= startLine]) ifTrue:
			[sl0 := sl0 max: startLine.
			sl1 := sl1 min: endLine.
			x0 := ((1 to: st0 - 1) sum: [:i| (tracker tracks at: i) widthInCharacters + 0.5] ifEmpty: [0]) + 2.5 * charWidth.
			w := ((st0 to: st1) sum: [:i| (tracker tracks at: i) widthInCharacters + 0.5]) - 0.5 * charWidth.
			aCanvas fillRectangle:  (x0 @ ((sl0 - startLine) * lineSpacing + y) extent: w @ (lineSpacing * (sl1 - sl0) + lineSpacing)) color: self class selectionColor]].
	"Draw lines:"
	startLine to: endLine do: [:i|
		| s c x k |
		"Draw line offsets at left and right, and highlight lines at beats:"
		i - 1 \\ pattern lpb = 0
			ifTrue: [i = tracker cursorLine ifFalse: [aCanvas fillRectangle: (0@y extent: extent x @ lineSpacing) color: beatColor]. c := lightColor]
			ifFalse: [c := darkColor].
		s := i - 1 printStringBase: 16 nDigits: 2.
		aCanvas drawString: s at: xLeft @ y font: font color: c.
		aCanvas drawString: s at: xRight @ y font: font color: c.
		"Draw triggers:"
		k := 0.
		x := charWidth * 2.5.
		self
			pattern: pattern
			line: i
			instrumentDo: [:instrument|
				instrument ifNil: [s := '··'. c := unsetColor] ifNotNil: [:v| s := v printStringBase: 16 nDigits: 2. c := noteColor].
				aCanvas drawString: s at: x @ y font: font color: c.
				x := charWidth * 2.5 + x]
			noteDo: [:note|
				k := k + 1.
				note ifNil: [s := '···'. c := unsetColor] ifNotNil: [:v| s := v = -1 ifTrue: ['OFF'] ifFalse: [(tracker tracks at: k) noteStringFrom: v]. c := noteColor].
				aCanvas drawString: s at: x @ y font: font color: c.
				x := charWidth * 3.5 + x]
			velocityDo: [:velocity|
				velocity ifNil: [s := '··'. c := unsetColor] ifNotNil: [:v| s := v printStringBase: 16 nDigits: 2. c := velocityColor].
				aCanvas drawString: s at: x @ y font: font color: c.
				x := charWidth * 2.5 + x]
			effectsDo: [:fx|
				fx
					ifNil: [aCanvas drawString: '···' at: x @ y font: font color: unsetColor]
					ifNotNil:
						[| cmd |
						cmd := fx bitShift: -8.
						aCanvas drawString: (FXStrings atPin: cmd), ((fx bitAnd: 16rFF) printStringBase: 16 nDigits: 2) at: x @ y font: font color: (FXColors at: cmd ifAbsent: [unsetColor])].
				x := charWidth * 3.5 + x]
			emptyTriggersDo:
				["aCanvas image: emptyTriggerImage at: x @ y.
				x := trackWidth + x"
				k := k + 1.
				aCanvas drawString: '··' at: x @ y font: font color: unsetColor.
				x := charWidth * 2.5 + x.
				aCanvas drawString: '···' at: x @ y font: font color: unsetColor.
				x := charWidth * 3.5 + x.
				aCanvas drawString: '··' at: x @ y font: font color: unsetColor.
				x := charWidth * 2.5 + x.
				(tracker tracks at: k) numberOfFXColumns timesRepeat:
					[aCanvas drawString: '···' at: x @ y font: font color: unsetColor.
					x := charWidth * 3.5 + x]].
		y := y + lineSpacing]! !

!PatternEditorMorph methodsFor: 'drawing' stamp: 'len 27/Jul/2026, 7:18:43 am (UTC)'!
drawTracksOn: aCanvas
	| color textColor charWidth x mask headerLineThickness fittingTrackLabel highlightedTrackStart highlightedTrackEnd |
	charWidth := font widthOf: $X.
	headerLineThickness := 7.5. "originally was charWidth/2.0, but we don't want to change with the font size"
	x := charWidth * 2.5.
	mask := tracker selectedMask.
	selectionLineStart
		ifNotNil: [highlightedTrackStart := selectionTrackStart min: tracker cursorTrack.
			highlightedTrackEnd := selectionTrackStart max: tracker cursorTrack]
		ifNil: [highlightedTrackStart := highlightedTrackEnd := tracker cursorTrack].
	tracker tracks withIndexDo: [:track :i| | trackColor trackLabel trackWidth maxTrackLabelWidth |
		trackColor := self class trackColor: i.
		trackWidth := charWidth * track widthInCharacters.
		maxTrackLabelWidth := trackWidth - (labelMonoFont widthOfString: 'SM') - 2.
"		aCanvas fillRectangle: (x@0 extent: trackWidth @ extent y) color: (trackColor lightnessAndChromaBy: (i = tracker cursorTrack ifTrue: [0.25] ifFalse: [0.2]))."
"		aCanvas fillRectangle: (x@0 extent: trackWidth @ extent y) color: (trackColor darker: (i = tracker cursorTrack ifTrue: [0.54] ifFalse: [0.6]))."
"		aCanvas fillRectangle: (x@0 extent: trackWidth @ extent y) color: (trackColor alpha: (i = tracker cursorTrack ifTrue: [0.1] ifFalse: [0.02]))."
		(i between: highlightedTrackStart and: highlightedTrackEnd) ifTrue: [aCanvas fillRectangle: (x@0 extent: trackWidth @ extent y) color: (trackColor lightnessAndChromaBy: 0.25)].
		((mask at: i) and: [track enabled])
			ifTrue:
				[color := trackColor.
				textColor := Color white]
			ifFalse:
				[color := trackColor darker: 0.25.
				textColor := Color white darker: 0.25].
		aCanvas fillRectangle: (x @ 0 extent: trackWidth @ headerLineThickness) color: color.
		(tracker selectedInstrumentNumberAtTrack: i) ifNotNil: [:k|
			trackLabel := k printStringBase: 16 nDigits: 2.
			tracker instruments at: k ifPresent: [:anInstrument| anInstrument label ifNotNil: [:aString| trackLabel := trackLabel, ' ', aString]].
			fittingTrackLabel := trackLabel.
			[(labelFont widthOfString: fittingTrackLabel) > maxTrackLabelWidth] whileTrue: [trackLabel := trackLabel allButLast. fittingTrackLabel := trackLabel, '…'].
			aCanvas drawString: fittingTrackLabel at: x @ 8 font: labelFont color: textColor].
		x := x + trackWidth.
		track muted ifTrue: [aCanvas drawString: 'M' at: x - (labelMonoFont widthOf: $M) @ 8 font: labelMonoFont color: textColor].
		track soloed ifTrue: [aCanvas drawString: 'S' at: x - (labelMonoFont widthOfString: 'SM') - 1 @ 8 font: labelMonoFont color: textColor].
		x := x + (charWidth/2.0)].
	aCanvas fillRectangle: (x @ 0 corner: extent x @ headerLineThickness) color: Color darkGray! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 18/Jun/2026, 4:17:59 pm (UTC)'!
aboutToBeGrabbedBy: aHand
	^ MovingHelperMorph new target: self; offset: (self owner internalizeFromWorld: aHand morphPosition) - self morphPosition! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 31/Jul/2026, 12:08:47 pm (UTC)'!
handleCommandHotkey: anEvent
	"Font size:"
	anEvent keyCharacter = $- ifTrue: [self adjustFontSizeBy: -1. ^ true].
	anEvent keyCharacter = $= ifTrue: [self adjustFontSizeBy: 1. ^ true].
	"Inspecting:"
	anEvent keyCharacter = $i ifTrue: [tracker selectedTrigger ifNotNil: [:aTrigger| aTrigger inspect]. ^ true].
	"Clipboard:"
	anEvent keyCharacter = $c ifTrue: [self clipboardCopy. ^ true].
	anEvent keyCharacter = $x ifTrue: [self clipboardCut. ^ true].
	anEvent keyCharacter = $v ifTrue: [self clipboardPaste. ^ true].
	anEvent keyCharacter = $a ifTrue: [self selectAll. ^ true].
	"Undo/Redo:"
	anEvent keyCharacter = $z ifTrue: [tracker undo. ^ true].
	(anEvent keyCharacter = $Z or: [anEvent keyCharacter = $y]) ifTrue: [tracker redo. ^ true].
	^ false! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 27/Jul/2026, 4:11:31 pm (UTC)'!
handleInputKey: anEvent
	| c i |
"	(tracker followPlayhead and: [tracker isPlaying]) ifTrue: [^ false]." "avoid input if following playhead"
	anEvent isBackspace ifTrue:
		[selectionLineStart isNil
			ifTrue: [tracker snapshot; selectedTriggerAt: cursorPosition put: nil. self redrawNeeded]
			ifFalse: [self deleteSelection].
		^ true].
	anEvent keyCharacter = $] ifTrue: [self transposeSelectedTriggersBy: tracker selectedTrack tuning size. ^ true].
	anEvent keyCharacter = $[ ifTrue: [self transposeSelectedTriggersBy: tracker selectedTrack tuning size negated. ^ true].
	anEvent keyCharacter = $} ifTrue: [self transposeSelectedTriggersBy: 1. ^ true].
	anEvent keyCharacter = ${ ifTrue: [self transposeSelectedTriggersBy: -1. ^ true].
	cursorPosition = 3 ifTrue: "notes"
		[c := anEvent keyCharacter.
		c = $a ifTrue:
			[tracker snapshot; selectedTriggerAt: cursorPosition put: -1. "note off"
			tracker moveCursorLineDown: editStep.
			^ true].
		(i := 'zsxdcvgbhnjmq2w3er5t6y7ui9o0p' indexOf: c) > 0 ifTrue:
			[tracker snapshot; selectedTriggerAt: cursorPosition put: tracker selectedTrack inputCenterKey + i - 1.
			tracker moveCursorLineDown: editStep.
			^ true].
		^ false].
	(cursorPosition > 5 and: [cursorPosition - 6 \\ 3 = 0]) ifTrue: "FX commands"
		[(Trigger allFXCommandCharacters includes: (c := anEvent keyCharacter asUppercase)) ifTrue:
			[tracker snapshot; selectedTriggerAt: cursorPosition put: c codePoint.
			self moveCursorRight.
			^ true].
		^ false].
	(i := '0123456789ABCDEF' indexOf: anEvent keyCharacter asUppercase) > 0 ifTrue:
		[tracker snapshot; selectedTriggerAt: cursorPosition put: i - 1.
		(#(2 5) includes: cursorPosition) ifTrue:
			[cursorPosition := cursorPosition - 1.
			self showFXBalloon.
			tracker moveCursorLineDown: editStep.
			^ true].
		(#(8 11) includes: cursorPosition) ifTrue:
			[cursorPosition := cursorPosition - 2.
			self showFXBalloon.
			tracker moveCursorLineDown: editStep.
			^ true].	
		self moveCursorRight.
		^ true].
	^ false! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 3/Jul/2026, 9:05:57 am (UTC)'!
handleKeyStroke: anEvent
	(anEvent secondaryModifierPressed and: [self handleOptionHotkey: anEvent]) ifTrue: [^ true].
	(anEvent primaryModifierPressed and: [self handleCommandHotkey: anEvent]) ifTrue: [^ true].
	(anEvent shiftPressed and: [anEvent isArrow]) ifTrue: [self handleSelectionKey: anEvent. ^ true].
	anEvent isReturnKey ifTrue: [tracker isPlaying ifTrue: [tracker stop] ifFalse: [tracker loop: anEvent secondaryModifierPressed. self playSelection]. ^ true].
	anEvent isNavigation ifTrue: [self handleNavigationKey: anEvent. ^ true].
	(anEvent anyModifierKeyPressed not and: [self handleInputKey: anEvent]) ifTrue: [^ true].
	^ false! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 28/Jul/2026, 8:01:49 am (UTC)'!
handleNavigationKey: anEvent
	self unselectAll.
	anEvent isArrowUp ifTrue: [tracker moveCursorLineUp].
	anEvent isArrowDown ifTrue: [tracker moveCursorLineDown].
	anEvent isArrowLeft ifTrue:
		[anEvent primaryModifierPressed ifTrue: [self moveCursorColumnLeft] ifFalse: [self moveCursorLeft]].
	anEvent isArrowRight ifTrue:
		[anEvent primaryModifierPressed ifTrue: [self moveCursorColumnRight] ifFalse: [self moveCursorRight]].
	anEvent isPageUp ifTrue: [tracker moveCursorBeatUp].
	anEvent isPageDown ifTrue: [tracker moveCursorBeatDown].
	anEvent isHome ifTrue: [tracker moveCursorLineTop].
	anEvent isEnd ifTrue: [tracker moveCursorLineBottom]! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 3/Jul/2026, 9:07:04 am (UTC)'!
handleOptionHotkey: anEvent
	anEvent shiftPressed ifTrue:
		[anEvent isArrowUp ifTrue: [self moveSelectedTriggersUp. ^ true].
		anEvent isArrowDown ifTrue: [self moveSelectedTriggersDown. ^ true].
		anEvent isArrowLeft ifTrue: [self moveSelectedTracksLeft. ^ true].
		anEvent isArrowRight ifTrue: [self moveSelectedTracksRight. ^ true]].
	anEvent isArrowUp ifTrue: [tracker moveCursorPatternUp. ^ true].
	anEvent isArrowDown ifTrue: [tracker moveCursorPatternDown. ^ true].
	anEvent isArrowLeft ifTrue: [tracker moveCursorTrackLeft. ^ true].
	anEvent isArrowRight ifTrue: [tracker moveCursorTrackRight. ^ true].
	anEvent isBackspace ifTrue: [tracker deleteTrigger. self redrawNeeded. ^ true].
	anEvent isEsc ifTrue: [tracker toggleFollowPlayhead. ^ true].
	self flag: #fixme. "!!!!!! only works on macos"
	anEvent secondaryModifierPressed ifTrue:
		[anEvent keyCharacter = $µ "opt-m on macos" ifTrue: [tracker toggleTrackMute. ^ true].
		anEvent keyCharacter = $ß "opt-s on macos"ifTrue: [tracker toggleTrackSolo. ^ true]].
	^ false! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 29/Jul/2026, 12:37:51 pm (UTC)'!
handleSelectionKey: anEvent
	selectionLineStart ifNil:
		[selectionLineStart := tracker cursorLine.
		selectionTrackStart := tracker cursorTrack.
		self redrawNeeded].
	(anEvent isArrowUp and: [tracker cursorLine > 1]) ifTrue: [tracker moveCursorLineUp].
	(anEvent isArrowDown and: [tracker cursorLine < tracker selectedPattern length]) ifTrue: [tracker moveCursorLineDown].
	anEvent isArrowLeft ifTrue: [tracker moveCursorTrackLeft].
	anEvent isArrowRight ifTrue: [tracker moveCursorTrackRight]! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 19/Aug/2026, 6:19:20 am (UTC)'!
handlesKeyboardFocus
	^ true! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 18/Jun/2026, 4:59:04 pm (UTC)'!
handlesMouseDown: anEvent
	^ anEvent mouseButton2Pressed or: [anEvent mouseButton1Pressed]! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 15/Jun/2026, 1:45:29 pm (UTC)'!
handlesMouseScroll: anEvent
	^ #(up down) identityIncludes: anEvent direction! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 10/Jan/2026, 4:03:58 pm (UTC)'!
keyStroke: anEvent
	(self handleKeyStroke: anEvent) ifTrue: [anEvent wasHandled: true. ^ self].
	^ super keyStroke: anEvent! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 9/Jan/2026, 8:20:32 am (UTC)'!
keyboardFocusChange: aBoolean
	aBoolean ifTrue: [self startBlinking] ifFalse: [self stopBlinking].
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 28/Jul/2026, 8:02:12 am (UTC)'!
mouseButton1Down: aMouseButtonEvent localPosition: localEventPosition
	| charWidth x |
	charWidth := font widthOf: $X.
	x := localEventPosition x - (charWidth * 2.5).
	x < 0.0 ifTrue: [^ self].
	tracker tracks withIndexDo: [:each :i|
		x := x - (each widthInCharacters + 0.5 * charWidth).
		x < 0.0 ifTrue:
			[tracker setCursorTrack: i.
			^ self unselectAll]]! !

!PatternEditorMorph methodsFor: 'events' stamp: 'len 28/Jul/2026, 8:02:21 am (UTC)'!
mouseScroll: anEvent localPosition: localEventPosition
	self unselectAll.
	anEvent direction = #up ifTrue: [tracker moveCursorLineUp] ifFalse: [tracker moveCursorLineDown]! !

!PatternEditorMorph methodsFor: 'geometry' stamp: 'len 26/Jul/2026, 2:42:11 pm (UTC)'!
minimumExtent
	| w |
	w := tracker tracks sum: [:each| each widthInCharacters + 0.5].
	^ (font widthOf: $X) * (w + 4.5) @ (font lineSpacing * 16)! !

!PatternEditorMorph methodsFor: 'initialization' stamp: 'len 30/Jul/2026, 7:52:52 pm (UTC)'!
initialize
	super initialize.
"	font := FontFamily familyName: 'impulseBig' pointSize: 18."
	font := FontFamily familyName: 'JetBrains Mono NL' pointSize: 18.
"	font := FontFamily familyName: 'Commodore 64 Angled' pointSize: 14."
	labelFont := FontFamily defaultFamilyPointSize: 15.
	labelMonoFont := FontFamily familyName: 'JetBrains Mono NL' pointSize: 15.
	editStep := 1.
	showCursor := true.
	pauseBlinking := false! !

!PatternEditorMorph methodsFor: 'initialization' stamp: 'len 22/Jun/2026, 9:20:55 am (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	cursorPosition := 1.
	aTracker when: #sequenceChanged send: #redrawNeeded to: self.
	aTracker when: #tracksChanged send: #updateTracks to: self.
	aTracker when: #cursorChanged send: #updateCursor to: self.
	aTracker when: #playheadChanged send: #redrawNeeded to: self.
	aTracker when: #instrumentLabelChanged send: #redrawNeeded to: self.
	aTracker when: #selectedTrackTuningChanged: send: #redrawNeeded to: self.
	self updateTracks! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 30/Dec/2025, 6:25:06 pm (UTC)'!
headerHeight
	^ labelFont lineSpacing + 8! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 27/Jul/2026, 12:20:44 pm (UTC)'!
lastColumnPosition
	"Answer the start of the last column of this track."
	^ self lastPosition - (tracker selectedTrack numberOfFXColumns > 0 ifTrue: [2] ifFalse: [1])! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 27/Jul/2026, 12:07:29 pm (UTC)'!
lastPosition
	^ tracker selectedTrack numberOfFXColumns * 3 + 5! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 15/Jun/2026, 12:02:36 pm (UTC)'!
onBlinkCursor
	"Blink the cursor"
	showCursor := showCursor not | pauseBlinking.
	pauseBlinking := false.
	"cursorRect ifNotNil: [ :r | self invalidateLocalRect: r]"
	self redrawNeeded! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 27/Jul/2026, 12:07:29 pm (UTC)'!
pattern: pattern line: anInteger instrumentDo: instrumentBlock noteDo: noteBlock velocityDo: velocityBlock effectsDo: effectsBlock emptyTriggersDo: emptyBlock
	pattern blocks with: tracker tracks do: [:each :track|
		each
			ifNil: [emptyBlock value]
			ifNotNil:
				[(each at: anInteger)
					ifNil: [emptyBlock value]
					ifNotNil: [:trigger|
						instrumentBlock value: trigger instrument.
						noteBlock value: trigger note.
						velocityBlock value: trigger velocity.
						1 to: track numberOfFXColumns do: [:i|
							| fx |
							fx := trigger effects at: i ifAbsent: [].
							fx = 0 ifTrue: [fx := nil].
							effectsBlock value: fx]]]]! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 9/Jan/2026, 8:18:12 am (UTC)'!
pauseBlinking
	"Show a solid cursor (non blinking) for a short while."
	pauseBlinking := true.
	"Show cursor right now if needed:"
	showCursor ifFalse:
		[showCursor := true.
		self redrawNeeded
		"cursorRect ifNotNil: [:r| self invalidateLocalRect: r]"]! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 26/Jun/2026, 9:36:08 pm (UTC)'!
selectedLines
	| cursorLine |
	cursorLine := tracker cursorLine.
	selectionLineStart ifNil: [^ {cursorLine}].
	^ (selectionLineStart min: cursorLine) to: (selectionLineStart max: cursorLine)! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 26/Jun/2026, 9:37:04 pm (UTC)'!
selectedTracks
	| cursorTrack |
	cursorTrack := tracker cursorTrack.
	selectionTrackStart ifNil: [^ {cursorTrack}].
	^ (selectionTrackStart min: cursorTrack) to: (selectionTrackStart max: cursorTrack)! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 26/Jul/2026, 1:26:34 pm (UTC)'!
showFXBalloon
	self deleteBalloon.
	cursorPosition > 5 ifFalse: [^ self].
	tracker selectedTrigger ifNotNil: [:trigger|
		(trigger effects at: cursorPosition - 6 // 3 + 1 ifAbsent: [])
			ifNotNil: [:fx| (Trigger descriptionForFX: fx) ifNotNil: [:text| self showBalloon: text at: self cursorRect bottomRight + (28 @ 0)]]]! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 9/Jan/2026, 8:35:08 am (UTC)'!
startBlinking
	"And show the cursor"
	pauseBlinking := true.
	"Start blinking in a short while"
	showCursor := true.
	self startStepping: #onBlinkCursor stepTime: 500! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 9/Jan/2026, 8:33:48 am (UTC)'!
stopBlinking
	"And do not show cursor anymore."
	self stopStepping: #onBlinkCursor.
	"Hide cursor right now if needed:"
	showCursor ifFalse:
		[showCursor := false.
		self redrawNeeded
		"textCursorRect ifNotNil: [ :r | self invalidateLocalRect: r ]"]! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 28/Jul/2026, 8:02:57 am (UTC)'!
updateCursor
	(tracker followPlayhead and: [tracker isPlaying]) ifTrue: [self unselectAll].
	self redrawNeeded.
	self showFXBalloon! !

!PatternEditorMorph methodsFor: 'private' stamp: 'len 27/Jul/2026, 4:12:40 pm (UTC)'!
updateTracks
	cursorPosition := cursorPosition min: self lastPosition.
	self ensureMinimumExtent.
	self redrawNeeded! !

!PatternEditorMorph class methodsFor: 'class initialization' stamp: 'len 5/Aug/2026, 3:30:17 pm (UTC)'!
initialize
	"
	self initialize
	"
	super initialize.
	"Load the monospaced font we need for the pattern editor:"
	(FontFamily availableFamilies includesKey: 'JetBrains Mono NL') ifFalse:
		[TrueTypeFontFamily readAllTrueTypeFontsIn: DirectoryEntry trueTypeFontsDirectory / 'JetBrainsMono'].
	TrackColors := (0 to: 6) collect: [:i| Color okl: 0.7 c: 0.4 h: i * (360.0 / 7) + 10.0]. "roygbiv shifted 10°"
	(FXStrings := (1 to: 255) collect: [:i| (Character codePoint: i) asString])
		at: $^ codePoint put: '↑';
		at: $_ codePoint put: '↓'.
	FXColors := Array new: 255 withAll: Color red "self unsetColor".
	"Velocity/Volume:"
	'<>!!' do: [:c| FXColors at: c codePoint put: self velocityColor].
	"Pitch:"
	'G^_' do: [:c| FXColors at: c codePoint put: (Color okl: 0.85 c: 0.3 h: 80 "340")].
	"Samples:"
	'@$/\~+-%' do: [:c| FXColors at: c codePoint put: (Color okl: 0.85 c: 0.3 h: 220)].
	"Controls:"
	'0123456789' do: [:c| FXColors at: c codePoint put: (Color okl: 0.85 c: 0.3 h: 160 "80")].
	"Video:"
	'ABX' do: [:c| FXColors at: c codePoint put: (Color okl: 0.85 c: 0.3 h: 340 "160")].
	"Other:"
	'#F*?&' do: [:c| FXColors at: c codePoint put: Color white] "note color"! !

!PatternEditorMorph class methodsFor: 'colors' stamp: 'len 22/Feb/2026, 12:58:39 pm (UTC)'!
cursorColor
	^ Color redCathode! !

!PatternEditorMorph class methodsFor: 'colors' stamp: 'len 13/Jun/2026, 4:44:14 pm (UTC)'!
playheadColor
	^ self cursorColor alpha: 0.3! !

!PatternEditorMorph class methodsFor: 'colors' stamp: 'len 27/Jul/2026, 6:03:26 pm (UTC)'!
selectionColor
	^ self cursorColor alpha: 0.3! !

!PatternEditorMorph class methodsFor: 'colors' stamp: 'len 10/Jun/2026, 10:03:41 am (UTC)'!
trackColor: anInteger
	^ TrackColors atWrap: anInteger! !

!PatternEditorMorph class methodsFor: 'colors' stamp: 'len 30/Jul/2026, 6:16:05 pm (UTC)'!
unsetColor
	^ Color gray! !

!PatternEditorMorph class methodsFor: 'colors' stamp: 'len 8/Jul/2026, 10:02:57 am (UTC)'!
velocityColor
	^ `Color okl: 0.85 c: 0.3 h: 120`! !

!PlaybackStatusMorph methodsFor: 'drawing' stamp: 'len 9/Jul/2026, 11:13:44 am (UTC)'!
drawOn: aCanvas
	aCanvas drawString: '▶' at: 4 @ 0 font: font color: (tracker isPlaying ifTrue: [Color white] ifFalse: [Color lightGray])
		
"	tracker isPlaying ifTrue:
		[aCanvas drawString: '▶' '◼' at: 4 @ 0 font: font color: PatchMorph waveformColor]"! !

!PlaybackStatusMorph methodsFor: 'events' stamp: 'len 24/Feb/2026, 10:31:36 am (UTC)'!
handlesKeyboardFocus
	^ false! !

!PlaybackStatusMorph methodsFor: 'geometry' stamp: 'len 22/Jun/2026, 11:23:36 am (UTC)'!
minimumExtent
	^ (font widthOfString: 'X') *  1.5 @ font lineSpacing! !

!PlaybackStatusMorph methodsFor: 'initialization' stamp: 'len 22/Jun/2026, 11:23:50 am (UTC)'!
initialize
	super initialize.
	font := FontFamily defaultFamilyPointSize: 15.
"	font := FontFamily familyName: 'JetBrains Mono NL' pointSize: 15."
	self morphExtent: self minimumExtent! !

!PlaybackStatusMorph methodsFor: 'initialization' stamp: 'len 22/Jun/2026, 11:58:31 am (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	tracker when: #playingStatusChanged send: #redrawNeeded to: self! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 7/Aug/2026, 8:52:07 am (UTC)'!
addMarkerAtCursor
	cursorPosition ifNil: [^ self].
	cursorPosition := 	sample zeroCrossingAfter: cursorPosition - 1.
	"If a marker is too close to the new marker, replace it:"
	sample markers: ((sample markers select: [:m| (m - cursorPosition) abs > 128]) copyWith: cursorPosition) sorted.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 8/Aug/2026, 7:23:46 am (UTC)'!
clipboardCopy
	ClipboardBuffer := sample copy: (self selectedInterval ifNil: [^ self])! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 8/Aug/2026, 7:28:19 am (UTC)'!
clipboardCut
	ClipboardBuffer := sample cut: (self selectedInterval ifNil: [^ self]).
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 8/Aug/2026, 7:28:14 am (UTC)'!
clipboardInsert
	sample insert: (ClipboardBuffer ifNil: [^ self]) at: (cursorPosition ifNil: [^ self]) truncated.
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 8/Aug/2026, 7:28:24 am (UTC)'!
clipboardPaste
	sample paste: (ClipboardBuffer ifNil: [^ self]) at: (cursorPosition ifNil: [^ self]) truncated.
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 3/Aug/2026, 8:51:40 am (UTC)'!
cursorSlice
	"Answer the slice number at the cursor. This is first marker to the left of the cursor, or 0.
	If the sample is not sliced answer nil."
	cursorPosition ifNil: [^ nil].
	sample markers ifEmpty: [^ nil].
	cursorPosition < sample markers first ifTrue: [^ 0].
	^​ sample markers findLast: [:x| x <= cursorPosition]! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 4/Aug/2026, 6:56:40 pm (UTC)'!
cursorSliceEnd
	cursorPosition ifNil: [^ nil].
	sample markers ifEmpty: [^ sample buffer size - 1].
	cursorPosition > sample markers last ifTrue: [^ sample buffer size - 1].
	^​ sample markers at: (sample markers findFirst: [:x| x > cursorPosition]) ifAbsent: [^ sample buffer size - 1]! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 4/Aug/2026, 6:49:08 pm (UTC)'!
cursorSliceStart
	cursorPosition ifNil: [^ nil].
	sample markers ifEmpty: [^ 0].
	cursorPosition < sample markers first ifTrue: [^ 0].
	^​ sample markers at: (sample markers findLast: [:x| x <= cursorPosition])! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 2/Aug/2026, 11:30:06 am (UTC)'!
cursorStepSize
	sample ifNil: [^ 0].
	^ mode = #zoom ifTrue: [4] ifFalse: [sample buffer size // 256 max: 1]! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 8/Aug/2026, 7:46:02 am (UTC)'!
fadeSelectionFrom: startGain to: endGain
	sample fade: (self selectedInterval ifNil: [^ self]) from: startGain to: endGain.
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 1/Aug/2026, 7:25:33 pm (UTC)'!
moveCursorLeft
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	cursorPosition := (cursorPosition ifNil: [0]) - self cursorStepSize max: 0.
	cursorPosition := sample zeroCrossingBefore: cursorPosition.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 7/Aug/2026, 8:52:30 am (UTC)'!
moveCursorRight
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	cursorPosition := (cursorPosition ifNil: [0]) + self cursorStepSize min: sample buffer size - 1.
	cursorPosition := sample zeroCrossingAfter: cursorPosition.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 2/Aug/2026, 7:29:41 am (UTC)'!
moveCursorSliceLeft
	| i |
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	sample ifNil: [^ self].
	cursorPosition ifNil: [cursorPosition := sample buffer size - 1].
	sample markers ifEmpty: [^ self].
	i := (sample markers findLast: [:x| x < cursorPosition]).
	cursorPosition := sample markers at: i ifAbsent: [0].
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 30/Jul/2026, 2:23:58 pm (UTC)'!
moveCursorSliceRight
	| i |
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	sample ifNil: [^ self].
	cursorPosition ifNil: [cursorPosition := 0].
	sample markers ifEmpty: [^ self].
	i := (sample markers findLast: [:x| x <= cursorPosition]).
	i < sample markers size ifFalse: [^ self].
	cursorPosition := sample markers at: i + 1.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 1/Aug/2026, 7:10:46 pm (UTC)'!
normalizeAmplitude
	sample ifNil: [^ self].
	sample normalizeAmplitude.
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 2/Aug/2026, 3:52:48 pm (UTC)'!
removeDCOffset
	sample ifNil: [^ self].
	sample removeDCOffset.
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 4/Aug/2026, 6:34:09 pm (UTC)'!
removeMarkerLeftToCursor
	| i |
	cursorPosition ifNil: [^ self].
	sample markers ifEmpty: [^ self].
	i := (sample markers findLast: [:x| x <= cursorPosition]).
	sample markers: (sample markers copyFrom: 1 to: i - 1), (sample markers copyFrom: i + 1 to: sample markers size).
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 4/Aug/2026, 6:51:17 pm (UTC)'!
selectAll
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	((sample markers includes: selectionPositionStart) and: [sample markers includes: cursorPosition])
		ifTrue:
			[selectionPositionStart := 1.
			cursorPosition := sample buffer size - 1]
		ifFalse:
			[selectionPositionStart := self cursorSliceEnd.
			cursorPosition := self cursorSliceStart].
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 3/Aug/2026, 8:59:20 am (UTC)'!
setLoopToSelection
	| p0 p1 |
	cursorPosition ifNil: [^ self].
	selectionPositionStart ifNil: [^ self].
	p0 := cursorPosition min: selectionPositionStart.
	p1 := cursorPosition max: selectionPositionStart.
	sample loopStart: p0 loopEnd: p1.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 1/Aug/2026, 7:43:33 pm (UTC)'!
setTriggerOffsetToCursor
	| trigger |
	trigger := tracker selectedTrigger ifNil: [^ self].
	trigger offset ifNotNil:
		[trigger offset: cursorPosition / (sample buffer size - 1.0).
		tracker triggerEvent: #sequenceChanged]! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 1/Aug/2026, 7:47:08 pm (UTC)'!
setTriggerSliceToCursor
	| trigger i |
	trigger := tracker selectedTrigger ifNil: [^ self].
	(i := sample markers findLast: [:x| x <= cursorPosition]) = 0 ifTrue: [^ self].
	trigger slice ifNotNil:
		[trigger slice: i.
		tracker triggerEvent: #sequenceChanged]! !

!SampleEditorMorph methodsFor: 'actions' stamp: 'len 6/Aug/2026, 10:41:57 am (UTC)'!
trimSilence
	sample ifNil: [^ self].
	"make sure nothing is playing:"
	tracker stop.
	self stop.
	sample trimSilence.
	needsRecomputingImage := true.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 9/Aug/2026, 3:06:37 pm (UTC)'!
drawFullOn: aCanvas
	| x n h beatDuration beatWidth sampleDuration markerColor cursorColor |
	sample ifNil: [^ self].
	aCanvas image: self waveformImage at: 0 @ 0.
	h := extent y // 2.
	aCanvas line: 0 @ h to: extent x @ h width: 1 color: (Color white alpha: 0.3).
	markerColor := SampleMorph markerColor.
	cursorColor := PatternEditorMorph cursorColor.
	n := sample buffer size.
	"Draw beat grid:"
	beatDuration := 60.0 / tracker bpm.
	sampleDuration := sample duration.
	sampleDuration / beatDuration <= 16 ifTrue:
		[beatWidth := extent x / sampleDuration * beatDuration.
		aCanvas strokeWidth: 1.5 color: (Color white alpha: 0.5) dashedStrokeBits: 2r1110000000 do:
			[x := 0.0.
			[(x := x + beatWidth) < extent x] whileTrue:
				[aCanvas moveTo: x @ 1; lineTo: x @ (extent y - 1)]]].
	"Draw loop:"
	sample loopLength > 0 ifTrue:
		[| x0 |
		x0 := sample loopStart / n * extent x.
		x := sample loopEnd / n * extent x.
		aCanvas strokeWidth: 1 color: SampleMorph loopColor do:
			[aCanvas moveTo: x0 @ 0; lineTo: x0 @ extent y.
			aCanvas moveTo: x @ 0; lineTo: x @ extent y].
		aCanvas fillRectangle: (x0 @ 1 corner: x @ (extent y - 1)) color: (SampleMorph loopColor alpha: 0.15)].
	"Draw markers:"
	sample markers isEmpty ifFalse:
		[| x0 startSlice |
		aCanvas strokeWidth: 1 color: markerColor do:
			[sample markers do: [:p|
				x := p asFloat / n * extent x.
				aCanvas moveTo: x @ 1; lineTo: x @ (extent y - 1)]].
		cursorPosition ifNotNil:
			[startSlice := (sample markers findLast: [:m| m <= cursorPosition]).
			x0 := (sample markers at: startSlice ifAbsent: [0]) / n * extent x.
			x := (sample markers at: startSlice + 1 ifAbsent: [n - 1]) / n * extent x.
			aCanvas fillRectangle: (x0 @ 1 corner: x @ (extent y - 1)) color: (markerColor alpha: 0.1).
			self drawMarkerLabel: ((startSlice ifNil: [0]) printStringBase: 16 nDigits: 2) on: aCanvas at: x0 color: markerColor]].
	"Draw playhead:"
	playheadPosition ifNotNil: [:p|
		x := p - 1.0 /  n * extent x.
		aCanvas line: x @ 1 to: x @ (extent y - 1) width: 2 color: Color white.
		self drawVideoOn: aCanvas at: x position: playheadPosition width: 128].
	playingSample ifNotNil:
		[x := playingSample position - 1.0 / n * extent x.
		aCanvas line: x @ 1 to: x @ (extent y - 1) width: 2 color: Color white.
		self drawVideoOn: aCanvas at: x position: playingSample position width: 128].
	"Draw selection and cursor:"
	(cursorPosition notNil and: [tracker isPlayingFollowingPlayhead not]) ifTrue:
		[x := cursorPosition - 1.0 /  n * extent x.
		selectionPositionStart ifNotNil: [:s|
			| x0 |
			x0 := s - 1.0 / n * extent x.
			aCanvas fillRectangle: ((x min: x0) @ 1 corner: (x max: x0) @ (extent y - 1)) color: PatternEditorMorph selectionColor.
			aCanvas line: x0 @ 1 to: x0 @ (extent y - 1) width: (self hasKeyboardFocus ifTrue: [2] ifFalse: [1]) color: cursorColor].
		self drawMarkerOn: aCanvas at: x width: ((showCursor and: [self hasKeyboardFocus]) ifTrue: [2] ifFalse: [1]) color: cursorColor.
		self drawMarkerTopLabel: ((cursorPosition - 1.0 / n * 255.0) truncated printStringBase: 16 nDigits: 2) on: aCanvas at: x color: cursorColor.
		self drawVideoOn: aCanvas at: x position: cursorPosition width: 128]! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 2/Aug/2026, 6:26:20 pm (UTC)'!
drawMarkerLabel: aString on: aCanvas at: x0 color: aColor
	| labelWidth x |
	labelWidth := (font widthOfString: aString) + 8.
	x := x0.
	x + labelWidth < extent x ifFalse: [x := x - labelWidth].
"	aCanvas fillRectangle: (x @ (extent y - font lineSpacing) extent: labelWidth @ font lineSpacing) color: aColor.
"	aCanvas drawString: aString at: x + 4 @ (extent y - font lineSpacing) font: font color: aColor! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 2/Aug/2026, 6:36:27 pm (UTC)'!
drawMarkerOn: aCanvas at: x width: width color: aColor
	aCanvas line: x @ 1 to: x @ (extent y - 1) width: width color: aColor! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 2/Aug/2026, 6:48:35 pm (UTC)'!
drawMarkerTopLabel: aString on: aCanvas at: x0 color: aColor
	| labelWidth x |
	labelWidth := (font widthOfString: aString) + 8.
	x := x0 - labelWidth.
	x < 1 ifTrue: [x := x + labelWidth].
	aCanvas fillRectangle: (x @ 0 extent: labelWidth @ font lineSpacing) color: aColor.
	aCanvas drawString: aString at: x + 4 @ 1 font: font color: Color white! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 30/Jul/2026, 1:13:35 pm (UTC)'!
drawOn: aCanvas
	(mode = #zoom and: [cursorPosition notNil])
		ifTrue: [self drawZoomedOn: aCanvas]
		ifFalse: [self drawFullOn: aCanvas]! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 3/Aug/2026, 4:40:11 pm (UTC)'!
drawVideoOn: aCanvas at: x0 position: pos width: width
	| x height |
	sample class = Video ifFalse: [^ self].
	x := x0 - width - 4.
	x > 0 ifFalse: [x := x0 + 4].
	height := sample height * width asFloat / sample width.
	aCanvas
		intoLocation: (AffineTransformation transformFrom: (0 @ 0 extent: sample width @ sample height) to: (x @ (extent y - height - font lineSpacing) extent: width @ height))
		do: [aCanvas image: sample strip at: 0 @ 0 sourceRect: (0 @ (sample lineAtPosition: pos) extent: sample width @ sample height)]! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 4/Aug/2026, 10:28:27 am (UTC)'!
drawZoomedOn: aCanvas
	| h n m x y p s startPosition endPosition |
	sample ifNil: [^ self].
	h := extent y // 2.
	aCanvas line: 0 @ h to: extent x @ h width: 1 color: (Color white alpha: 0.3).
	n := sample buffer size.
	m := extent x // 2.
	startPosition := cursorPosition - m max: 1.
	endPosition := cursorPosition + m min: n.
	"Draw waveform:"
	aCanvas strokeWidth: 1.5 color: PatchMorph sampleWaveformColor do:
		[aCanvas moveTo: startPosition - cursorPosition + m @ (h - (((sample buffer at: startPosition) min: 1.0 max: -1.0) * h)).
		startPosition to: endPosition do: [:i|
			x := i - cursorPosition + m.
			y := h - (((sample buffer at: i) min: 1.0 max: -1.0) * h).
			aCanvas lineTo: x @ y]].
	"Draw loop:"
	sample loopLength > 0 ifTrue:
		[| x0 x1 |
		x0 := sample loopStart - cursorPosition + m.
		x1 := sample loopEnd - cursorPosition + m.
		(x0 between: 0 and: extent x)
			ifTrue: [aCanvas line: x0 @ 0 to: x0 @ extent y width: 1 color: SampleMorph loopColor]
			ifFalse: [x0 := x0 > m ifTrue: [extent x - 1] ifFalse: [1]].
		(x1 between: 0 and: extent x)
			ifTrue: [aCanvas line: x1 @ 0 to: x1 @ extent y width: 1 color: SampleMorph loopColor]
			ifFalse: [x1 := x1 > m ifTrue: [extent x - 1] ifFalse: [1]].
		x0 = x1 ifFalse: [aCanvas fillRectangle: (x0 @ 1 corner: x1 @ (extent y - 1)) color: (SampleMorph loopColor alpha: 0.15)]].
	"Draw markers:"
	sample markers isEmpty ifFalse:
		[aCanvas strokeWidth: 1 color: SampleMorph markerColor do:
			[sample markers do: [:i|
				(i between: startPosition and: endPosition) ifTrue:
					[x := i - cursorPosition + m.
					aCanvas moveTo: x @ 1; lineTo: x @ (extent y - 1)]]]].
	"Draw cursor:"
	tracker isPlayingFollowingPlayhead
		ifTrue:
			[aCanvas line: m @ 1 to: m @ (extent y - 1) width: 2 color: Color white]
		ifFalse:
			[aCanvas line: m @ 1 to: m @ (extent y - 1) width: (showCursor ifTrue: [2] ifFalse: [1]) color: PatternEditorMorph cursorColor.
			p := cursorPosition - 1.0 / n * 255.0.
			s := (p truncated printStringBase: 16 nDigits: 2), ':', (((p - p truncated) * 256) truncated printStringBase: 16 nDigits: 2).
			self drawMarkerTopLabel: s on: aCanvas at: m color: PatternEditorMorph cursorColor].
			self drawVideoOn: aCanvas at: m position: cursorPosition width: 128.
	selectionPositionStart ifNotNil: [:i|
			| x0 |
			x0 := i - cursorPosition + m min: extent x - 1 max: 1.
			aCanvas fillRectangle: ((m min: x0) @ 1 corner: (m max: x0) @ (extent y - 1)) color: PatternEditorMorph selectionColor.
			aCanvas line: x0 @ 1 to: x0 @ (extent y - 1) width: (self hasKeyboardFocus ifTrue: [2] ifFalse: [1]) color: PatternEditorMorph cursorColor].
! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 2/Aug/2026, 1:06:05 pm (UTC)'!
markerColor
	^ PatchMorph waveformColor! !

!SampleEditorMorph methodsFor: 'drawing' stamp: 'len 29/Jul/2026, 1:59:47 pm (UTC)'!
requiresVectorCanvas
	^ true! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 4/Aug/2026, 6:42:30 pm (UTC)'!
click: anEvent localPosition: localEventPosition
	mode = #full ifFalse: [^ self].
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	anEvent shiftPressed
		ifTrue: [selectionPositionStart ifNil: [selectionPositionStart := cursorPosition]]
		ifFalse: [selectionPositionStart := nil].
	cursorPosition := ((sample ifNil: [^ self]) buffer size - 1.0 * localEventPosition x / extent x) truncated + 1.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 4/Aug/2026, 6:43:25 pm (UTC)'!
doubleClick: anEvent localPosition: localEventPosition
	self click: anEvent localPosition: localEventPosition.
	self selectAll! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 8/Aug/2026, 7:25:37 am (UTC)'!
handleCommandHotkey: anEvent
	"Inspecting:"
	anEvent keyCharacter = $i ifTrue: [sample inspect. ^ true].
	"Clipboard:"
	anEvent keyCharacter = $c ifTrue: [self clipboardCopy. ^ true].
	anEvent keyCharacter = $x ifTrue: [self clipboardCut. ^ true].
	anEvent keyCharacter = $v ifTrue: [self clipboardPaste. ^ true].
	anEvent keyCharacter = $V ifTrue: [self clipboardInsert. ^ true].
	anEvent keyCharacter = $a ifTrue: [self selectAll. ^ true].
	^ false! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 8/Aug/2026, 7:39:46 am (UTC)'!
handleKeyStroke: anEvent
	sample ifNil: [^ false].
"	(anEvent secondaryModifierPressed and: [self handleOptionHotkey: anEvent]) ifTrue: [^ true]."
	(anEvent primaryModifierPressed and: [self handleCommandHotkey: anEvent]) ifTrue: [^ true].
	anEvent isReturnKey ifTrue: [self isPlaying ifTrue: [self stop] ifFalse: [self playLooping: anEvent secondaryModifierPressed]. ^ true].
	anEvent isNavigation ifTrue: [self handleNavigationKey: anEvent. ^ true].
"	(anEvent anyModifierKeyPressed not and: [self handleInputKey: anEvent]) ifTrue: [^ true]."
	anEvent isBackspace ifTrue: [self removeMarkerLeftToCursor. ^ true].
	anEvent keyCharacter = $| ifTrue: [self addMarkerAtCursor. ^ true].
	anEvent keyCharacter = $@ ifTrue: [self setTriggerOffsetToCursor. ^ true].
	anEvent keyCharacter = $$ ifTrue: [self setTriggerSliceToCursor. ^ true].
	anEvent keyCharacter = $/ ifTrue: [self fadeSelectionFrom: 0.5 to: 1.0. ^ true].
	anEvent keyCharacter = $÷ "opt-/" ifTrue: [self fadeSelectionFrom: 2.0 to: 1.0. ^ true].
	anEvent keyCharacter = $\ ifTrue: [self fadeSelectionFrom: 1.0 to: 0.5. ^ true].
	anEvent keyCharacter = $« "opt-\" ifTrue: [self fadeSelectionFrom: 1.0 to: 2.0. ^ true].
	^ false! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 3/Aug/2026, 6:45:01 pm (UTC)'!
handleNavigationKey: anEvent
	anEvent isArrowUp ifTrue: [mode := #zoom. self redrawNeeded. ^ self].
	anEvent isArrowDown ifTrue: [mode := #full. self redrawNeeded. ^ self].
	(anEvent shiftPressed and: [anEvent primaryModifierPressed not])
		ifTrue: [selectionPositionStart ifNil: [selectionPositionStart := cursorPosition]]
		ifFalse: [selectionPositionStart := nil].
	anEvent isArrowLeft ifTrue:
		[anEvent primaryModifierPressed ifTrue: [anEvent shiftPressed ifTrue: [self moveSliceMarkerLeft] ifFalse: [self moveCursorSliceLeft]] ifFalse: [self moveCursorLeft]].
	anEvent isArrowRight ifTrue:
		[anEvent primaryModifierPressed ifTrue: [anEvent shiftPressed ifTrue: [self moveSliceMarkerRight] ifFalse: [self moveCursorSliceRight]] ifFalse: [self moveCursorRight]].
	anEvent isHome ifTrue: [cursorPosition := 0].
	anEvent isEnd ifTrue: [cursorPosition := sample buffer size - 1].
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 30/Jul/2026, 1:02:23 pm (UTC)'!
handleSelectionKey: anEvent
	anEvent isArrowLeft ifTrue:
		[anEvent primaryModifierPressed ifTrue: [self moveCursorSliceLeft] ifFalse: [self moveCursorLeft]].
	anEvent isArrowRight ifTrue:
		[anEvent primaryModifierPressed ifTrue: [self moveCursorSliceRight] ifFalse: [self moveCursorRight]].
	anEvent isHome ifTrue: [cursorPosition := 0. self redrawNeeded].
	anEvent isEnd ifTrue: [cursorPosition := sample buffer size - 1. self redrawNeeded]! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 30/Jul/2026, 11:52:37 am (UTC)'!
handlesMouseDown: anEvent
	^ anEvent mouseButton2Pressed or: [anEvent mouseButton1Pressed]! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 30/Jul/2026, 9:54:58 am (UTC)'!
keyStroke: anEvent
	(self handleKeyStroke: anEvent) ifTrue: [anEvent wasHandled: true. ^ self].
	^ super keyStroke: anEvent! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 3/Aug/2026, 7:23:10 am (UTC)'!
keyboardFocusChange: aBoolean
	aBoolean ifTrue: [self startBlinking] ifFalse: [mode := #full. self stopBlinking].
"	title visible: aBoolean."
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'events' stamp: 'len 4/Aug/2026, 6:41:22 pm (UTC)'!
mouseButton1Down: anEvent localPosition: localEventPosition
	mode = #full ifFalse: [^ self].
	anEvent hand
		waitForClicksOrDragOrSimulatedMouseButton2:  self
		event:  anEvent 
		clkSel: #click:localPosition:
		clkNHalf:  nil
		dblClkSel:  #doubleClick:localPosition:
		dblClkNHalfSel:  nil
		tripleClkSel:  nil
		dragSel: #dragEvent:localPosition:

"
	tracker isPlaying ifTrue: [tracker followPlayhead: false].
	anEvent shiftPressed
		ifTrue: [selectionPositionStart ifNil: [selectionPositionStart := cursorPosition]]
		ifFalse: [selectionPositionStart := nil].
	cursorPosition := ((sample ifNil: [^ self]) buffer size - 1.0 * localEventPosition x / extent x) truncated + 1.
	self redrawNeeded
"! !

!SampleEditorMorph methodsFor: 'geometry' stamp: 'len 3/Aug/2026, 7:26:05 am (UTC)'!
extentChanged: oldExtent
	needsRecomputingImage := true.
	flap position: 8 @ (self morphHeight - flap morphHeight - 2.0) extent: flap minimumExtent! !

!SampleEditorMorph methodsFor: 'initialization' stamp: 'len 29/Jul/2026, 7:22:47 am (UTC)'!
defaultExtent
	^ `384 @ 92`! !

!SampleEditorMorph methodsFor: 'initialization' stamp: 'len 7/Aug/2026, 6:55:34 am (UTC)'!
initialize
	super initialize.
	needsRecomputingImage := true.
	needsUpdate := true.
	mode := #full.
	showCursor := true.
	pauseBlinking := false.
	font := FontFamily defaultFamilyPointSize: 15.
	self addMorph: (title := LabelMorph contents: '' fontSize: 12 emphasis: 1) position: 4 @ 8.
	title color: (Color white alpha: 0.5)"; hide".
	flap := RoundedLinearLayoutMorph newColumn gap: 10; padding: 4 @ 8; color: (Color darkGray alpha: 0.5).
	self addMorph: flap.
"	flap hide"! !

!SampleEditorMorph methodsFor: 'initialization' stamp: 'len 6/Aug/2026, 10:30:52 am (UTC)'!
outOfWorld: aWorld
	self stop.
	super outOfWorld: aWorld! !

!SampleEditorMorph methodsFor: 'menus' stamp: 'len 3/Aug/2026, 8:57:58 am (UTC)'!
getMenu
	| menu |
	menu := MenuMorph new defaultTarget: self.
	menu
		add: 'Normalize' action: #normalizeAmplitude;
		add: 'Trim silence' action: #trimSilence;
		add: 'Remove DC offset' action: #removeDCOffset.
	selectionPositionStart ifNotNil:
		[menu add: 'Loop selection' action: #setLoopToSelection].
	^ menu! !

!SampleEditorMorph methodsFor: 'stepping' stamp: 'len 4/Aug/2026, 10:11:10 am (UTC)'!
step
	| position |
	needsUpdate ifTrue: [self update].
	sample ifNil: [^ self].
	((position := sample position) = playheadPosition and: [playingSample isNil]) ifTrue: [^ self].
	playheadPosition := position.
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'stepping' stamp: 'len 29/Jul/2026, 12:03:42 pm (UTC)'!
stepTime
	^ 10 "too fast?"! !

!SampleEditorMorph methodsFor: 'stepping' stamp: 'len 29/Jul/2026, 7:18:43 am (UTC)'!
wantsSteps
	^ true! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 2/Aug/2026, 11:51:33 am (UTC)'!
onBlinkCursor
	"Blink the cursor"
	showCursor := showCursor not | pauseBlinking.
	pauseBlinking := false.
	"cursorRect ifNotNil: [ :r | self invalidateLocalRect: r]"
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 2/Aug/2026, 11:51:38 am (UTC)'!
pauseBlinking
	"Show a solid cursor (non blinking) for a short while."
	pauseBlinking := true.
	"Show cursor right now if needed:"
	showCursor ifFalse:
		[showCursor := true.
		self redrawNeeded]! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 8/Aug/2026, 7:22:34 am (UTC)'!
selectedInterval
	| p0 p1 |
	cursorPosition ifNil: [^ nil].
	selectionPositionStart ifNil: [^ cursorPosition truncated to: cursorPosition truncated].
	p0 := (cursorPosition min: selectionPositionStart) truncated.
	p1 := (cursorPosition max: selectionPositionStart) truncated.
	^ p0 to: p1! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 4/Aug/2026, 7:49:44 am (UTC)'!
setTracker: aTracker
	tracker := aTracker.
	aTracker
		when: #cursorChanged send: #updateNeeded to: self;
		when: #tracksChanged send: #updateNeeded to: self;
		when: #bpmChanged: send: #redrawNeeded to: self;
		when: #playingStatusChanged send: #stop to: self.
	needsRecomputingImage := true.
	self update! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 2/Aug/2026, 11:52:14 am (UTC)'!
startBlinking
	"And show the cursor"
	pauseBlinking := true.
	"Start blinking in a short while"
	showCursor := true.
	self startStepping: #onBlinkCursor stepTime: 500! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 2/Aug/2026, 11:51:44 am (UTC)'!
stopBlinking
	"And do not show cursor anymore."
	self stopStepping: #onBlinkCursor.
	"Hide cursor right now if needed:"
	showCursor ifFalse:
		[showCursor := false.
		self redrawNeeded]! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 9/Aug/2026, 3:06:47 pm (UTC)'!
update
	| newSample |
	needsUpdate := false.
	newSample := tracker selectedInstrument ifNotNil: [:anInstrument| anInstrument patch modules detect: [:one| one isKindOf: Sample] ifNone: []].
	sample = newSample ifFalse:
		[sample ifNotNil: [(sample controls at: #pitch) removeActionsWithReceiver: self].
		sample := newSample.
		cursorPosition := nil.
		title contents: (sample ifNil: [''] ifNotNil: [sample label ifNil: ['']]).
		flap removeAllMorphs.
		sample ifNotNil:
			[| panel |
			panel := sample panel.
"			panel addMorph: (ToggleButtonMorph new state: sample loop; when: #changed: send: #loop: to: sample; receive: #state: from: sample when: #loopChanged:; icon: TrackerWindow repeatIcon; setBalloonText: 'Loop')."
			flap addMorph: panel.
			(sample controls at: #pitch) when: #changed: send: #redrawNeeded to: self].
		needsRecomputingImage := true].
	playheadPosition := sample ifNotNil: [sample position].
	tracker isPlayingFollowingPlayhead ifTrue: [cursorPosition := playheadPosition].
	self redrawNeeded! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 30/Jul/2026, 12:51:30 pm (UTC)'!
updateNeeded
	needsUpdate := true! !

!SampleEditorMorph methodsFor: 'private' stamp: 'len 3/Aug/2026, 7:17:14 am (UTC)'!
waveformImage
	| h canvas i step waveform frame color |
	needsRecomputingImage ifFalse: [^ waveformImage].
	needsRecomputingImage := false.
	(waveformImage isNil or: [waveformImage extent ~= extent]) ifTrue: [waveformImage := Form extent: extent depth: Display depth].
	waveformImage fillBlack.
	h := waveformImage extent y / 2.0.
	waveform := sample buffer.
	step := waveform size asFloat / waveformImage width.
	canvas := BitBltCanvas onForm: waveformImage.
	frame := Float32Array new: step truncated.
	color := PatchMorph sampleWaveformColor.
	i := 1.
	0 to: waveformImage extent x - 1 do: [:x|
		| r peakColor |
		frame replaceFrom: 1 to: frame size with: waveform startingAt: i truncated.
		(r := frame rms) > 0.0 ifTrue:
			[peakColor := color darker alpha: (r * 2.5 min: 0.8 max: 0.35).
			canvas line: x @ (h - ((frame max max: 0.0) * h)) to: x @ (h - ((frame min min: 0.0) * h)) width: 1 color: peakColor].
"			peak := frame peak.
			canvas line: x @ (h - (peak * h)) to: x @ (h + (peak * h)) width: 1 color: peakColor]."
		i := i + step].
"	canvas drawString: (sample label ifNil: ['']) at: 4 @ 8 font: ((FontFamily defaultFamilyPointSize: 12) emphasized: 1) color: (Color white alpha: 0.5)."
	^ waveformImage! !

!SampleEditorMorph methodsFor: 'playing' stamp: 'len 4/Aug/2026, 7:48:10 am (UTC)'!
isPlaying
	^ AudioPlayer isPlaying: self! !

!SampleEditorMorph methodsFor: 'playing' stamp: 'len 4/Aug/2026, 10:46:50 am (UTC)'!
playLooping: aBoolean
	self isPlaying ifTrue: [^ self].
	cursorPosition ifNil: [^ self].
	playingSample := sample copy.
	selectionPositionStart
		ifNil: [playingSample setPosition: cursorPosition]
		ifNotNil:
			[| start |
			start := cursorPosition min: selectionPositionStart.
			playingSample setPosition: start.
			aBoolean ifTrue: [playingSample loopStart: start loopEnd: (selectionPositionStart max: cursorPosition)]].
	playingSample gateOn; update.
	AudioPlayer startPlaying: self! !

!SampleEditorMorph methodsFor: 'playing' stamp: 'len 4/Aug/2026, 10:04:32 am (UTC)'!
playSampleCount: n into: anAudioBuffer startingAt: startIndex
	^ (playingSample ifNil: [^ 0]) playSampleCount: n into: anAudioBuffer startingAt: startIndex! !

!SampleEditorMorph methodsFor: 'playing' stamp: 'len 6/Aug/2026, 10:40:23 am (UTC)'!
stop
	self isPlaying ifFalse: [^ self].
	AudioPlayer stopPlaying: self.
	playingSample := nil! !

!VideoMonitorMorph methodsFor: 'as yet unclassified' stamp: 'len 6/Jul/2026, 8:38:33 am (UTC)'!
drawOn: aCanvas
	| frame scale |
"	aCanvas fillRectangle: self localBounds color: Color black."
	frame := tracker currentVideoFrame.
	scale := extent y / frame height asFloat.
	aCanvas
		intoLocation: (AffineTransformation withScale: scale position: extent x // 2 - (frame width * scale // 2) @ 0)
		do: [aCanvas image: frame at: 0 @ 0]! !

!VideoMonitorMorph methodsFor: 'as yet unclassified' stamp: 'len 5/Jul/2026, 7:24:09 pm (UTC)'!
requiresVectorCanvas
	^ true! !

!VideoMonitorMorph methodsFor: 'as yet unclassified' stamp: 'len 5/Jul/2026, 1:33:59 pm (UTC)'!
setTracker: aTracker
	tracker := aTracker! !

!VideoMonitorMorph methodsFor: 'as yet unclassified' stamp: 'len 5/Jul/2026, 4:23:10 pm (UTC)'!
step
	self redrawNeeded! !

!VideoMonitorMorph methodsFor: 'as yet unclassified' stamp: 'len 5/Jul/2026, 4:22:36 pm (UTC)'!
stepTime
	^ 30! !

!VideoMonitorMorph methodsFor: 'as yet unclassified' stamp: 'len 5/Jul/2026, 4:22:46 pm (UTC)'!
wantsSteps
	^ true! !

!Instrument methodsFor: 'accessing' stamp: 'len 24/Jul/2026, 12:59:27 pm (UTC)'!
label
	^ patch label! !

!Instrument methodsFor: 'accessing' stamp: 'len 24/Jul/2026, 12:59:50 pm (UTC)'!
label: aString
	patch label: aString! !

!Instrument methodsFor: 'accessing' stamp: 'len 27/Jun/2026, 9:35:46 pm (UTC)'!
meterLeftValue
	^ patch meterLeftValue! !

!Instrument methodsFor: 'accessing' stamp: 'len 27/Jun/2026, 9:35:56 pm (UTC)'!
meterRightValue
	^ patch meterRightValue! !

!Instrument methodsFor: 'accessing' stamp: 'len 27/Jun/2026, 9:36:05 pm (UTC)'!
meterValue
	^ patch meterValue! !

!Instrument methodsFor: 'accessing' stamp: 'len 28/Jun/2026, 9:12:07 am (UTC)'!
patch
	^ patch! !

!Instrument methodsFor: 'accessing' stamp: 'len 24/Jul/2026, 5:10:10 pm (UTC)'!
patchMorph
	^ patchMorph ifNil: [patchMorph := PatchMorph new patch: patch]! !

!Instrument methodsFor: 'accessing' stamp: 'len 30/Jun/2026, 8:09:44 pm (UTC)'!
rackMorph
	^ rackMorph ifNil: [rackMorph := RackMorph new patch: patch]! !

!Instrument methodsFor: 'accessing' stamp: 'len 29/Jun/2026, 7:53:22 am (UTC)'!
setOwnerTrack: aTrack
	track ifNotNil: [track forgetInstrument].
	track := aTrack.
	track ifNotNil: [patch buses: track tracker buses; enabled: track enabled]! !

!Instrument methodsFor: 'accessing' stamp: 'len 3/Jan/2026, 8:40:08 am (UTC)'!
track
	^ track! !

!Instrument methodsFor: 'accessing' stamp: 'len 6/Jul/2026, 11:12:44 am (UTC)'!
video
	^ patch video! !

!Instrument methodsFor: 'copying' stamp: 'len 19/Apr/2026, 3:49:45 pm (UTC)'!
copy
	| buffers |
	buffers := OrderedCollection new.
	^ self class new readFromJson: (self asJsonWithBuffers: buffers) buffers: buffers! !

!Instrument methodsFor: 'initialization' stamp: 'len 24/Jul/2026, 5:08:59 pm (UTC)'!
initialize
	patch := Patch new.
	patchMorph := PatchMorph new patch: patch! !

!Instrument methodsFor: 'playing' stamp: 'len 11/Jul/2026, 11:31:27 am (UTC)'!
handleCut: anInteger
	| velocity time |
	velocity := ((anInteger bitShift: -4) bitAnd: 16rF) / 15.0.
	(time := anInteger bitAnd: 16rF) = 0 ifTrue: [^ patch setVelocity: velocity].
	track scheduleTrigger: (Trigger new velocity: (velocity * 128.0) truncated) after: time / 16.0 * track tracker tpl! !

!Instrument methodsFor: 'playing' stamp: 'len 5/Aug/2026, 3:21:57 pm (UTC)'!
handlePostNoteFX: anInteger
	"Slide effects must be handled *after* the note on, otherwise the slide gets overridden."
	| command v |
	command := anInteger bitShift: -8.
	command = 33 "!! (cut)" ifTrue: [^ self handleCut: anInteger].
	command = 42 "* (retrigger)" ifTrue: [^ self handleRetrigger: anInteger].
	command = 126 "~ (scribble)" ifTrue: [^ self handleScribble: anInteger].
	command = 37 "% (stretch)" ifTrue: [^ self handleStretch: anInteger].
	v := anInteger bitAnd: 16rFF.
	command = 60 "< (crescendo, fade volume in)" ifTrue: [patch adjustVelocityBy: (v bitShift: -4) / 15.0 glide: (v bitAnd: 16rF) * track tracker tpl. ^ self].
	command = 62 "> (diminuendo, fade volume out)" ifTrue: [patch adjustVelocityBy: (v bitShift: -4) / -15.0 glide: (v bitAnd: 16rF) * track tracker tpl. ^ self].
	command = 94 "^ (slide pitch up)" ifTrue: [patch adjustNoteBy: (v bitShift: -4) glide: (v bitAnd: 16rF) * track tracker tpl. ^ self].
	command = 95 "_ (slide pitch down)" ifTrue: [patch adjustNoteBy: (v bitShift: -4) negated glide: (v bitAnd: 16rF) * track tracker tpl. ^ self].
	command = 43 "+ (skip forward)" ifTrue: [patch skip: v / 16.0 / track tracker lps. ^ self].
	command = 45 "- (skip backwards)" ifTrue: [patch skip: v / -16.0 / track tracker lps. ^ self].
	command = 47 "/ (speed forward)" ifTrue: [patch setSpeed: (#[0.0 0.125 0.25 0.375 0.5 0.66 0.75 0.9 1.0 1.25 1.5 1.75 2.0 3.0 5.0 8.0] at: (v bitShift: -4) + 1) glide: (v bitAnd: 16rF) * track tracker tpl. ^ self].
	command = 92 "\ (speed backwards)" ifTrue: [patch setSpeed: (#[0.0 -0.125 -0.25 -0.375 -0.5 -0.66 -0.75 -0.9 -1.0 -1.25 -1.5 -1.75 -2.0 -3.0 -5.0 -8.0] at: (v bitShift: -4) + 1) glide: (v bitAnd: 16rF) * track tracker tpl. ^ self]! !

!Instrument methodsFor: 'playing' stamp: 'len 28/Jul/2026, 9:09:14 am (UTC)'!
handlePreNoteFX: anInteger
	| command v |
	command := anInteger bitShift: -8.
	v := anInteger bitAnd: 16rFF.
	command = 64 "@ (sample offset)" ifTrue: [patch setOffset: v / 255.0. ^ self].
	command = 36 "$ (slice number)" ifTrue: [patch setSlice: v. ^ self].
	(command between: 48 and: 57) "0 to 9 (control change)" ifTrue: [patch setControlNumber: command - 48 to: v / 255.0. ^ self]! !

!Instrument methodsFor: 'playing' stamp: 'len 11/Jul/2026, 11:33:05 am (UTC)'!
handleRetrigger: anInteger
	| time velocity x |
	(time := anInteger bitAnd: 16rF) = 0 ifTrue: [^ self].
	velocity := (trigger velocity ifNil: [128.0]) / 128.0.
	x := (anInteger bitShift: -4) bitAnd: 16rF.
	(x between: 0 and: 5) ifTrue: [velocity := velocity - (#(0 0.03 0.06 0.12 0.25 0.5) at: x + 1) max: 0.0].
	(x between: 6 and: 7) ifTrue: [velocity := velocity * (#(0.666 0.5) at: x - 5)].
	(x between: 8 and: 13) ifTrue: [velocity := velocity + (#(0 0.03 0.06 0.12 0.25 0.5) at: x - 7)].
	(x between: 14 and: 15) ifTrue: [velocity := velocity / (#(0.666 0.5) at: x - 13)].
	track scheduleTrigger: (trigger copy velocity: (velocity * 128.0) truncated) after: time / 16.0 * track tracker tpl! !

!Instrument methodsFor: 'playing' stamp: 'len 12/Jul/2026, 7:43:00 am (UTC)'!
handleScribble: anInteger
	| x y glide |
	x := (anInteger bitShift: -4) bitAnd: 16rF.
	(y := anInteger bitAnd: 16rF) = 0 ifTrue: [^ self].
	glide := y / 16.0 * track tracker tpl.
	patch flipSpeed: (#[0.0 0.125 0.25 0.375 0.5 0.66 0.75 0.9 1.0 1.25 1.5 1.75 2.0 3.0 5.0 8.0] at: x + 1) glide: glide.
	track scheduleTrigger: trigger after: glide! !

!Instrument methodsFor: 'playing' stamp: 'len 6/Aug/2026, 4:44:44 pm (UTC)'!
handleStretch: anInteger
	| x y cycle factor |
	x := (anInteger bitShift: -4) bitAnd: 16rF. "stretch factor, 0 = ∞ (freeze), 8 = 1×, 4 = 0.5×"
	(y := anInteger bitAnd: 16rF) = 0 ifTrue: [^ self]. "grain size fraction of a line, 0 to 15/16 of a line"
	cycle := y / 16.0 * track tracker tpl. "grain size in ticks"
	factor :=	#[-1.0 -0.875 -0.75 -0.625 -0.5 -0.375 -0.25 -0.125 0.0 0.25 0.5 0.75 1.0 2.0 4.0 7.0] at: x + 1.
"	'skip ', factor printString, ' cycle ', cycle printString :: print.
	(patch modules detect: [:one| one class = Video]) position print."
	patch skip: factor * cycle / Module controlRate.
"	(patch modules detect: [:one| one class = Video]) position print."
	track scheduleTrigger: (Trigger new effects: {anInteger}) after: cycle! !

!Instrument methodsFor: 'playing' stamp: 'len 27/Jun/2026, 9:42:13 pm (UTC)'!
noteOff
	patch noteOff! !

!Instrument methodsFor: 'playing' stamp: 'len 27/Jun/2026, 9:46:33 pm (UTC)'!
noteOn: midiKey
	self noteOn: midiKey glide: 0.0! !

!Instrument methodsFor: 'playing' stamp: 'len 27/Jun/2026, 9:46:22 pm (UTC)'!
noteOn: midiKey glide: numberOfLines
	patch noteOn: (track tuningOrNil ifNil: [midiKey] ifNotNil: [:aTuning| aTuning map: midiKey]) glide: (numberOfLines * track tracker tpl) truncated! !

!Instrument methodsFor: 'playing' stamp: 'len 26/Jul/2026, 7:06:12 am (UTC)'!
playTrigger
	trigger isNoteOn
		ifTrue:
			[patch setVelocity: (trigger velocity ifNil: [128.0]) / 128.0 glide: 0.
			"start at begining if playing forward, end if playing backwards; override with @xx:"
			patch setOffset: (trigger isReverse ifTrue: [1.0] ifFalse: [0.0]).
			"start new notes at speed 1× forward; override with /x0 or \x0:"
			patch setSpeed: 1.0 glide: 0.
			trigger effectsDo: [:fx| self handlePreNoteFX: fx].
			self noteOn: trigger note + trigger noteShift glide: trigger noteGlide.
			trigger effectsDo: [:fx| self handlePostNoteFX: fx]]
		ifFalse:
			[trigger velocity ifNotNil: [:vel| patch setVelocity: vel / 128.0].
			trigger effectsDo: [:fx| self handlePreNoteFX: fx; handlePostNoteFX: fx].
			trigger isNoteOff ifTrue: [patch noteOff]].
	trigger := nil! !

!Instrument methodsFor: 'playing' stamp: 'len 27/Jun/2026, 9:50:35 pm (UTC)'!
reset
	patch reset! !

!Instrument methodsFor: 'playing' stamp: 'len 5/Jan/2026, 12:45:17 pm (UTC)'!
scheduleTrigger: aTrigger
	trigger := aTrigger! !

!Instrument methodsFor: 'playing' stamp: 'len 24/Jul/2026, 8:46:41 am (UTC)'!
tick
	patch enabled: track enabled; clear.
	trigger ifNotNil: [self playTrigger].
	patch tick! !

!Instrument methodsFor: 'serialization' stamp: 'len 25/Jul/2026, 7:44:39 am (UTC)'!
asJsonWithBuffers: aList
	| answer |
	answer := patch asJsonWithBuffers: aList.
	answer at: #positions put: ((patch modules collect: [:each| (patchMorph patchableFor: each) morphPosition]) collect: [:pos| OrderedDictionary new at: #x put: pos x; at: #y put: pos y; yourself]).
	^ answer! !

!Instrument methodsFor: 'serialization' stamp: 'len 25/Jul/2026, 7:45:13 am (UTC)'!
readFrom: aStream
	| numberOfBuffers bufferList json |
	aStream useBytes.
	numberOfBuffers := aStream nextInt32BigEndian: true.
	bufferList := (1 to: numberOfBuffers) collect: [:i| Float32Array newFromStream: aStream].
	aStream useByteCharacters.
	json := Json readFrom: aStream.
	^ self readFromJson: json buffers: bufferList! !

!Instrument methodsFor: 'serialization' stamp: 'len 25/Jul/2026, 7:45:00 am (UTC)'!
readFromJson: json buffers: bufferList
	| positions |
	patch readFromJson: json buffers: bufferList.
	positions := json at: #positions ifAbsent: [(json at: #modules) collect: [:each| OrderedDictionary new at: #x put: (each at: #x); at: #y put: (each at: #y); yourself]].
	positions := positions collect: [:each| (each at: #x) @ (each at: #y)].
	patchMorph recreateModulesWithPositions: positions.
	patchMorph recreateWires.
	patch label: (json at: #label)! !

!Instrument methodsFor: 'serialization' stamp: 'len 25/Jul/2026, 7:44:50 am (UTC)'!
writeOn: aStream
	| bufferList json |
	bufferList := OrderedCollection new.
	json := self asJsonWithBuffers: bufferList.
	aStream nextInt32Put: bufferList size bigEndian: true.
	bufferList do: [:each| each writeOn: aStream].
	json jsonWriteOn: aStream! !

!Pattern methodsFor: 'accessing' stamp: 'len 27/Jul/2026, 8:46:14 am (UTC)'!
blocks
	^ blocks! !

!Pattern methodsFor: 'accessing' stamp: 'len 22/Jul/2026, 8:59:30 am (UTC)'!
instruments
	"Answer all instrument numbers referenced by this pattern."
	| answer |
	answer := Set new.
	self do: [:each| each instrument ifNotNil: [:anInteger| answer add: anInteger]].
	^ answer! !

!Pattern methodsFor: 'accessing' stamp: 'len 31/Jul/2026, 11:52:01 am (UTC)'!
lastLineWithTrigger
	^ blocks max: [:eachBlock| eachBlock ifNil: [0] ifNotNil: [eachBlock findLast: [:trigger| trigger notNil]]]! !

!Pattern methodsFor: 'accessing' stamp: 'len 18/Dec/2025, 9:32:38 am (UTC)'!
length
	^ length! !

!Pattern methodsFor: 'accessing' stamp: 'len 26/Dec/2025, 6:55:31 pm (UTC)'!
length: anInteger
	anInteger > length ifTrue: [blocks := blocks collect: [:each| each ifNotNil: [each, (Array new: anInteger - length)]]].
	anInteger < length ifTrue: [blocks := blocks collect: [:each| each ifNotNil: [each copyFrom: 1 to: anInteger]]].
	length := anInteger! !

!Pattern methodsFor: 'accessing' stamp: 'len 14/Mar/2026, 11:31:54 am (UTC)'!
lpb
	^ lpb ifNil: [4]! !

!Pattern methodsFor: 'accessing' stamp: 'len 14/Mar/2026, 11:26:07 am (UTC)'!
lpb: anInteger
	lpb := anInteger! !

!Pattern methodsFor: 'accessing' stamp: 'len 14/Jun/2026, 7:35:57 pm (UTC)'!
swapInstrument: anInteger with: anotherInteger
	blocks do: [:each| each ifNotNil: [each do: [:trigger| trigger ifNotNil:
				[trigger instrument = anInteger
					ifTrue: [trigger instrument: anotherInteger]
					ifFalse: [trigger instrument = anotherInteger ifTrue: [trigger instrument: anInteger]]]]]].! !

!Pattern methodsFor: 'accessing' stamp: 'len 12/Aug/2026, 9:27:35 am (UTC)'!
track: trackIndex at: line
	^ (blocks at: trackIndex) ifNotNil: [:anArray| anArray at: line]! !

!Pattern methodsFor: 'accessing' stamp: 'len 27/Dec/2025, 1:18:02 pm (UTC)'!
track: trackIndex at: line position: position put: value
	| block trigger |
	block := (blocks at: trackIndex) ifNil: [value ifNil: [^ self]. blocks at: trackIndex put: (Array new: length)].
	trigger := (block at: line) ifNil: [value ifNil: [^ self]. block at: line put: Trigger new].
	trigger at: position put: value.
	trigger isEmpty ifTrue:
		[block at: line put: nil.
		(block allSatisfy: [:each| each isNil]) ifTrue: [blocks at: trackIndex put: nil]]! !

!Pattern methodsFor: 'accessing' stamp: 'len 12/Aug/2026, 9:27:25 am (UTC)'!
track: trackIndex at: line put: aTrigger
	| block |
	block := (blocks at: trackIndex) ifNil: [aTrigger ifNil: [^ self]. blocks at: trackIndex put: (Array new: length)].
	block at: line put: aTrigger.
	(aTrigger isNil and: [block allSatisfy: [:each| each isNil]]) ifTrue: [blocks at: trackIndex put: nil]! !

!Pattern methodsFor: 'accessing' stamp: 'len 1/Aug/2026, 1:22:55 pm (UTC)'!
track: trackIndex do: aBlock
	((blocks at: trackIndex) ifNil: [^ self]) do: [:each| each ifNotNil: [aBlock value: each]]! !

!Pattern methodsFor: 'accessing' stamp: 'len 11/Mar/2026, 12:54:58 pm (UTC)'!
track: trackIndex instrumentAbove: line
	"Answer the instrument set for the given track at or above the given line. This is the instrument that will play that line when the playhead reaches it."
	| block |
	block := (blocks at: trackIndex) ifNil: [^ nil].
	line to: 1 by: -1 do: [:j| (block at: j) ifNotNil: [:aTrigger| aTrigger instrument ifNotNil: [:anInteger| ^ anInteger = 0 ifFalse: [anInteger]]]].
	^ nil! !

!Pattern methodsFor: 'accessing' stamp: 'len 12/Aug/2026, 9:28:08 am (UTC)'!
track: trackIndex swap: line1 with: line2
	(blocks at: trackIndex) ifNotNil: [:anArray| anArray swap: line1 with: line2]! !

!Pattern methodsFor: 'copying' stamp: 'len 26/Dec/2025, 7:01:58 pm (UTC)'!
postCopy
	blocks := blocks collect: [:eachBlock| eachBlock ifNotNil: [eachBlock collect: [:each| each copy]]]! !

!Pattern methodsFor: 'enumerating' stamp: 'len 14/Aug/2026, 5:44:22 am (UTC)'!
do: aBlock
	"Enumerate all triggers present in the receiver."
	blocks do: [:eachBlock| eachBlock ifNotNil: [eachBlock do: [:eachTrigger| eachTrigger ifNotNil: [aBlock value: eachTrigger]]]]! !

!Pattern methodsFor: 'enumerating' stamp: 'len 27/Jul/2026, 12:07:29 pm (UTC)'!
tracks: tracks line: anInteger instrumentDo: instrumentBlock noteDo: noteBlock velocityDo: velocityBlock effectsDo: effectsBlock emptyTriggersDo: emptyBlock
	blocks with: tracks do: [:each :track|
		each
			ifNil: [emptyBlock value]
			ifNotNil:
				[(each at: anInteger)
					ifNil: [emptyBlock value]
					ifNotNil: [:trigger|
						instrumentBlock value: trigger instrument.
						noteBlock value: trigger note.
						velocityBlock value: trigger velocity.
						1 to: track numberOfFXColumns do: [:i|
							| fx |
							fx := trigger effects at: i ifAbsent: [].
							fx = 0 ifTrue: [fx := nil].
							effectsBlock value: fx]]]]! !

!Pattern methodsFor: 'initialization' stamp: 'len 14/Mar/2026, 11:26:57 am (UTC)'!
initialize: anInteger
	length := 64.
	lpb := 4.
	blocks := Array new: anInteger! !

!Pattern methodsFor: 'serialization' stamp: 'len 14/Mar/2026, 11:28:00 am (UTC)'!
asJson
	| answer blocksJson |
	(answer := OrderedDictionary new)
		at: #length put: length;
		at: #lpb put: lpb.
	blocksJson := blocks collect: [:eachBlock|
		| blockJson |
		blockJson := OrderedCollection new.
		eachBlock ifNotNil:
			[eachBlock withIndexDo: [:each :i|
				each ifNotNil:
					[blockJson add: (OrderedDictionary new at: #line put: i; at: #trigger put: each asJson; yourself)]]].
		blockJson asArray].
	answer at: #blocks put: blocksJson.
	^ answer! !

!Pattern methodsFor: 'serialization' stamp: 'len 14/Mar/2026, 11:28:37 am (UTC)'!
readFromJson: json
	| blocksJson |
	length := json at: #length.
	lpb := json at: #lpb ifAbsent: [4].
	blocksJson := json at: #blocks.
	blocks := Array new: blocksJson size.
	blocksJson withIndexDo: [:eachBlockJson :t|
		eachBlockJson do: [:rowJson|
			self track: t at: (rowJson at: #line) put: (Trigger new readFromJson: (rowJson at: #trigger))]]! !

!Pattern methodsFor: 'testing' stamp: 'len 12/Aug/2026, 9:43:28 am (UTC)'!
hasReferenceToInstrument: anInteger
	self do: [:trigger| anInteger = trigger instrument ifTrue: [^ true]].
	^ false! !

!Pattern methodsFor: 'testing' stamp: 'len 15/Jul/2026, 10:35:51 am (UTC)'!
isEmpty
	^ blocks allSatisfy: [:each| each isNil]! !

!Pattern methodsFor: 'testing' stamp: 'len 27/Dec/2025, 7:24:12 pm (UTC)'!
isEmptyTrack: anInteger
	^ (blocks at: anInteger) isNil! !

!Pattern methodsFor: 'tracks' stamp: 'len 24/Dec/2025, 11:51:22 am (UTC)'!
deleteTrack: anInteger
	"Remove the track at the given index."
	blocks := (blocks copyFrom: 1 to: anInteger - 1), (blocks copyFrom: anInteger + 1 to: blocks size)! !

!Pattern methodsFor: 'tracks' stamp: 'len 26/Dec/2025, 6:55:53 pm (UTC)'!
insertTrack: anInteger
	"Add a track at the given index."
	blocks := (blocks copyFrom: 1 to: anInteger - 1), {nil}, (blocks copyFrom: anInteger to: blocks size)! !

!Pattern methodsFor: 'tracks' stamp: 'len 31/Dec/2025, 3:48:08 pm (UTC)'!
swapTrack: anInteger with: anotherInteger
	anInteger = anotherInteger ifTrue: [^ self].
	blocks swap: anInteger with: anotherInteger! !

!Pattern class methodsFor: 'instance creation' stamp: 'len 26/Dec/2025, 11:03:15 pm (UTC)'!
new: anInteger
	^ self new initialize: anInteger! !

!Track methodsFor: 'accessing' stamp: 'len 9/Jan/2026, 8:09:05 am (UTC)'!
enabled
	^ soloed or: [muted not and: [tracker anyTrackSoloed not]]! !

!Track methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 6:53:29 pm (UTC)'!
inputCenterKey
	^ (tracker inputOctave - 4) * (tuning ifNil: [12] ifNotNil: [tuning size]) + 60! !

!Track methodsFor: 'accessing' stamp: 'len 17/Feb/2026, 12:28:45 pm (UTC)'!
instrument
	^ instrument! !

!Track methodsFor: 'accessing' stamp: 'len 17/Feb/2026, 12:28:15 pm (UTC)'!
meterLeftValue
	^ (instrument ifNil: [^ 0.0]) meterLeftValue! !

!Track methodsFor: 'accessing' stamp: 'len 17/Feb/2026, 12:28:15 pm (UTC)'!
meterRightValue
	^ (instrument ifNil: [^ 0.0]) meterRightValue! !

!Track methodsFor: 'accessing' stamp: 'len 17/Feb/2026, 12:28:15 pm (UTC)'!
meterValue
	^ (instrument ifNil: [^ 0.0]) meterValue! !

!Track methodsFor: 'accessing' stamp: 'len 17/Dec/2025, 9:11:15 am (UTC)'!
muted
	^ muted! !

!Track methodsFor: 'accessing' stamp: 'len 31/Dec/2025, 3:30:46 pm (UTC)'!
muted: aBoolean
	muted := aBoolean! !

!Track methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 10:11:16 am (UTC)'!
noteStringFrom: note
	"Answer a string to represent the given MIDI note, depending on the tuning of this track."
	^ (tuning ifNil: [^ note noteToName]) noteStringFrom: note! !

!Track methodsFor: 'accessing' stamp: 'len 17/Dec/2025, 9:44:47 am (UTC)'!
soloed
	^ soloed! !

!Track methodsFor: 'accessing' stamp: 'len 22/Dec/2025, 10:32:01 am (UTC)'!
soloed: aBoolean
	soloed := aBoolean! !

!Track methodsFor: 'accessing' stamp: 'len 26/Feb/2026, 10:20:51 am (UTC)'!
tracker
	^ tracker! !

!Track methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 6:55:24 pm (UTC)'!
tuning
	^ tuning ifNil: [Tuning edo12]! !

!Track methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 6:56:58 pm (UTC)'!
tuning: aTuning
	tuning := aTuning = Tuning edo12 ifFalse: [aTuning]! !

!Track methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 6:55:28 pm (UTC)'!
tuningOrNil
	^ tuning! !

!Track methodsFor: 'accessing' stamp: 'len 6/Jul/2026, 11:12:44 am (UTC)'!
video
	^ (instrument ifNil: [^ nil]) video! !

!Track methodsFor: 'initialization' stamp: 'len 27/Jul/2026, 12:07:39 pm (UTC)'!
initialize
	muted := false.
	soloed := false.
	numberOfFXColumns := 2! !

!Track methodsFor: 'initialization' stamp: 'len 3/Jan/2026, 8:47:12 am (UTC)'!
setTracker: aTracker
	tracker := aTracker! !

!Track methodsFor: 'playing' stamp: 'len 17/Feb/2026, 12:28:32 pm (UTC)'!
forgetInstrument
	instrument := nil! !

!Track methodsFor: 'playing' stamp: 'len 14/Jul/2026, 7:47:26 am (UTC)'!
handleGlobalFX: anInteger
	| command v |
	command := anInteger bitShift: -8.
	v := anInteger bitAnd: 16rFF.
	"Global commands:"
	command = 70 "F (set tempo)" ifTrue: [tracker bpm: (v max: 1). ^ self].
	command = 65 "A (set video source A)" ifTrue: [tracker setVideoSourceA: v. ^ self].
	command = 66 "B (set video source B)" ifTrue: [tracker setVideoSourceB: v. ^ self].
	command = 88 "X (set BitBlt combination rules)" ifTrue: [tracker setVideoOperation: v. ^ self]! !

!Track methodsFor: 'playing' stamp: 'len 26/Jul/2026, 7:06:53 am (UTC)'!
playTrigger
	trigger instrument ifNotNil: [:anInteger|
		instrument ifNotNil: [instrument setOwnerTrack: nil].
		instrument := tracker instruments at: anInteger ifAbsent: [].
		instrument ifNotNil: [instrument setOwnerTrack: self "; reset"]].
	instrument ifNotNil: [instrument scheduleTrigger: trigger].
	trigger effectsDo: [:fx| self handleGlobalFX: fx].
	trigger := nil! !

!Track methodsFor: 'playing' stamp: 'len 26/Jul/2026, 1:33:21 pm (UTC)'!
scheduleTrigger: aTrigger
	"Schedule aTrigger to play either immediatly if delay = 0, or after the number of ticks required by the delay.
	The delay is specified by a Qxx command, where xx specifies the delay in steps of 1/256th the duration of a line."
	| triggerDelay |
	(triggerDelay := aTrigger delay) = 0
		ifTrue: [self scheduleTrigger: aTrigger after: 0]
		ifFalse: [self scheduleTrigger: aTrigger after: triggerDelay * tracker tpl]! !

!Track methodsFor: 'playing' stamp: 'len 26/Feb/2026, 4:30:14 pm (UTC)'!
scheduleTrigger: aTrigger after: ticks
	"Schedule aTrigger to play after the required number of ticks."
	trigger := aTrigger.
	ticksToTrigger := ticks! !

!Track methodsFor: 'playing' stamp: 'len 17/Feb/2026, 12:28:15 pm (UTC)'!
tick
	trigger ifNotNil: [ticksToTrigger > 0 ifTrue: [ticksToTrigger := ticksToTrigger - 1] ifFalse: [self playTrigger]].
	instrument ifNotNil: [instrument tick]! !

!Track methodsFor: 'serialization' stamp: 'len 27/Jul/2026, 12:08:31 pm (UTC)'!
asJson
	| answer |
	(answer := OrderedDictionary new)
		at: #muted put: muted;
		at: #soloed put: soloed;
		at: #numberOfFXColumns put: numberOfFXColumns.
	tuning ifNotNil: [:aTuning| answer at: #tuning put: aTuning asJson].
	^ answer! !

!Track methodsFor: 'serialization' stamp: 'len 27/Jul/2026, 12:08:54 pm (UTC)'!
readFromJson: json
	muted := json at: #muted.
	soloed := json at: #soloed.
	numberOfFXColumns := json at: #numberOfFXColumns ifAbsent: [2].
	json at: #tuning ifPresent: [:tuningJson| tuning := Tuning new readFromJson: tuningJson]! !

!Track methodsFor: 'as yet unclassified' stamp: 'len 1/Aug/2026, 1:27:06 pm (UTC)'!
decreaseFXColumns
	| min trackNumber |
	min := 0.
	trackNumber := tracker tracks indexOf: self.
	tracker sequenceUniquePatterns do: [:each| each track: trackNumber do: [:trig| min := min max: trig effects size]].
	numberOfFXColumns := numberOfFXColumns - 1 max: min.
	tracker triggerEvent: #tracksChanged! !

!Track methodsFor: 'as yet unclassified' stamp: 'len 27/Jul/2026, 12:07:39 pm (UTC)'!
increaseFXColumns
	numberOfFXColumns := numberOfFXColumns + 1.
	tracker triggerEvent: #tracksChanged! !

!Track methodsFor: 'as yet unclassified' stamp: 'len 27/Jul/2026, 12:07:39 pm (UTC)'!
numberOfFXColumns
	^ numberOfFXColumns! !

!Track methodsFor: 'as yet unclassified' stamp: 'len 27/Jul/2026, 12:07:53 pm (UTC)'!
widthInCharacters
	^ numberOfFXColumns * 3.5 + 8! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 8:21:07 am (UTC)'!
at: position put: value
	| i col fx |
	position = 1 ifTrue: [^ instrument := value ifNotNil: [((instrument ifNil: [0]) bitAnd: 16r0F) bitOr: (value bitShift: 4)]].
	position = 2 ifTrue: [^ instrument := value ifNotNil: [((instrument ifNil: [0]) bitAnd: 16rF0) bitOr: value]].
	position = 3 ifTrue: [^ note := value].
	position = 4 ifTrue: [^ velocity := value ifNotNil: [(((velocity ifNil: [0]) bitAnd: 16r0F) bitOr: (value bitShift: 4)) min: 16r80]].
	position = 5 ifTrue: [^ velocity := value ifNotNil: [(((velocity ifNil: [0]) bitAnd: 16rF0) bitOr: value) min: 16r80]].
	i := position - 6 // 3 + 1.
	[effects size < i] whileTrue: [effects := effects copyWith: 0].
	fx := effects at: i.
	col := position - 6 \\ 3.
	col = 0 ifTrue: [fx := value ifNil: [0] ifNotNil: [(fx bitAnd: 16rFF) bitOr: (value bitShift: 8)]].
	col = 1 ifTrue: [fx := value ifNil: [0] ifNotNil: [(fx bitAnd: 16rFF0F) bitOr: (value bitShift: 4)]].
	col = 2 ifTrue: [fx := value ifNil: [0] ifNotNil: [(fx bitAnd: 16rFFF0) bitOr: value]].
	effects at: i put: fx.
	[effects notEmpty and: [effects last = 0]] whileTrue: [effects := effects allButLast]! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 1:33:02 pm (UTC)'!
delay
	"Answer the delay for this trigger, i.e. the parameter of the effect command &xx, as a fraction of the duration of a line."
	self effectsDo: [:fx| (fx bitShift: -8) = 38 "&" ifTrue: [^ (fx bitAnd: 16rFF) / 256.0]].
	^ 0! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 7:49:59 am (UTC)'!
effects
	^ effects! !

!Trigger methodsFor: 'accessing' stamp: 'len 5/Aug/2026, 3:26:07 pm (UTC)'!
effects: anArray
	effects := anArray! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 7:56:04 am (UTC)'!
effectsDo: aBlock
	effects do: aBlock! !

!Trigger methodsFor: 'accessing' stamp: 'len 24/Dec/2025, 8:57:45 am (UTC)'!
instrument
	^ instrument! !

!Trigger methodsFor: 'accessing' stamp: 'len 24/Dec/2025, 8:59:14 am (UTC)'!
instrument: anInteger
	instrument := anInteger! !

!Trigger methodsFor: 'accessing' stamp: 'len 16/Dec/2025, 1:34:20 pm (UTC)'!
note
	^ note! !

!Trigger methodsFor: 'accessing' stamp: 'len 16/Dec/2025, 1:34:28 pm (UTC)'!
note: anInteger
	note := anInteger! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 7:10:30 am (UTC)'!
noteGlide
	"Answer the glide or portamento effect for this trigger in number of lines.
	This is the value of the parameter of the effect command G."
	self effectsDo: [:fx| (fx bitShift: -8) = 71 "G" ifTrue: [^ (fx bitAnd: 16rFF) / 16.0]].
	^ 0! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 7:10:06 am (UTC)'!
noteShift
	"If the receiver has any #xx finetuning effect, answer the shift amount from 0.0 (current note) to 1.0 (next note). Otherwise answer 0."
	| answer |
	answer := 0.0.
	self effectsDo: [:fx| (fx bitShift: -8) = 35 "#xx (finetune note up)" ifTrue: [answer := (fx bitAnd: 16rFF) / 256.0 + answer]].
	^ answer! !

!Trigger methodsFor: 'accessing' stamp: 'len 31/Jul/2026, 3:34:23 pm (UTC)'!
offset
	"Answer the sample offset effect for this trigger, or nil."
	self effectsDo: [:fx| (fx bitShift: -8) = 64 "@" ifTrue: [^ (fx bitAnd: 16rFF) / 256.0]].
	^ nil! !

!Trigger methodsFor: 'accessing' stamp: 'len 31/Jul/2026, 3:40:02 pm (UTC)'!
offset: aNumber
	1 to: effects size do: [:i|
		((effects at: i) bitShift: -8) = 64 "@" ifTrue:
			[effects at: i put: (((effects at: i) bitAnd: 16rFF00) bitXor: (255 * aNumber) rounded).
			^ self]]! !

!Trigger methodsFor: 'accessing' stamp: 'len 26/Jul/2026, 7:09:18 am (UTC)'!
probability
	"Answer the probability for this trigger, i.e. the parameter of the effect command ?xx."
	self effectsDo: [:fx| (fx bitShift: -8) = 63 "?" ifTrue: [^ (fx bitAnd: 16rFF) / 255.0]].
	^ 1.0! !

!Trigger methodsFor: 'accessing' stamp: 'len 31/Jul/2026, 3:35:23 pm (UTC)'!
slice
	"Answer the slice effect for this trigger, or nil."
	self effectsDo: [:fx| (fx bitShift: -8) = 36 "$" ifTrue: [^ fx bitAnd: 16rFF]].
	^ nil! !

!Trigger methodsFor: 'accessing' stamp: 'len 31/Jul/2026, 3:41:18 pm (UTC)'!
slice: anInteger
	self assert: (anInteger between: 0 and: 255).
	1 to: effects size do: [:i|
		((effects at: i) bitShift: -8) = 36 "$" ifTrue:
			[effects at: i put: (((effects at: i) bitAnd: 16rFF00) bitXor: anInteger).
			^ self]]! !

!Trigger methodsFor: 'accessing' stamp: 'len 19/Dec/2025, 12:13:34 pm (UTC)'!
velocity
	^ velocity! !

!Trigger methodsFor: 'accessing' stamp: 'len 13/Jun/2026, 8:18:59 am (UTC)'!
velocity: anInteger
	velocity := anInteger min: 128 max: 0! !

!Trigger methodsFor: 'copying' stamp: 'len 29/Jul/2026, 7:55:03 pm (UTC)'!
postCopy
	super postCopy.
	effects := effects copy! !

!Trigger methodsFor: 'initialization' stamp: 'len 26/Jul/2026, 7:54:32 am (UTC)'!
initialize
	effects := #()! !

!Trigger methodsFor: 'serialization' stamp: 'len 26/Jul/2026, 7:55:43 am (UTC)'!
asJson
	| answer |
	answer := OrderedDictionary new.
	note ifNotNil: [answer at: #note put: note].
	instrument ifNotNil: [answer at: #instrument put: instrument].
	velocity ifNotNil: [answer at: #velocity put: velocity].
	effects ifNotEmpty: [answer at: #effects put: effects].
	^ answer! !

!Trigger methodsFor: 'serialization' stamp: 'len 26/Jul/2026, 7:57:22 am (UTC)'!
readFromJson: json
	note := json at: #note ifAbsent: [].
	instrument := json at: #instrument ifAbsent: [].
	velocity := json at: #velocity ifAbsent: [].
	effects := json at: #effects ifAbsent: [#()].
	json at: #fx1 ifPresent: [:fx| effects := effects copyWith: fx].
	json at: #fx2 ifPresent: [:fx| effects := effects copyWith: fx]! !

!Trigger methodsFor: 'testing' stamp: 'len 26/Jul/2026, 7:54:00 am (UTC)'!
isEmpty
	^ note isNil and: [instrument isNil and: [velocity isNil and: [effects allSatisfy: [:each| each = 0]]]]! !

!Trigger methodsFor: 'testing' stamp: 'len 18/Feb/2026, 4:33:07 pm (UTC)'!
isNoteOff
	^ note notNil and: [note < 0]! !

!Trigger methodsFor: 'testing' stamp: 'len 18/Feb/2026, 4:28:26 pm (UTC)'!
isNoteOn
	^ note notNil and: [note >= 0]! !

!Trigger methodsFor: 'testing' stamp: 'len 26/Jul/2026, 7:12:37 am (UTC)'!
isReverse
	"Answer true if the receiver has an effect \xx to play a sample backwards."
	self effectsDo: [:fx| (fx bitShift: -8) = 92 "\" ifTrue: [^ true]].
	^ false! !

!Trigger methodsFor: 'transformations' stamp: 'len 11/Jun/2026, 9:06:34 am (UTC)'!
transposeBy: steps
	self isNoteOn ifTrue: [(note + steps between: 0 and: 127) ifTrue: [note := note + steps]]! !

!Trigger methodsFor: 'printing' stamp: 'len 12/Aug/2026, 7:10:30 am (UTC)'!
printOn: aStream
	aStream
		nextPutAll: (instrument ifNil: ['--'] ifNotNil: [instrument printStringBase: 16 nDigits: 2]);
		space;
		nextPutAll: (note ifNil: ['---'] ifNotNil: [note = -1 ifTrue: ['OFF'] ifFalse: [note noteToName]]);
		space;
		nextPutAll: (velocity ifNil: ['--'] ifNotNil: [velocity printStringBase: 16 nDigits: 2]).
	self effectsDo: [:fx|
		aStream
			space;
			nextPut: (Character codePoint: (fx bitShift: -8));
			nextPutAll: ((fx bitAnd: 16rFF) printStringBase: 16 nDigits: 2)]! !

!Trigger methodsFor: 'comparing' stamp: 'len 12/Aug/2026, 2:15:53 pm (UTC)'!
= anObject
	^ (anObject isKindOf: Trigger) and: [anObject instrument = self instrument and: [anObject note = self note and: [anObject velocity = self velocity and: [anObject effects = self effects]]]]! !

!Trigger methodsFor: 'comparing' stamp: 'len 12/Aug/2026, 2:19:14 pm (UTC)'!
hash
	^ ((instrument hash hashMultiply + note hash) hashMultiply + velocity hash) hashMultiply + effects hash! !

!Trigger class methodsFor: 'as yet unclassified' stamp: 'len 7/Jul/2026, 6:58:20 pm (UTC)'!
allFXCommandCharacters
	^ '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ<>/\+-?!!@&~#$%^*_=|'! !

!Trigger class methodsFor: 'as yet unclassified' stamp: 'len 6/Aug/2026, 5:47:10 am (UTC)'!
descriptionForFX: anInteger
	| command v |
	command := anInteger bitShift: -8.
	command = 33 "!! (cut)" ifTrue:
		[^ 'Cut to velocity ', (((anInteger bitShift: -4) bitAnd: 16rF) / 15.0 * 100) rounded printString, '% after ', ((anInteger bitAnd: 16rF)/16) printText, ' of a line'].
	command = 42 "* (retrigger)" ifTrue:
		[| velocityChange |
		velocityChange := #('' '-1/32' '-1/16' '-1/8' '-1/4' '-1/2' '×2/3' '×1/2' '' '+1/32' '+1/16' '+1/8' '+1/4' '+1/2' '×3/2' '×2') at: ((anInteger bitShift: -4) bitAnd: 16rF) + 1.
		velocityChange ifNotEmpty: [velocityChange := ' changing velocity by ', velocityChange].
		^ 'Retrigger every ', ((anInteger bitAnd: 16rF)/16) printText, ' of a line', velocityChange].
	v := anInteger bitAnd: 16rFF.
	command = 60 "< (crescendo, fade in)" ifTrue: [^ 'Fade in ', ((v bitShift: -4) / 15.0 * 100) rounded printString, '% over ', (v bitAnd: 16rF) printString, ' lines'].
	command = 62 "> (diminuendo, fade out)" ifTrue: [^ 'Fade out ', ((v bitShift: -4) / 15.0 * 100) rounded printString, '% over ', (v bitAnd: 16rF) printString, ' lines'].
	command = 94 "^ (slide pitch up)" ifTrue: [^ 'Slide pitch up by ', (v bitShift: -4) printString, ' notes over ', (v bitAnd: 16rF) printString, ' lines'].
	command = 95 "_ (slide pitch down)" ifTrue: [^ 'Slide pitch down by ', (v bitShift: -4) printString, ' notes over ', (v bitAnd: 16rF) printString, ' lines'].
	command = 35 "# (finetune note up)" ifTrue: [^ 'Finetune note up by ', (v / 256.0 printStringFractionDigits: 2)].
	command = 71 "G (glide to note)" ifTrue: [^ 'Glide to note over ', (v / 16.0 printStringFractionDigits: 2), ' lines'].
	"Sample commands:"
	command = 64 "@ (sample offset)" ifTrue: [^ 'Jump to sample offset ', (v printStringBase: 16 length: 2 padded: true)].
	command = 36 "$ (slice number)" ifTrue: [^ 'Jump to slice ', (v printStringBase: 16 length: 2 padded: true)].
	command = 47 "/ (speed forward)" ifTrue:
		[| speed lines |
		speed := #[0.0 0.125 0.25 0.375 0.5 0.66 0.75 0.9 1.0 1.25 1.5 1.75 2.0 3.0 5.0 8.0] at: ((anInteger bitShift: -4)  bitAnd: 16rF) + 1.
		lines := anInteger bitAnd: 16rF.
		^ lines = 0 ifTrue: ['Play forward at ', (speed printStringFractionDigits: 2), '×'] ifFalse: ['Slide to play forward at ', (speed printStringFractionDigits: 2), '× over ', lines printString, ' lines']].
	command = 92 "\ (speed backwards)" ifTrue:
		[| speed lines |
		speed := #[0.0 0.125 0.25 0.375 0.5 0.66 0.75 0.9 1.0 1.25 1.5 1.75 2.0 3.0 5.0 8.0] at: ((anInteger bitShift: -4)  bitAnd: 16rF)+ 1.
		lines := anInteger bitAnd: 16rF.
		^ lines = 0 ifTrue: ['Play backwards at ', (speed printStringFractionDigits: 2), '×'] ifFalse: ['Slide to play backwards at ', (speed printStringFractionDigits: 2), '× over ', lines printString, ' lines']].
	command = 126 "~ (scribble)" ifTrue:
		[| speed |
		speed := #[0.0 0.125 0.25 0.375 0.5 0.66 0.75 0.9 1.0 1.25 1.5 1.75 2.0 3.0 5.0 8.0] at: ((anInteger bitShift: -4)  bitAnd: 16rF)+ 1.
		^ 'Scribble at ', (speed printStringFractionDigits: 2), '× every ', ((anInteger bitAnd: 16rF)/16) printText, ' of a line'].
	"Control change commands:"
	(command between: 48 and: 57) "0 to 9" ifTrue: [^ 'Set control [', (command - 48) printString, '] to ', (v / 255.0 * 100) rounded printString, '%'].
	"Global commands:"
	command = 70 "F (set bpm)" ifTrue: [^ 'Set tempo to ', (v max: 1) printString, ' BPM'].
	command = 63 "? (trigger probability)" ifTrue: [^ 'Play trigger with ', (v / 255.0 * 100) rounded printString, '% probability'].
	command = 38 "& (trigger delay)" ifTrue: [^ 'Delay trigger by ', v printString, '/256 of a line'].
	command = 65 "A (set video source A)" ifTrue: [^ 'Set video source A to track ', v printString].
	command = 66 "B (set video source B)" ifTrue: [^ 'Set video source B to track ', v printString].
	command = 88 "X (bitblt rules)" ifTrue:
		[| rules |
		rules := #('black' 'src' 'and' 'xor' 'or' 'not and' 'not xor' 'not or' 'int+' 'int-' 'rgb+' 'rgb-' 'rgb max' 'rgb min' 'not(dst)' 'not(src)').
		^ 'BitBlt: ', (rules at: (v bitShift: -4) + 1), ', ', (rules at: (v bitAnd: 16rF) + 1)].
	^ nil! !

!Tuning methodsFor: 'accessing' stamp: 'len 9/Jun/2026, 7:00:32 pm (UTC)'!
intervals
	^ intervals! !

!Tuning methodsFor: 'accessing' stamp: 'len 9/Jun/2026, 11:47:48 am (UTC)'!
label
	^ label! !

!Tuning methodsFor: 'accessing' stamp: 'len 9/Jun/2026, 8:27:37 pm (UTC)'!
map: midiKey
	"Map a MIDI key in this tuning to a MIDI key in the standard 12-TET tuning.
	Assumes root key = C4 (MIDI key 60), i.e. it maps the root at MIDI key 60 to the standard C4 at 261.63 Hz."
	| cents degree octave relativeNote |
	relativeNote := midiKey - 60.0.
	octave := relativeNote // intervals size.
	degree := relativeNote \\ intervals size.
	cents := octave * intervals last + (degree < 1.0 ifTrue: [intervals first * degree] ifFalse: [intervals atLinear: degree]).
	^ (60 noteToHertz * (2.0 raisedTo: cents / 1200.0)) hertzToNote! !

!Tuning methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 4:38:45 pm (UTC)'!
noteStringFrom: midiKey
	"Answer a string to represent the given MIDI note."
	| relativeMidiKey n degree |
	relativeMidiKey := midiKey rounded - 60.
	n := intervals size.
	degree := relativeMidiKey \\ n.
"	degreeString := degreeNames ifNotNil: [degreeNames at: degree+1] ifNil: [degree printStringBase: 10 length: 2 padded: true].
	degreeString size = 1 ifTrue: [degreeString := degreeString, '-'].
	^ degreeString, (relativeMidiKey // n + 4) printString
	"
	^ (degree < 10 ifTrue: [' ', degree printString] ifFalse: [degree printString]), (#('₀' '₁' '₂' '₃' '₄' '₅' '₆' '₇' '₈' '₉') at: relativeMidiKey // n + 5 ifAbsent: ['?'])! !

!Tuning methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 6:58:10 pm (UTC)'!
period
	^ intervals last! !

!Tuning methodsFor: 'accessing' stamp: 'len 10/Jun/2026, 6:57:38 pm (UTC)'!
size
	^ intervals size! !

!Tuning methodsFor: 'serialization' stamp: 'len 10/Jun/2026, 7:28:58 pm (UTC)'!
asJson
	| answer |
	(answer := OrderedDictionary new)
		at: #label put: label;
		at: #intervals put: intervals.
	noteNames ifNotNil: [answer at: #noteNames put: (noteNames collect: [:each| each asUtf8Bytes])].
	^ answer! !

!Tuning methodsFor: 'serialization' stamp: 'len 10/Jun/2026, 7:28:49 pm (UTC)'!
readFromJson: json
	label := json at: #label.
	intervals := (json at: #intervals) asFloat32Array.
	json at: #noteNames ifPresent: [:anArray| noteNames := anArray asArray collect: [:each| CharacterSequence fromUtf8Bytes: each asByteArray]]! !

!Tuning methodsFor: 'private' stamp: 'len 9/Jun/2026, 6:56:45 pm (UTC)'!
intervals: anArray
	intervals := anArray asFloat32Array! !

!Tuning methodsFor: 'private' stamp: 'len 9/Jun/2026, 11:48:00 am (UTC)'!
label: aString
	label := aString! !

!Tuning methodsFor: 'private' stamp: 'len 10/Jun/2026, 7:12:06 pm (UTC)'!
noteNames: anArray
	noteNames := anArray! !

!Tuning methodsFor: 'comparing' stamp: 'len 22/Jun/2026, 9:20:21 pm (UTC)'!
= aTuning
	^ self class = aTuning class and: [intervals = aTuning intervals]! !

!Tuning methodsFor: 'comparing' stamp: 'len 22/Jun/2026, 9:20:29 pm (UTC)'!
hash
	^ intervals hash! !

!Tuning methodsFor: 'printing' stamp: 'len 22/Jun/2026, 9:23:34 am (UTC)'!
printOn: aStream
	aStream nextPutAll: (label ifNil: [^ super printOn: aStream])! !

!Tuning class methodsFor: 'library' stamp: 'len 9/Jun/2026, 3:14:43 pm (UTC)'!
library
	^ Library! !

!Tuning class methodsFor: 'class initialization' stamp: 'len 10/Jun/2026, 7:01:07 pm (UTC)'!
initialize
	super initialize.
	EDO12 := nil.
	Library := OrderedCollection new.
	Library addAll: {self edo7. self edo12. self edo19. self edo31. self edo: 53. self fiveLimitJustIntonation. self pythagorean. self harmonic: 8}! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 9/Jun/2026, 6:59:43 pm (UTC)'!
edo: anInteger
	^ self label: anInteger printString, '-EDO' intervals: ((1 to: anInteger) collect: [:i| 1200.0 * i / anInteger])! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 10/Jun/2026, 7:12:06 pm (UTC)'!
edo12
	^ EDO12 ifNil: [EDO12 := (self edo: 12) noteNames: #('C' 'C♯' 'D' 'D♯' 'E' 'F' 'F♯' 'G' 'G♯' 'A' 'A♯' 'B')]! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 10/Jun/2026, 7:12:07 pm (UTC)'!
edo19
	^ (self edo: 19) noteNames: #('C' 'C♯' 'D♭' 'D' 'D♯' 'E♭' 'E' 'E♯' "=F♭" 'F' 'F♯' 'G♭' 'G' 'G♯' 'A♭' 'A' 'A♯' 'B♭' 'B' 'B♯' "=C♭")! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 10/Jun/2026, 7:12:06 pm (UTC)'!
edo31
	^ (self edo: 31) noteNames: #('C' 'C↑' 'C♯' 'D♭' 'D↓' 'D' 'D↑' 'D♯' 'E♭' 'E↓' 'E' 'E↑' 'F↓' 'F' 'F↑' 'F♯' 'G♭' 'G↓' 'G' 'G↑' 'G♯' 'A♭' 'A↓' 'A' 'A↑' 'A♯' 'B♭' 'B↓' 'B' 'B↑' 'C↓')! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 10/Jun/2026, 7:12:06 pm (UTC)'!
edo7
	^ (self edo: 7) noteNames: #('C' 'D' 'E' 'F' 'G' 'A' 'B')! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 10/Jun/2026, 7:12:07 pm (UTC)'!
fiveLimitJustIntonation
	^ (self label: '5-Limit JI' ratios: {16/15. 9/8. 6/5. 5/4. 4/3. 45/32. 3/2. 8/5. 5/3. 9/5. 15/8. 2/1}) noteNames: #('C' 'C♯' 'D' 'E♭' 'E↓' "syntonic E, lower than Pythagorean by ~21.5¢" 'F' "'F♯↓'" 'F↡'  "lower than Pythagorean F♯" 'G' 'G♯' 'A↓' "syntonic A" 'B♭' 'B↓' "syntonic B")! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 9/Jun/2026, 6:59:10 pm (UTC)'!
harmonic: n
	^ self label: 'Harmonic ', n printString ratios: ((n to: n*2) collect: [:m| m / n])! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 9/Jun/2026, 6:58:37 pm (UTC)'!
label: aString intervals: anArray
	^ self new label: aString; intervals: anArray! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 9/Jun/2026, 6:58:52 pm (UTC)'!
label: aString ratios: aCollection
	^ self label: aString intervals: (aCollection collect: [:each| (each log: 2.0) * 1200.0]) sorted! !

!Tuning class methodsFor: 'instance creation' stamp: 'len 10/Jun/2026, 7:12:06 pm (UTC)'!
pythagorean
	^ (self label: 'Pythagorean' ratios: {256/243. 9/8. 32/27. 81/64. 4/3. 1024/729. 3/2. 128/81. 27/16. 16/9. 243/128. 2/1}) noteNames: #('C' 'C♯' 'D' 'D♯' 'E' 'F' 'F♯' 'G' 'G♯' 'A' 'A♯' 'B')
! !

!Morph methodsFor: '*tracker' stamp: 'len 15/Jun/2026, 1:17:50 pm (UTC)'!
showBalloon: stringOrText at: localPosition
	"Pop up a balloon containing the given string,
	first removing any existing BalloonMorphs in the world."

	| balloon |
	self world ifNotNil: [:w|
		balloon := HoverHelpMorph contents: stringOrText doWordWrap: false.
		"Do it in a while. In some cases, processing the event that
		might have triggered us might also remove any Help Balloon"
		UISupervisor whenUIinSafeState: [balloon popUpForHand: w activeHand; target: self getter: nil; morphPosition: (self externalizeToWorld: localPosition)]]! !
DarkerTheme initialize!
PatternEditorMorph initialize!
Tuning initialize!