Jam-PT/CMakeLists.txt at main · matteobissoli/Jam-PT · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
cmake_minimum_required(VERSION 3.22)

project(JamPT VERSION 0.1.0 LANGUAGES C CXX OBJCXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_OBJCXX_STANDARD 17)
set(CMAKE_OBJCXX_STANDARD_REQUIRED ON)
set_property(GLOBAL PROPERTY USE_FOLDERS YES)

set(JAMPT_MACOS_DEPLOYMENT_TARGET "11.0" CACHE STRING "Minimum macOS deployment version for Jam-PT")
set(JAMPT_MACOS_ARCHITECTURES "arm64;x86_64" CACHE STRING "macOS architectures to build for Jam-PT")

if (APPLE)
    set(CMAKE_OSX_DEPLOYMENT_TARGET "${JAMPT_MACOS_DEPLOYMENT_TARGET}" CACHE STRING "Minimum macOS deployment version" FORCE)
    set(CMAKE_OSX_ARCHITECTURES "${JAMPT_MACOS_ARCHITECTURES}" CACHE STRING "Build macOS binaries for the requested architectures" FORCE)
endif()

if (CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang")
    add_compile_options(
        -Wno-implicit-int-conversion
        -Wno-implicit-int-conversion-on-negation
        -Wno-switch
        -Wno-switch-enum
    )
endif()

option(JAMPT_FETCH_JUCE "Fetch JUCE automatically with FetchContent" ON)
set(JAMPT_JUCE_GIT_TAG "8.0.8" CACHE STRING "JUCE git tag used when JAMPT_FETCH_JUCE is ON")

if (JAMPT_FETCH_JUCE)
    include(FetchContent)
    FetchContent_Declare(
        juce
        GIT_REPOSITORY https://github.com/juce-framework/JUCE.git
        GIT_TAG ${JAMPT_JUCE_GIT_TAG}
        GIT_SHALLOW TRUE
    )
    FetchContent_MakeAvailable(juce)
else()
    if (NOT DEFINED JUCE_SOURCE_DIR)
        message(FATAL_ERROR "Set JUCE_SOURCE_DIR to a local JUCE checkout, or enable JAMPT_FETCH_JUCE.")
    endif()
    add_subdirectory(${JUCE_SOURCE_DIR} JUCE)
endif()

juce_add_plugin(Jam-PT
    COMPANY_NAME "Matteo Bissoli"
    BUNDLE_ID "com.matteobissoli.jampt"
    PLUGIN_MANUFACTURER_CODE MtBs
    PLUGIN_CODE JmPt
    FORMATS AU VST3 Standalone
    PRODUCT_NAME "Jam-PT"
    COPY_PLUGIN_AFTER_BUILD TRUE
    IS_SYNTH FALSE
    NEEDS_MIDI_INPUT FALSE
    NEEDS_MIDI_OUTPUT FALSE
    IS_MIDI_EFFECT FALSE
    EDITOR_WANTS_KEYBOARD_FOCUS FALSE
    AU_MAIN_TYPE kAudioUnitType_Generator
)

juce_generate_juce_header(Jam-PT)

target_sources(Jam-PT
    PRIVATE
        src/PluginProcessor.cpp
        src/PluginEditor.cpp
        src/AudioFilePlayer.cpp
        src/DemucsProcessor.mm
)

target_include_directories(Jam-PT
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}/src
)

target_compile_definitions(Jam-PT
    PUBLIC
        JUCE_WEB_BROWSER=0
        JUCE_USE_CURL=0
        JUCE_VST3_CAN_REPLACE_VST2=0
)

target_link_libraries(Jam-PT
    PRIVATE
        juce::juce_audio_utils
        juce::juce_audio_formats
        juce::juce_audio_processors
        juce::juce_gui_extra
        juce::juce_recommended_config_flags
        juce::juce_recommended_lto_flags
        juce::juce_recommended_warning_flags
)

if (APPLE)
    set_target_properties(Jam-PT PROPERTIES
        XCODE_ATTRIBUTE_CLANG_ENABLE_OBJC_ARC NO
        XCODE_ATTRIBUTE_ONLY_ACTIVE_ARCH NO
        XCODE_ATTRIBUTE_OTHER_LIBTOOLFLAGS "-no_warning_for_no_symbols"
    )
endif()