commons-java/build.gradle at master · mtransitapps/commons-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

plugins {
    id("java-library")
    alias(libs.plugins.kotlin.jvm)
    alias(libs.plugins.kotlinx.serialization)
    alias(libs.plugins.android.lint) // dependency of commons-android
}

def envCI = System.getenv("CI")
def isCI = envCI != null && envCI != ""
def mtDebugDefault = providers.environmentVariable("MT_DEBUG_DEFAULT")
        .map { it.toBoolean() }
        .orElse(false)
def generatedBuildConfigDir = layout.buildDirectory.dir("generated/sources/mt/buildConfig")

def generateBuildConfig = tasks.register("generateBuildConfig") {
    inputs.property("mtDebugDefault", mtDebugDefault)
    outputs.dir(generatedBuildConfigDir)
    doLast {
        def debugDefault = mtDebugDefault.get()
        def outputDir = generatedBuildConfigDir.get().asFile
        outputDir.deleteDir()
        def outputFile = new File(outputDir, "org/mtransit/commons/BuildConfig.kt")
        outputFile.parentFile.mkdirs()
        outputFile.write("""package org.mtransit.commons

internal object BuildConfig {
    const val DEBUG_DEFAULT = ${debugDefault}
}
""", "UTF-8")
    }
}

java {
    sourceCompatibility = rootProject.javaVersion
    targetCompatibility = rootProject.javaVersion
    toolchain.languageVersion = JavaLanguageVersion.of(rootProject.javaToolchainVersion.toString())
}
kotlin {
    sourceSets.main.kotlin.srcDir(generateBuildConfig)
    compilerOptions {
        jvmTarget = JvmTarget.fromTarget(rootProject.javaVersion.toString())
        // allWarningsAsErrors = true // replaced by "DeprecatedCall" in lint
    }
}

dependencies {
    implementation(platform(libs.kotlin.bom))
    implementation(platform(libs.kotlinx.coroutines.bom))
    implementation(platform(libs.kotlinx.serialization.bom))
    implementation(libs.bundles.kotlin)

    testImplementation(libs.bundles.test.unit)
}

test {
    useJUnit()
    testLogging {
        if (isCI) {
            events("started", "passed", "skipped", "failed", "standard_out", "standard_error")
        } else {
            events("failed")
        }
    }
}