infrastructure/flake.nix at main · rezics/infrastructure · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
{
  description = "Reusable infrastructure modules and tooling for the REZICS platform";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";

  outputs =
    { self, nixpkgs }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        config.allowUnfreePredicate = package: nixpkgs.lib.getName package == "nomad";
      };
    in
    {
      nixosModules = rec {
        fleet = ./modules/fleet.nix;
        common = ./modules/common.nix;
        nomad = ./modules/nomad.nix;
        nomadAutoscaler = ./modules/nomad-autoscaler.nix;
        rezicsPlatform = ./modules/rezics-platform.nix;
        cloudflaredTunnel = ./modules/cloudflared.nix;

        base = {
          imports = [
            fleet
            common
            nomad
          ];
        };

        edge = {
          imports = [
            base
            nomadAutoscaler
            rezicsPlatform
            cloudflaredTunnel
          ];
        };

        data = base;
      };

      packages.${system} = rec {
        release-gateway = pkgs.callPackage ./packages/release-gateway.nix { };
        default = release-gateway;
      };

      devShells.${system}.default = pkgs.mkShell {
        packages = [
          pkgs.go
          pkgs.go-task
          pkgs.nomad
          pkgs.ripgrep
          pkgs.shellcheck
        ];
      };

      checks.${system}.release-gateway = self.packages.${system}.release-gateway;
      formatter.${system} = pkgs.nixfmt;
    };
}